Lo siento. Es mi primera vez y no me di cuenta. Lo explico en español. Uso un sitema con una media móvil de 14 y otra de 35 periodos. Compro cuando el precio está por debajo de ambas medias y vendo cuando está por encima. O sea un istema contratendencia. Coloco un stop de 10 puntos. Hasta aqui todo bien, pero necesito implementar una condición en la que cuando salta el stop, no vuelva a comprar hasta que el precio no se ha situado de nuevo bajo ambas medias. O al revés si estoy vendiendo. De esta manera evitaría tener perdidas grandes cuando hay una subida o bajada importante. Gracias de antemano.

Esta es su versión actualizada, la probé en el EUR/CHF en 1 minuto, porque el Stop Loss es demasiado pequeño y las condiciones de entrada demasiado fáciles y en los gráficos más largos a menudo abren y cierran una operación en la misma vela e inmediatamente abren otro sin que ProOrder sea capaz de detectar ONMARKET y STRATEGYPROFIT a tiempo.

//-------------------------------------------------------------------------
// Código principal : EMA14,35TF-1
//-------------------------------------------------------------------------
// Definición de los parámetros del código
DEFPARAM CumulateOrders = False // Acumulación de posiciones desactivada

ONCE MyProfit = 0     //Variable utilizada para conocer el resultado (actualizado a
                      //   la última operación cerrada) de mi estrategia
ONCE TradeLongON  = 1 //Variable utilizada para permitir operaciones alcistas:  1 = sí,  0 = no
ONCE TradeShortON = 1 //Variable utilizada para permitir operaciones bajistas:  1 = sí,  0 = no

ONCE LongTrade  = 0   //Variable utilizada para saber si la última operación fue al alza
ONCE ShortTrade = 0   //Variable utilizada para saber si la última operación fue hacia abajo
IF LongOnMarket THEN
LongTrade  = 1
ShortTrade = 0
ELSIF ShortOnMarket THEN
LongTrade  = 0
ShortTrade = 1
ENDIF

IF Not OnMarket AND MyProfit < StrategyProfit THEN  //Si la última operación fue perdida ...
MyProfit = StrategyProfit
IF LongTrade THEN                                //...y fue alcista....
TradeLongON  = 0                              //...detener las operaciones alcistas
ELSIF ShortTrade THEN                            //...y era bajista...
TradeShortON = 0                              //...detener operaciones bajistas
ENDIF
ENDIF

IF MyProfit <> StrategyProfit THEN
MyProfit = StrategyProfit           //Guarde el resultado de la estrategia actualizada
ENDIF

// Impide al sistema operar en días precisos de la semana
daysForbiddenEntry = OpenDayOfWeek = 6

// Condiciones para entrada de posiciones largas
indicator1 = Average[14](close)
c1 = (close < indicator1)
indicator2 = Average[35](close)
c2 = (close < indicator2)

IF c1 AND c2 THEN                       //Cuando las condiciones C1 y C2 ocurren ...
TradeShortON = 1                     //...Puedes comenzar de nuevo con operaciones bajistas
ENDIF

IF (c1 AND c2) AND not daysForbiddenEntry AND TradeLongON THEN
BUY 50 SHARES AT MARKET
ENDIF

// Condiciones de salida de posiciones largas
indicator3 = Average[14](close)
c3 = (close > indicator3)
indicator4 = Average[35](close)
c4 = (close > indicator4)

IF c3 AND c4 THEN
SELL AT MARKET
ENDIF

// Condiciones de entrada de posiciones cortas
indicator5 = Average[14](close)
c5 = (close > indicator5)
indicator6 = Average[35](close)
c6 = (close > indicator6)

IF c5 AND c6 THEN                       //Cuando las condiciones C5 y C6 ocurren ...
TradeLongON = 1                      //...Puedes comenzar de nuevo con operaciones alcistas
ENDIF

IF (c5 AND c6) AND not daysForbiddenEntry AND TradeShortON THEN
SELLSHORT 50 SHARES AT MARKET
ENDIF

// Condiciones de salida de posiciones cortas
indicator7 = Average[14](close)
c7 = (close < indicator7)
indicator8 = Average[35](close)
c8 = (close < indicator8)

IF c7 AND c8 THEN
EXITSHORT AT MARKET
ENDIF

// Stops y objetivos
SET STOP pLOSS 10
//graph MyProfit
//graph StrategyProfit
//graph TradeLongON
//graph TradeShortON
//graph LongTrade + (ShortTrade * 2)

Puede adjuntar una foto de la pantalla con la operación comercial destacada.
Cuéntame también sobre qué herramienta y el marco de tiempo probaste la estrategia.

Gracias.