RETRACEMENT ACTIONS

Viewing 4 posts - 1 through 4 (of 4 total)

Author

Posts

07/01/2026 at 7:28 PM #262311 quote

philippe noury

Participant

Junior

Bonsoir

Existe t_il des ScreenerS pour des actions US qui permettent de détecter des actions avec un retracement de 50% ?

OU des sites qui peuvent nous aidés pour cela ?

Dans l’attente cordialement

07/02/2026 at 9:04 AM #262341 quote

Iván González

Moderator

Legend

Bonjour. Oui, c’est possible :

// Screener : actions sur un retracement de 50 %
N = 100          // fenetre de recherche du swing
tol = 1.5        // tolerance autour des 50 % (en %)

hh = highest[N](high)
ll = lowest[N](low)
rango = hh - ll
fib50 = (hh + ll) / 2

hhBar = -1
llBar = -1
for i = 0 to N-1 do
   if hhBar = -1 and high[i] = hh then
      hhBar = i
   endif
   if llBar = -1 and low[i] = ll then
      llBar = i
   endif
next

bull = 0
if llBar > hhBar then
   bull = 1
endif

dist = abs(close - fib50) / fib50 * 100

c1 = rango > 0
c2 = dist <= tol

SCREENER[c1 AND c2](dist AS "Dist50%", bull AS "1Bull/0Bear")

Captura-de-pantalla-2026-07-02-090327.png

07/02/2026 at 9:08 AM #262343 quote

Iván González

Moderator

Legend

Vous pouvez également abréger la commande loop avec l’instruction highestbars

// Screener : actions sur un retracement de 50 %
N = 100          // fenetre de recherche du swing
tol = 1.5        // tolerance autour des 50 % (en %)

hh = highest[N](high)
ll = lowest[N](low)
rango = hh - ll
fib50 = (hh + ll) / 2

hhBar = highestbars[N](high)
llBar = lowestbars[N](low)

bull = 0
if llBar > hhBar then
   bull = 1
endif

dist = abs(close - fib50) / fib50 * 100

c1 = rango > 0
c2 = dist <= tol

SCREENER[c1 AND c2](dist AS "Dist50%", bull AS "1Bull/0Bear")

07/02/2026 at 9:35 AM #262347 quote

philippe noury

Participant

Junior

Bonjour

Merci pour votre aide

ESt ce que ce sceener détecte seulement un retracement à 50% ?

Mon but serait un minimum de 50% pouvant allez jusqu’à,80%

comme je suis novice en bourse j’essaie de me former et pour le moment voir la stratégie de retracement

dans l ‘attente cordialement

merci encore pour votre travail

robertogozzi thanked this post