Si, cerco di fartelo appena possibile.

Quali bande VWAP utilizzi?

E’ quello predefinito, però non si può utilizzare per le strategie, utuilizzerò questo https://www.prorealcode.com/prorealtime-indicators/vwap-intraday/.

Eccolo:

//////////////////////////////////////////////////////////////////////////
DEFPARAM CumulateOrders = false
//------------------------------------------------------------------------
//                    Setup delle candele Heikin-Ashi
once xOpen = open
xClose     = (open + close + high + low) / 4
if barindex > 0 then
xOpen   = (xOpen + xClose[1]) / 2
endif
//xLow     = min(low,min(xClose,xOpen))
//xHigh    = max(high,max(xClose,xOpen))
//xTypic   = (xHigh + xLow + xClose) / 3
//xMed     = (xHigh + xLow) / 2
//xRange   = xHigh - xLow
Bullish    = xClose > xOpen
Bearish    = xClose < xOpen
//------------------------------------------------------------------------
//                          VWAP intraday (& bands)
//
// https://www.prorealcode.com/prorealtime-indicators/vwap-intraday/
//------------------------------------------------------------------------
d = max(1, intradaybarindex)
IF Volume > 0 THEN
   VWAP = SUMMATION[d](volume*typicalprice)/SUMMATION[d](volume)
ENDIF
if (intradaybarindex=0) then
   sd = 0
else
   sd = SUMMATION[d](max(abs(high-vwap),abs(vwap-low)))/d
endif
SDup1 = vwap+sd
SDlw1 = vwap-sd
SDup2 = vwap+sd*2
SDlw2 = vwap-sd*2
SDup3 = vwap+sd*3
SDlw3 = vwap-sd*3
//RETURN VWAP as "VWAP",SDup1 as "upper1",SDlw1 as "lower1",SDup2 as "upper2",SDlw2 as "lower2",SDup3  as "upper3",SDlw3 as "lower3"
//////////////////////////////////////////////////////////////////////////
L1 = Bearish[1]
L2 = xClose[1] < SDlw3
L3 = Bullish
L4 = xClose    > SDlw3
CL = L1 and L2 and L3 and L4 and Not LongOnMarket
//
S1 = Bullish[1]
S2 = xClose[1] > SDup3
S3 = Bearish
S4 = xClose    < SDup3
CS = S1 and S2 and S3 and S4 and Not ShortOnMarket
//
IF CL Then
   BUY 1 Contract at Market
ENDIF
//
IF CS Then
   SELLSHORT 1 Contract at Market
ENDIF