J’ai également remarqué des données incorrectes. Je vais essayer d’en savoir plus et je vous tiendrai au courant.

Bonjour. Je trouve ton code correct. Si je ne me trompe pas, ce que tu cherches, c’est la valeur la plus basse des 60 dernières bougies et quand elle s’est produite, n’est-ce pas ? Dans ce cas, tu devrais utiliser une boucle plus appropriée. Avec ton code actuel, tu demandes à localiser la bougie où low = lowest[60](low). Comme tu peux le voir sur la capture d’écran, cela a pu se produire il y a plus de 60 périodes, même si ta ligne des plus bas est bien sur 60 périodes. Pour les plus hauts, c’est exactement la même chose, sauf qu’il faut chercher une configuration baissière pour le remarquer. Je te mets un exemple avec TSLA pour que tu voies que cela ne correspond pas non plus. Si ce que tu cherches, ce sont les bougies qui ont donné les valeurs maximales et minimales des 60 dernières bougies, alors tu devrais utiliser le code suivant pour ne pas te tromper.

DefParam DrawOnLastBarOnly = true

Periode = 60
atr = AverageTrueRange[14](close)

// +Haut
HAUTcours = Highest[Periode](High)
HAUTindex = 0
FOR i = 0 TO Periode - 1 DO
   IF High[i] = HAUTcours THEN
      HAUTindex = i
      BREAK
   ENDIF
NEXT

IF HAUTindex > 0 THEN
   DrawText("#HAUTcours#", BarIndex[HAUTindex], HAUTcours + 3*atr) Coloured(255, 0, 0)
   DrawText("#HAUTindex#", BarIndex[HAUTindex], HAUTcours + 2*atr) Coloured(255, 0, 0)
   DrawArrowDown(BarIndex[HAUTindex], HAUTcours + 0.15 * atr) Coloured(255, 0, 0)
ENDIF

// +Bas
BAScours = Lowest[Periode](Low)
BASindex = 0
FOR i = 0 TO Periode - 1 DO
   IF Low[i] = BAScours THEN
      BASindex = i
      BREAK
   ENDIF
NEXT

IF BASindex > 0 THEN
   DrawText("#BAScours#", BarIndex[BASindex], BAScours - 3*atr) Coloured(0, 128, 0)
   DrawText("#BASindex#", BarIndex[BASindex], BAScours - 2*atr) Coloured(0, 128, 0)
   DrawArrowUp(BarIndex[BASindex], BAScours - 0.15*atr) Coloured(0, 128, 0)
ENDIF


RETURN close

Après une analyse plus approfondie 🙂 voir mon image jointe pour commencer !

BarsSince ne répond pas à la question “où se trouve l’extrême dans ma fenêtre de 60 bougies ?”, mais à “à quand remonte la dernière fois où ce prix précis est apparu”.
Du coup, quand le nouveau Lowest des 60 dernières bougies est égal à un creux plus ancien, BarsSince peut retourner 93 (ou tout autre nombre > 60), alors que l’extrême de la fenêtre courante est… dans la fenêtre !

Ton premier code est donc correct pour dater la dernière occurrence d’un prix, mais pas adapté à ce que tu veux faire ici (pointer l’extrême dans la période).
Pour ça, il faut utiliser HighestBars / LowestBars qui renvoient l’offset (0…Période-1) de l’extrême à l’intérieur de la fenêtre.

Voir: https://www.prorealcode.com/documentation/highestbars/

Selon moi, voici le code adapté :

DefParam DrawOnLastBarOnly = true

Periode = 60

if barindex>periode then 
// +HAUT sur la période
hautBars  = HighestBars[Periode](High)        // offset de l'extrême dans la fenêtre (0..Periode-1)
hautPrix  = High[hautBars]

if hautBars >= 0 then
DrawText("#HAUTprix#", BarIndex[hautBars], hautPrix+3) Coloured(255,0,0)
DrawText("#hautBars#", BarIndex[hautBars], hautPrix+2) Coloured(255,0,0)
DrawArrowDown(BarIndex[hautBars], hautPrix+1) Coloured(255,0,0)
endif

// +BAS sur la période
basBars   = LowestBars[Periode](Low)          // offset de l'extrême dans la fenêtre (0..Periode-1)
basPrix   = Low[basBars]

if basBars >= 0 then
DrawText("#BASprix#", BarIndex[basBars], basPrix-3) Coloured(0,128,0)
DrawText("#basBars#", BarIndex[basBars], basPrix-2) Coloured(0,128,0)
DrawArrowUp(BarIndex[basBars], basPrix-1) Coloured(0,128,0)
endif
endif 

RETURN