Ciao Roberto
si puo’ avere un TS con candele heikin -ashi, con TF da 5 minuti?
si apre e si chiude la posizione ogni volta che cambia il colore delle candele,
ma filtrato magari con un supertrend, e in armonia con un TF di 30 minuti.
si lavora in stop end reverse, ma sempre con uno stop loss a protezione
Grazie
Eccolo:
DEFPARAM CumulateOrders = FALSE
Timeframe(30 minute,UpdateOnClose)
ST = Supertrend[3,10]
Timeframe(5 minute,UpdateOnClose)
ONCE xOpen = open
xClose = TotalPrice
IF BarIndex > 1 THEN
xOpen = (xOpen[1] + xClose[1]) / 2
ENDIF
xHigh = max(high,max(xClose,xOpen))
xLow = min(low, min(xClose,xOpen))
Rialzo = xClose > xOpen
Ribasso = xClose < xOpen
Cambio = (Rialzo AND Ribasso[1]) OR (Rialzo[1] AND Ribasso)
Timeframe(default)
// LONG
IF Rialzo AND Cambio AND close > ST AND Not LongOnMarket THEN
BUY 1 contract at Market
ENDIF
// SHORT
IF Ribasso AND Cambio AND close < ST AND Not ShortOnMarket THEN
SELLSHORT 1 contract at Market
ENDIF
// TP & SL
SET Target pProfit 200
SET Stop pLoss 200
Grazie Roberto, ma non va, scusami, non mi sono spiegato bene
io vorrei che , se a 30 minuti, non heihin-ashi, l’ultima candela chiude verde,
nel grafico a 5 minuti, si heikin-ashi, si aspetta un ritracciamento con candele rosse e alla prima candela verde si va long,
senza ritracciamento non si apre la posizione long e si aspetta la prossima candela a 30 minuti per ricominciare.
Se a 30 minuti, non heihin-ashi, l’ultima candela chiude rossa, nel grafico a 5 minuti, si heikin-ashi,
si aspetta un ritracciamento con candele verdi e alla prima candela rossa si va short,
senza ritracciamento non si apre la posizione short e si aspetta la prossima candela a 30 minuti per ricominciare.
La posizione aperta viene chiusa al cambio di colore della candela a 5 minuti, senza mettere target profit, oppure in stop loss da 25 pips,
e dopo si aspetta la chiusura della 30 minuti per ricominciare.
Grazie
È tutta un’altra cosa da quello che avevi chiesto.
Vedrò come farlo.
Eccolo, ho tolto il supertrend ed ho messo le nuove indicazioini che mi hai dato (l’ho provato solo per verificare errori di sintassi).
Se riscontri entrate errate fammi sapere:
- strumento
- time frame
- data ed ora dell’entrata errata
DEFPARAM CumulateOrders = FALSE
//-----------------------------------------------------------------
Timeframe(30 minute,UpdateOnClose)
Rialzo30 = close >open
Ribasso30 = close < open
//-----------------------------------------------------------------
Timeframe(5 minute,UpdateOnClose)
ONCE xOpen = open
xClose = TotalPrice
IF BarIndex > 1 THEN
xOpen = (xOpen[1] + xClose[1]) / 2
ENDIF
xHigh = max(high,max(xClose,xOpen))
xLow = min(low, min(xClose,xOpen))
//
Rialzo5 = xClose > xOpen
Ribasso5 = xClose < xOpen
Cambio5 = (Rialzo5 AND Ribasso5[1]) OR (Rialzo5[1] AND Ribasso5)
//-----------------------------------------------------------------
Timeframe(default)
// LONG
IF Not LongOnMarket AND Rialzo30 AND Rialzo5 AND Cambio5 THEN
BUY 1 contract at Market
ENDIF
// SHORT
IF Not ShortOnMarket AND Ribasso30 AND Ribasso5 AND Cambio5 THEN
SELLSHORT 1 contract at Market
ENDIF
// TP & SL
SET Target pProfit 200
SET Stop pLoss 200
Se NON vuoi fare lo Stop & Reverse, devi solo sostituire LongOnMarket e ShortOnMarket, alle righe 22 e 26, con:
OnMarket
Grazie Roby, sei un amico
ho inserito OnMarket, troppe tante le posizioni aperte
ho eliminato il target profit perchè la posizione aperta, deve essere chiusa al cambio di colore della candela a 5 minuti,
e adesso non lo fa, senza mettere target profit e dopo si aspetta la chiusura della prossima 30 minuti per ricominciare.
Cioè, a 30 minuti chiude verde, quindi a 5 minuti, in quella mezz’ora successiva, deve ritracciare di una o piu’ candele rosse
e alla prima candela verde a 5 minuti si apre la posizione long, altrimenti non si apre e si aspetta la prossima candela 30 minuti.
la posizione si chiude con il cambio di colore, oppure si lascia correre se il colore non cambia.
Stesso discorso in caso dello short, cioè a 30 minuti chiude rosso, nella mezz’ora dopo si aspetta un ritracciamento di una o piu’ candele verdi
e alla prima candela rossa si va short; si chiude al cambio colore della 5 minuti o si lascia correre se il colore non cambia.
Grazie per la collaborazione e disponibilita’
Scusa, mi ero dimenticato di mettere l’uscita al cambio di colore sul 5 minuti:
DEFPARAM CumulateOrders = FALSE
//-----------------------------------------------------------------
Timeframe(30 minute,UpdateOnClose)
Rialzo30 = close >open
Ribasso30 = close < open
//-----------------------------------------------------------------
Timeframe(5 minute,UpdateOnClose)
ONCE xOpen = open
xClose = TotalPrice
IF BarIndex > 1 THEN
xOpen = (xOpen[1] + xClose[1]) / 2
ENDIF
xHigh = max(high,max(xClose,xOpen))
xLow = min(low, min(xClose,xOpen))
//
Rialzo5 = xClose > xOpen
Ribasso5 = xClose < xOpen
Cambio5 = (Rialzo5 AND Ribasso5[1]) OR (Rialzo5[1] AND Ribasso5)
//-----------------------------------------------------------------
Timeframe(default)
// LONG
IF Not OnMarket AND Rialzo30 AND Rialzo5 AND Cambio5 THEN //Entrata
BUY 1 contract at Market
ENDIF
IF LongOnMarket AND Ribasso5 THEN //Uscita
SELL AT Market
ENDIF
// SHORT
IF Not OnMarket AND Ribasso30 AND Ribasso5 AND Cambio5 THEN //Entrata
SELLSHORT 1 contract at Market
ENDIF
IF ShortOnMarket AND Rialzo5 THEN //Uscita
EXITSHORT AT Market
ENDIF
// TP & SL
//SET Target pProfit 200
SET Stop pLoss 30
