Buon giorno chiederei i due seguenti screener:
a ) titoli azionari daily la cui forza relativa incroci a rialzo la sua media esponenziale a 20 periodi;
prezzo superiore a 20 dollari
volumi in crescita rispetto ai 5 giorni precedenti.
b) titoli azionari daily la cui forza relativa incroci a rialzo la sua media esponenziale a 20 periodi;
titoli con forza relativa già sopra la sua media mobile a 50 periodi
prezzo superiore a 20 dollari
volumi in crescita rispetto ai 5 giorni precedenti.
Grazie mille.
Ecco il primo
// RSI and 20-period Exponential Moving Average
myRSI = RSI[14](close)
emaRSI = Average[20,1](myRSI)
// Conditions
condCross = myRSI CROSSES OVER emaRSI
condPrice = close > 20
condVol = Volume > Highest[5](Volume)[1]
// Screener execution
SCREENER[condCross AND condPrice AND condVol]
Ed ecco il secondo 🙂
// RSI, 20-period EMA, and 50-period Simple Moving Average
myRSI = RSI[14](close)
emaRSI = Average[20,1](myRSI)
smaRSI = Average[50](myRSI)
// Conditions
condCross = myRSI CROSSES OVER emaRSI
condAbove = myRSI > smaRSI
condPrice = close > 20
condVol = Volume > Highest[5](Volume)[1]
// Screener execution
SCREENER[condCross AND condAbove AND condPrice AND condVol]
Buon giorno, scusi non intendevo come forze relativa l RSI. ma la FORZA RELATIVA ( indicatore PARAGONE con l SP500)
Puo’ rimandarmi i due SCREENER con l indicatore FORZA RELATIVA (paragone con SP500) ?
GRAZIE MILLE.
Prova questi due. Non sono riuscito a trovare SP500 tra l’elenco degli indici, prova tu, oppure chiedi a ProReralTime. Nell’esempio ho indicato il NASDAQ, che sono riuscito a trovare. Le azioni le puoi scegliere quando lo fai partire.
Screener 1:
TIMEFRAME(daily)
CloseVal = Close
EQUITYFRAME("Azioni - US (NASDAQ","")
CloseInd = Close
EQUITYFRAME(default)
Ratio = (CloseVal / CloseInd) * 100 //rapporto tra indice ed azione
//
TIMEFRAME(default)
RelativeStrength = (Ratio - Ratio[1]) *100
MyAvg = average[20,1](RelativeStrength) //Media Esponenziale a 20 periodi
Cond = 0
CondVOL = volume > highest[5](volume[1])
CondPREZZO = close > 20
CondAVG = RelativeStrength CROSSES OVER MyAvg
IF CondAVG AND CondPREZZO AND CondVOL THEN
cond = 1
ENDIF
SCREENER [Cond]
Screener 2:
TIMEFRAME(daily)
CloseVal = Close
EQUITYFRAME("Azioni - US (NASDAQ","")
CloseInd = Close
EQUITYFRAME(default)
Ratio = (CloseVal / CloseInd) * 100 //rapporto tra indice ed azione
//
TIMEFRAME(default)
RelativeStrength = (Ratio - Ratio[1]) *100
MyAvg = average[20,1](RelativeStrength) //Media Esponenziale a 20 periodi
MyAvg2 = average[50,0](RelativeStrength) //Media Semplice a 50 periodi
Cond = 0
CondVOL = volume > highest[5](volume[1])
CondPREZZO = close > 20
CondAVG = RelativeStrength CROSSES OVER MyAvg
CondAVG2 = (summation[2](RelativeStrength > MyAvg2) = 2)
IF CondAVG AND CondAVG2 AND CondPREZZO AND CondVOL THEN
cond = 1
ENDIF
SCREENER [Cond]
