Eccolo, l’ho provato sul Dax, H1 e Giornaliero (mi sembra funzioni):

Bullish            = close > open
Bearish            = close < open
MieCondizioniLong  = average[10,0](close) CROSSES OVER  average[50,0](close) AND Bullish AND Not OnMarket
MieCondizioniShort = average[10,0](close) CROSSES UNDER average[50,0](close) AND Bearish AND Not OnMarket
IF Not OnMarket THEN
   Uscita = 0
   Flag   = 0
ENDIF
IF OnMarket AND Not OnMarket[1] THEN
   Entrata = TradePrice   //aggiorna il prezzo d'entrata a quello reale
ENDIF
IF MieCondizioniLong  THEN
   BUY 1 CONTRACT AT MARKET
   Entrata = close        //assumiamo che il prezzo d'entrata sia il prezzo
   //                       corrente (verrà corretto la prossima candela)
   Uscita  = open
ENDIF
IF MieCondizioniShort THEN
   SELLSHORT 1 CONTRACT AT MARKET
   Entrata = close        //assumiamo che il prezzo d'entrata sia il prezzo
   //                       corrente (verrà corretto la prossima candela)
   Uscita  = open
ENDIF
IF LongOnMarket AND Flag = 0 THEN
   Uscita = max(Uscita,Entrata + ((close - Entrata) / 3))
ENDIF
IF ShortOnMarket AND Flag = 0 THEN
   Uscita = min(Uscita,Entrata - ((Entrata - close) / 3))
ENDIF
IF Uscita <> 0 AND ((LongOnMarket AND Bearish) OR (ShortOnMarket AND Bullish)) THEN
   Flag = 1
ENDIF
IF Uscita <> 0 THEN
   IF LongOnMarket THEN
      SELL      AT Uscita STOP
   ELSIF ShortOnMarket THEN
      EXITSHORT AT Uscita STOP
   ENDIF
ENDIF
//graphonprice Entrata coloured(0,0,255,255)
//graphonprice Uscita  coloured(255,0,0,255)
//IF ShortOnMarket THEN
//   graph (Entrata - close) / PipSize
//ELSE
//   graph (close - Entrata) / PipSize
//ENDIF
//graph Flag