Pour le code en ticks, en amont du calcul de volatmoy avec tableaux, le commentaire du post #200701 se traduira par la modification suivante en créant amaxhier et aminhier pour corriger ton bug dans volathaute et volatbasse afin de correspondre à amax[1] et amin[1] du code en ut jour.

D’autre part, dans le cas des cfd h24 pour être sûr d’avoir exactement les mêmes open de journée en ticks que celles retournées par le mot-clé dopen(), j’ai remplacé les recherches de changement de dates avec un today<>today[1] (parenthèse: ok à la date du post, je reste juste prudent sur today qui a déjà changé de comportement lors d’une version précédente, au cas où le post remonte dans le futur et que l’ancien comportement soit éventuellement revenu entretemps)

defparam drawonlastbaronly=true
iatr=exponentialaverage[100](tr)
REM TRUE RANGE
amax=max(dclose(1),dhigh(0))
amin=min(dclose(1),dlow(0))

if today<>today[1] then
 amaxhier=amax[1]
 aminhier=amin[1]
 ouvhier=ouvjour
 ouvjour=open
endif

REM Calcul Volatilité journalière minimale par rapport à l'ouverture
volathaute=amaxhier-ouvhier // calcul de la volatilité au dessus de l’ouverture de la veille.
volatbasse=ouvhier-aminhier // calcul de la volatilité en dessous de l’ouverture de la veille.
volatmin=min(volatbasse,volathaute) // on veut la plus petite des deux

REM moyenne volatilité minimale sur 10 jours
if today<>today[1] then//if opendate<>opendate[1] then
 $memo[lastset($memo)+1]=volatmin
endif
if lastset($memo)>=10 then
 Volatcumu=0
 For i= lastset($memo)-9 to lastset($memo)
  Volatcumu= Volatcumu+$memo[i]
 next
 VolatMoy=Volatcumu/10
endif

REM Définition des limites des 2 zones décrites plus haut:
ZoneUP= dopen(0)+VolatMoy
ZoneDN= dopen(0)-VolatMoy
valup=round(zoneup,5)
valdn=round(zonedn,5)
ouverture=round(dopen(0),5)

if intradaybarindex=0 or day<>day[1] then
startbar=barindex
startprice=open
endif

if islastbarupdate then
ALPHAfond=25
drawrectangle(startbar,startprice,barindex,zoneup) coloured(0,204,0,ALPHAfond) bordercolor(0,0,0,20)
DRAWTEXT("#valup#",BARINDEX-3,valup+1*iatr,SansSerif,Bold,14) coloured(51,102,255)
drawrectangle(startbar,startprice,barindex,zonedn) coloured(255,51,51,ALPHAfond) bordercolor(0,0,0,20)
DRAWTEXT("#valdn#",BARINDEX-3,valdn-1*iatr,SansSerif,Bold,14) coloured(204,0,0)
DRAWTEXT("#ouverture#",BARINDEX-3,ouverture-1*iatr,SansSerif,Bold,14) coloured(0,0,0)
endif

return

C’est curieux en effet, les éléments graphiques (rectangles et textes) ne s’affiche qu’une fois puis disparaisse lors d’une nouvelle bougie, pourtant les valeurs coordonnées sont bien présentes. Je vais continuer à chercher pour comprendre pouquoi.

Pour reproduire, voici ma version:

defparam drawonlastbaronly=true

texte=1
iatr=average[100](tr)
ALPHAfond=max(1,alphafond)
alphafond=75
decalagetexte=5

timeframe(daily)
REM TRUE RANGE
amax=max(close[1],high[0])
amin=min(close[1],low[0])
 
REM Calcul Volatilité journalière minimale par rapport à l'ouverture
volathaute=amax[1]-open[1] // calcul de la volatilité au dessus de l’ouverture de la veille.
volatbasse=open[1]-amin[1] // calcul de la volatilité en dessous de l’ouverture de la veille.
volatmin=min(volatbasse,volathaute) // on veut la plus petite des deux
 
REM moyenne volatilité minimale sur 10 jours
VolatMoy=average[10](volatmin) // on fait la moyenne sur 10 jours de la volatilité minimum des jours de trading précédent la séance en cours.
 
REM Définition des limites des 2 zones décrites plus haut:
ZoneUP= open+VolatMoy
ZoneDN= open-VolatMoy
  
valup=round(zoneup,2)
valdn=round(zonedn,2)
ouverture=round(dopen(0),2)

timeframe(default)
if intradaybarindex=0 or day<>day[1] then
startbar=barindex
startprice=open
endif

if islastbarupdate then
drawrectangle(startbar,startprice,barindex,zoneup) coloured(0,204,0,ALPHAfond) bordercolor(0,0,0,20)
drawrectangle(startbar,startprice,barindex,zonedn) coloured(255,51,51,ALPHAfond) bordercolor(0,0,0,20)
IF TEXTE THEN
DRAWTEXT("#valup#",BARINDEX+decalagetexte,valup,SansSerif,Bold,10) coloured(51,102,255)
DRAWTEXT("#valdn#",BARINDEX+decalagetexte,valdn,SansSerif,Bold,10) coloured(204,0,0)
DRAWTEXT("#ouverture#",BARINDEX+decalagetexte,ouverture,SansSerif,Bold,10) coloured(0,0,0)
ENDIF
endif

return barindex,startbar,startprice,zoneup,zonedn