Reversal Stoch Adx Pattern

“chiaro” trend è un effetto visivo. Un software ha bisogno di parametri ben definiti per rilevarlo. Possono essere un prezzo che supera una certa media (o che l’ha superata già da N candele), oppuure un prezzo che supera la linea mediana delle Bande di Bollinger, oppure il prezzoche  nelle ultime N candele fa, rispetto alle N candele precedenti, Massimi e Minimi più alti (o più bassi), ecc…

Se mi dai un’indicazione dei criteri che desideri per riconoscere il trend te lo faccio.

Eccolo:

Body           = abs(close - open)
UpperShadow    = high - max(open,close)
LowerShadow    = min(open,close) - low
//--------------------------------------------------------------------------------------------------------------------
// Hammer
//
Ha1            = LowerShadow >= (Body * 3)     //Lower Shadow 3 times longer than the body
Ha2            = close >= (high-(range * 0.25))//must close in the upper 25% of its range
Ha3            = low = lowest[20](low)         //its Low must be the lowest one of the last 20 candles (1=disabled)
Hammer         = Ha1 AND Ha2 AND Ha3
//--------------------------------------------------------------------------------------------------------------------
// Shooting Star
//
Ss1            = UpperShadow >= (Body * 3)     //Upper Shadow 3 times longer than the body
Ss2            = LowerShadow <= Body           //Lower Shadow must be max as large as the body
Ss3            = close <= (low+(range * 0.25)) //must close in the lower 25% of its range
Ss4            = high = highest[20](high)      //its High must be the highest one of the last 20 candles (1=disabled)
ShootingStar   = Ss1 AND Ss2 AND Ss3 AND Ss4
//--------------------------------------------------------------------------------------------------------------------
BBVal          = 20                                                //20   BB periods
BBdev          = 2.0                                               //2.0  BB deviation
BBavg          = average[BBval,0](close)                           //BB mean (middle line)
UpperBB        = BBavg + ((std[BBval](close)) * BBdev)             //BB Upper Band
LowerBB        = BBavg - ((std[BBval](close)) * BBdev)             //BB Lower Band
//--------------------------------------------------------------------------------------------------------------------
Ema21          = average[21,1](close)          //21  periods
Ema200         = average[200,1](close)         //200 periods
UPtrend        = (close > Ema21) AND (close > Ema200)
DOWNtrend      = (close < Ema21) AND (close < Ema200)
MyStochasticK  = Stochastic[14,3](close)
MyADX          = ADX[14]
//--------------------------------------------------------------------------------------------------------------------
L1             = low  < LowerBB
S1             = high > UpperBB
L2             = MyStochasticK < 20
S2             = MyStochasticK > 80
L3             = MyADX > 40
S3             = L3
CondL          = L1 AND L2 AND L3 AND Hammer       AND UPtrend
CondS          = S1 AND S2 AND S3 AND ShootingStar AND DOWNtrend
Signal = 0
IF CondL THEN
   Signal = 1
ELSIF CondS THEN
   Signal = -1
ENDIF
RETURN Signal AS "Signal",0 AS"Zero"