Screener MACD PLATINUM UP

Viewing 7 posts - 1 through 7 (of 7 total)

Author

Posts

10/02/2017 at 5:53 PM #48041 quote

Participant

Master

Bonjour à tous,

Je voudrais créer un screener qui me renvoit les signaux positifs du MACD Platinum, j’ai fais cela mais ça n’a pas l’air d’être au point !

Si quelqu’un peut me donner un coup de main ?

merci

//SCREENER  PRC_MACD Platinum  indicator 29.09.2016
//Nicolas @ www.prorealcode.com  Sharing ProRealTime knowledge

EMAshort1 = exponentialaverage[short](close)
EMAshort2 = exponentialaverage[short](EMAshort1)
DifferenceShort = EMAshort1 - EMAshort2
ZeroLagShort = EMAshort1 + DifferenceShort

EMAlong1 = exponentialaverage[long](close)
EMAlong2 = exponentialaverage[long](EMAlong1)
DifferenceLong = EMAlong1 - EMAlong2
ZeroLagLong = EMAlong1 + DifferenceLong

ZeroLagMACD = ZeroLagShort - ZeroLagLong

signal1=ExponentialAverage[signal](ZEROLAGMACD)
signal2=ExponentialAverage[signal](signal1)
DIFFERENCE2=signal1-signal2

SignalMACD=signal1+DIFFERENCE2

C1= signalMACD>=zerolagMACD

short  = 12
long   = 26
signal =  9
SCREENER(C1)

10/03/2017 at 7:56 AM #48086 quote

Nicolas

Keymaster

Legend

Les conditions d’un screener doivent être entre crochets, et non entre parenthèses :

SCREENER [c1]

Les parenthèses sont utiles uniquement pour introduire une valeur quelconque comme notion de classement dans la fenêtre de restitution des résultats de ProScreener.

10/03/2017 at 10:58 AM #48105 quote

supertiti

Participant

Master

Bonjour Nicolas

même avec les crochets le screener ne renvoit rien ?!

une idée ?

bonne journée

10/03/2017 at 12:11 PM #48109 quote

Nicolas

Keymaster

Legend

Il faudrait essayer en déplaçant les paramètres des périodes des indicateurs que tu as mis à la fin, au début du code, sinon le programme ne sait pas ce qu’il doit calculer.

10/03/2017 at 12:42 PM #48114 quote

supertiti

Participant

Master

Voilà c’est fait, j’ai bien des retours cette fois ci mais pour autant j’aurais voulu que ça me retourne les “dots ” ou points de croisements qu’il y a dans ton indicateur et aucune valeur correspond ?!

// PLATINUM UP

//PRC_MACD Platinum  indicator 29.09.2016
//Nicolas @ www.prorealcode.com  Sharing ProRealTime knowledge
short  = 12
long   = 26
signal =  9
EMAshort1 = exponentialaverage[short](close)
EMAshort2 = exponentialaverage[short](EMAshort1)
DifferenceShort = EMAshort1 - EMAshort2
ZeroLagShort = EMAshort1 + DifferenceShort

EMAlong1 = exponentialaverage[long](close)
EMAlong2 = exponentialaverage[long](EMAlong1)
DifferenceLong = EMAlong1 - EMAlong2
ZeroLagLong = EMAlong1 + DifferenceLong

ZeroLagMACD = ZeroLagShort - ZeroLagLong

signal1=ExponentialAverage[signal](ZEROLAGMACD)
signal2=ExponentialAverage[signal](signal1)
DIFFERENCE2=signal1-signal2

SignalMACD=signal1+DIFFERENCE2

C1= signalMACD>=zerolagMACD

SCREENER [C1]

10/03/2017 at 12:43 PM #48115 quote

Nicolas

Keymaster

Legend

Dans ton screener, tu ne testes pas un croisement mais seulement si la variable 1 est au dessus de la variable 2.

10/03/2017 at 1:46 PM #48128 quote

supertiti

Participant

Master

C’est vrai que ça va beaucoup mieux comme ça ! je devrais réfléchir de temps en temps … merci pour ton aide toujours efficace

// PLATINUM UP

//PRC_MACD Platinum indicator 29.09.2016
//Nicolas @ www.prorealcode.com Sharing ProRealTime knowledge
short = 12
long = 26
signal = 9
EMAshort1 = exponentialaverage[short](close)
EMAshort2 = exponentialaverage[short](EMAshort1)
DifferenceShort = EMAshort1 - EMAshort2
ZeroLagShort = EMAshort1 + DifferenceShort

EMAlong1 = exponentialaverage[long](close)
EMAlong2 = exponentialaverage[long](EMAlong1)
DifferenceLong = EMAlong1 - EMAlong2
ZeroLagLong = EMAlong1 + DifferenceLong
ZeroLagMACD = ZeroLagShort - ZeroLagLong

signal1=ExponentialAverage[signal](ZEROLAGMACD)
signal2=ExponentialAverage[signal](signal1)
DIFFERENCE2=signal1-signal2

SignalMACD=signal1+DIFFERENCE2

C1= zerolagMACD crosses over signalMACD

SCREENER [C1]