Screener 1:

// Screener 1
/*
---------------  La valeur renvoyée par SIGNAL peut être l'une des suivantes :


Signal = 19 pas y avoir de prix au-delà de 1 an et prix < dernier plus haut d’il y a 1 an
Signal = 11 pas y avoir de prix au-delà de 1 an et prix < dernier plus haut d’il y a 1 mois
Signal = 13 pas y avoir de prix au-delà de 1 an et prix < dernier plus haut d’il y a 3 mois
Signal = 16 pas y avoir de prix au-delà de 1 an et prix < dernier plus haut d’il y a 6 mois
//
Signal = 29 pas y avoir de prix au-delà de 2 an et prix < dernier plus haut d’il y a 1 an
Signal = 21 pas y avoir de prix au-delà de 2 an et prix < dernier plus haut d’il y a 1 mois
Signal = 23 pas y avoir de prix au-delà de 2 an et prix < dernier plus haut d’il y a 3 mois
Signal = 26 pas y avoir de prix au-delà de 2 an et prix < dernier plus haut d’il y a 6 mois
//
Signal = 59 pas y avoir de prix au-delà de 5 an et prix < dernier plus haut d’il y a 1 an
Signal = 51 pas y avoir de prix au-delà de 5 an et prix < dernier plus haut d’il y a 1 mois
Signal = 53 pas y avoir de prix au-delà de 5 an et prix < dernier plus haut d’il y a 3 mois
Signal = 56 pas y avoir de prix au-delà de 5 an et prix < dernier plus haut d’il y a 6 mois
//
Signal = 69 pas y avoir de prix au-delà de 6 mois et prix < dernier plus haut d’il y a 1 an
Signal = 61 pas y avoir de prix au-delà de 6 mois et prix < dernier plus haut d’il y a 1 mois
Signal = 63 pas y avoir de prix au-delà de 6 mois et prix < dernier plus haut d’il y a 3 mois
Signal = 66 pas y avoir de prix au-delà de 6 mois et prix < dernier plus haut d’il y a 6 mois
*/
Timeframe(Yearly)
// IPO de x bars ( je recherche des actions qui ont moins de 1 ans, 2 ans, 5 ans
IPOy5 = close[4] = 0     // Il ne doit pas y avoir de prix au-delà de 4 ans
IPOy2 = close[2] = 0     // Il ne doit pas y avoir de prix au-delà de 1 an
IPOy1 = close[1] = 0     // Il ne doit y avoir aucun prix supérieur à celui de l'année en cours.
// prix < dernier plus haut (pas la cloture, le vrai dernier plus haut de la bar) d’il y a 1 an
DMy1  = close < high[1]  // prix < Dernier Maximum de 1 an
//
Timeframe(Monthly)
// IPO de x bars ( je recherche des actions qui ont moins de 6 mois
IPOm6 = close[5] = 0     // Il ne doit pas y avoir de prix au-delà de 6 mois
// prix < dernier plus haut (pas la cloture, le vrai dernier plus haut de la bar) d’il y a 1 mois, 3 mois, 6 mois
DMm6  = close < high[6]  // prix < Dernier Maximum de 6 mois
DMm3  = close < high[3]  // prix < Dernier Maximum de 3 mois
DMm1  = close < high[1]  // prix < Dernier Maximum de 1 mois
//
Timeframe(weekly)
// prix >=ema 20 weekly
w1 = close >= Average[20,1](close)   // prix >= ema 20 (weekly)
// prix >= ema 200(daily) ou 40(weekly)
w2 = close >= Average[40,1](close)   // prix >= ema 40(weekly)
//                                              Vous ne pouvez pas utiliser la moyenne mobile exponentielle (EMA) à 200
//                                              périodes car les calculs internes dépassent la limite de 256 périodes
//                                              (mais vous pouvez utiliser la moyenne mobile simple (SMA) à 200 périodes).
//
Timeframe(Daily)
// prix >= ema 20 (daily)
d1         = close >= Average[20,1](close)   // prix >= ema 20 (daily)
//
Xjours     = 30
PlusHautJ  = highest[Xjours](high)
//
Timeframe(default)
// prix entre le dernier plus haut de (x) bars et -50% par rapport à ce dernier plus haut
Xbars      = 40
MaxXbars   = highest[Xbars](high)    // Plus Haut des X dernières barres
MaxMoins50 = MaxXbars * 0.50         // 50% du plus haut des X dernières barres
Moins50    = (close <= MaxXbars) AND (close >= MaxMoins50) // Le prix doit se situer entre les deux valeurs.
// prix qui se situe dans une fourchette de (x%) par rapport au dernier plus bas de (x) bars, et le plus haut de (x) jours
Nbarres    = 30
PlusBas    = lowest[Nbarres](low)
Pourcent   = 0.20                                           // 20%
Fourchette = PlusHautJ - ((PlusHautJ - PlusBas) * Pourcent)
GammedePrix= (close <= PlusHautJ) AND (close >= Fourchette)
// prix qui a augmenté de (x%) par rapport au denier plus bas (pas la cloture de la barre!!!!!!!), de (x) bars pareil
Augment    = close >= (PlusBas * (1 + Pourcent))
// écart en % entre le plus bas de (x) bars et le plus haut de (x) bars (n’ importe ou) pour trouver les plus gros
// range en volatilité
PlusHaut   = highest[Nbarres](high)
Gamme      = PlusHaut - PlusBas
PCgamme    = round(Gamme * 100 / PlusHaut,2)  // écart en % entre le plus bas et le plus haut de (x) bars
// (j’utilise mon fibo pour ça) : prix entre le 25%(1/4) et le 61,8 (3/5) du dernier plus haut de (x) bars et
// le dernier plus bas de (x) bars
Fibo25     = PlusHaut - (Gamme * 0.25)         //25%   Fibonacci
Fibo618    = PlusHaut - (Gamme * 0.618)        //61.8% Fibonacci
FiboGamme  = (close <= Fibo25) AND (close >= Fibo618)
// ema 100 du volume capital qui augmente depuis (x) bars)
Ema100     = average[100,0](volume) // L'EMA sur 100 périodes peut être incorrecte car, comme je l'ai mentionné,
//                                     ses calculs internes peuvent dépasser la période maximale autorisée de 256.
//                                     Essayez de la laisser à 100 périodes, mais si le calcul est incorrect,
//                                     réduisez-la à environ 80 périodes.
//                                     Vous pouvez également la laisser à 100 périodes, mais remplacer
//                                     average[100,1](volume) (qui correspond à l'EMA) par average[100,0](volume)
//                                     (qui correspond à la SMA).
VolBarres  = 30                     // Barres où le volume augmente
AugmentVOL = volume >= highest[VolBarres](volume)
// ema 20 du volume capital > ema 100 volume capital
Ema20      = average[20,0](volume)
Ema20Dessus= 1 OR (Ema20 > Ema100)
// ema 20 du volume capital > à (valeure)
maValeur   = 2000 * close                 // valeure du volume capial
VolumeCond = Ema20 > maValeur
//
IPO = 0
IF IPOy1 THEN
IPO = 10
ELSIF IPOy2 THEN
IPO = 20
ELSIF IPOy5 THEN
IPO = 50
ELSIF IPOm6 THEN
IPO = 60
ENDIF
//
DM = 0
IF IPO THEN
IF DMy1 THEN
IPO = IPO + 9
ELSIF DMm1 THEN
IPO = IPO + 1
ELSIF DMm3 THEN
IPO = IPO + 3
ELSIF DMm6 THEN
IPO = IPO + 6
ENDIF
ENDIF
//
Cond = IPO AND DM AND w1 AND w2 AND d1 AND moins50 AND gammedeprix AND augment AND FiboGamme AND augmentvol AND ema20dessus AND volumecond
//
IF PCgamme THEN
ENDIF
//
SCREENER[Cond](IPO AS "Signal")

Vous devez vérifier attentivement les conditions et voir si je les ai correctement interprétées.

Cela ne me donne aucun signal sur l’échelle de temps journalière.

Je te donnerai le deuxième screener demain.

Bonjour, vous parlez de cette explication du filtre… ?

c1=close*volume>10000000//capital volume condition
c2=close>average[63](close)//moving average filter
c3=close/highest[63](high)>0.75//price location
c4=close/lowest[21](low)>1.5//upward variation
c5=close/close[21]*100//percentage increase


screener[c1 and c2 and c3 and c4 and c5]