// https://www.prorealcode.com/prorealtime-indicators/fractals-zigzag/
// credits: Nicolas @ prorealcode.com
//---external parameters
cp = 10 // candle period
// === added begin
Cmultiplier = 2 // multiplier for user adjustment
// === added end
once lastpoint = 0
// === added begin
once Atop = 0 // define starting values for calc
once Bbottom = 0 // we need at least A and B
once Ctop = 0 // for further calc we need more
once NeedNewA = 0 // starting values for value markers
once NeedNewB = 0 // 0=0 1=1
once NeedNewC = 0
x = cp*3 // the x, assuming a simple calc
// === added end
if high[cp] >= highest[2*cp+1](high) then
LH = 1
else
LH = 0
endif
if low[cp] <= lowest[2*cp+1](low) then
LL = -1
else
LL = 0
endif
if LH = 1 then
TOPy = high[cp] // value of High
TOPx = barindex[cp] // barindex of High
endif
if LL = -1 then
BOTy = low[cp] // value of Low
BOTx = barindex[cp] // barindex of Low
endif
if LH>0 and (lastpoint=-1 or lastpoint=0) then // last one was a Low
DRAWSEGMENT(lastX,lastY,TOPx,TOPy) COLOURED(200,0,0,255) // red line
// DRAWTEXT("■",TOPx,TOPy,Dialog,Bold,20) coloured(200,0,0,255) // red square
lastpoint = 1 // set marker that last one was a High
lastX = TOPx // postion on time axis
lastY = TOPy // value on price axis
// === added begin
IF Atop=0 OR NeedNewA=0 THEN
Atop=TOPy // == save calc value for the A top
AtopIndex=TOPx // == for exact drawing position
DRAWTEXT("Atop",AtopIndex,Atop,Dialog,Bold,10) coloured(200,0,0,255)
NeedNewB=0 // == marker that we need a new B bottom value next
NeedNewC=0 // == marker that we need a new C top value after that
NeedNewA=1 // == marker that the next top will not be A (but C)
ELSIF Ctop=0 OR NeedNewC=0 THEN
Ctop=TOPy // == save calc value for the C top
CtopIndex=TOPx
DRAWTEXT("Ctop",CtopIndex,Ctop,Dialog,Bold,10) coloured(200,0,0,255)
NeedNewB=0 // == marker that we need a new B bottom value next
NeedNewA=0 // == marker that the next top will be A (and not C)
NeedNewC=1 // == marker that we are done with C
// === now we might have all A,B,C values
IF Atop<>0 AND Bbottom<>0 AND Ctop<>0 THEN // we have all 3 values we need for calc
Aval=ABS(Atop-Bbottom) // the range a
Bval=ABS(Bbottom-Ctop) // the range b
// === calculating some c stuff value
Cval=Ctop+(Aval+Bval*Cmultiplier)
DRAWSEGMENT(CtopIndex-6,Cval,CtopIndex,Cval) COLOURED(0,0,255)
// // calculationg somd d stuff value
Dval=Cval-x*Cmultiplier
DRAWSEGMENT(CtopIndex-3,Dval,CtopIndex,Dval) COLOURED(255,0,255)
ENDIF
ENDIF
// === added end
endif
if LL<0 and (lastpoint=1 or lastpoint=0) then // last one was a High
DRAWSEGMENT(lastX,lastY,BOTx,BOTy) COLOURED(0,200,0,255) // green line
// DRAWTEXT("■",BOTx,BOTy,Dialog,Bold,20) coloured(0,200,0,255) // green square
lastpoint = -1 // set marker that last one was a Low
lastX = BOTx // postion on time axis
lastY = BOTy // value on price axis
// === added begin
IF Bbottom=0 OR NeedNewB=0 THEN
Bbottom=BOTy
BbottomIndex=BOTx
DRAWTEXT("Bbottom",BbottomIndex,Bbottom,Dialog,Bold,10) coloured(0,200,0,255)
NeedNewB=0 // == marker that the next bottom will also be a B value
ENDIF
// === added end
endif
RETURN
.
