Si, se puoi pazientare ancora un pò. Grazie 🙂

Eccolo:

DEFPARAM CumulateOrders = False
ONCE Entra = 0
IF OnMarket THEN
   Entra = 0
ELSE
   IF (close <= StopLoss) OR (close >= Entrata) THEN
      Entra = 0
   ENDIF
ENDIF
IF Entra = 0 AND Not OnMarket THEN
   HH          = highest[3](high[1])
   LL          = lowest[3](low[1])
   Escursione  = HH - LL
   Entrata     = LL + (Escursione / 2)
   Uscita50    = Entrata + (Escursione * 0.50)
   Uscita80    = Entrata + (Escursione * 0.80)
   StopLoss    = LL
   PerCentuale = Escursione * 100 / HH
   c1          = PerCentuale >= 1.02
   c2          = close > open
   IF c1 AND c2 THEN
      Entra = 1
   ENDIF
ENDIF
IF Entra AND Not OnMarket THEN
   BUY 3 CONTRACTS AT Entrata STOP
   Set Stop   Price LL
   Set Target Price Entrata + Escursione
ENDIF
IF OnMarket THEN
   IF close >= Uscita50 AND CountOfPosition = 3 THEN
      SELL 1 CONTRACT AT MARKET
   ELSIF close >= Uscita80 AND CountOfPosition = 2 THEN
      SELL 1 CONTRACT AT MARKET
   ENDIF
ENDIF
IF OnMarket AND CountOfPosition < 3 THEN
   IF close >= StopLoss * 1.002 THEN
      StopLoss = StopLoss * 1.002
   ENDIF
ENDIF
//graphonprice Entrata
//graphonprice LL       coloured("Red")
//graphonprice StopLoss coloured("Blue")
//graphonprice Uscita50 coloured("Green")
//graphonprice Uscita80 coloured("Green")
//graph PerCentuale