I call it Pseudo stochastic because I sue the same period for calculate the three variables that define the stochastic.

//STOCHASTIC TRADE v1.0
//Autor: LEO

DEFPARAM CumulateOrders = false // Cumulating positions deactivated
DEFPARAM PreLoadBars = 10000 //cargar informacion

//VARIABLES TO BE OPTIMIZED
//Ps=21 //preiod for stochastic values
//Slevel= 20 //stochastic signal
//Pactive=3 //bars after stochastic signals
//Kp=2 // Profit target to Kp times the stop loss
//Psma=200 //Period for a SimpleMoving Average


maxrisk0=20 //pips per trade to risk

n=1
maxrisk=maxrisk0+(n-1)*2
totalrisk=10*maxrisk*PIPVALUE //for stop the robot if things are going bad


spread=0.7
IF TIME < 060000 THEN //(germany time)
spread=1.7*spread
ELSIF TIME>214500 THEN //(germany time)
spread=1.7*spread
ENDIF

//Robot Working Time (Germany)
IF TIME>050000 and TIME < 220000 THEN
ontime=1
ELSE
ontime=0
ENDIF

////// RISK CONTROL IF THINGS ARE GOING WONDERFULL  //////
//n = 1 + (strategyprofit / (77*pipvalue))
//n = round(n * 100)
//n = n / 100
//n = max(1,n)

//--------------------------------------------------------
//>>>>>>>>>>>>>>>>>>     INDICATORS    <<<<<<<<<<<<<<<<<<<<<
//--------------------------------------------------------


SMA=average[Psma](close)
TYPICALDAY=(DHIGH(1)+DLOW(1)+Dclose(1))/3

mystoch=Stochastic[Ps,Ps](close)
StochD=Average[Ps](myStoch)


//--------------------------------------------------------
//>>>>>>>>>>>>>>>>>>     TRADING     <<<<<<<<<<<<<<<<<<<<<
//--------------------------------------------------------

a0=myStoch crosses over StochD
a1=highest[Pactive](a0)=1
a2=lowest[Pactive+1](mystoch) < Slev
a3=close > TYPICALDAY
a4=close > SMA


If a1 and a2 and a3 and a4 then
IF NOT LongOnMarket AND ontime=1 and DayOfWeek <= 5 THEN
//entrylong=high+0.5*spread*pipsize
stoplosslong=(close-lowest[Ps](low))/pipsize+spread
stoplosslong=min(stoplosslong,maxrisk)
BUY n CONTRACTS AT market//entrylong STOP
SET STOP pLOSS stoplosslong
SET TARGET pPROFIT Kp*stoplosslong
ENDIF
ENDIF

b0=myStoch crosses under StochD
b1=highest[Pactive](b0)=1
b2=highest[Pactive+1](mystoch) > 100-Slev
b3=close < TYPICALDAY
b4=close<SMA

IF b1 and b2 and b3 and b4 then
//entryshort=low-0.5*spread*pipsize
stoplossshort= (highest[Ps](high)-close)/pipsize+spread
stoplossshort= min(stoplossshort, maxrisk)
IF NOT ShortOnMarket AND ontime=1 and DayOfWeek <= 5 THEN
SELLSHORT n CONTRACTS AT market //entryshort STOP
SET STOP pLOSS StopLossShort
SET TARGET pPROFIT Kp*StopLossShort
ENDIF
ENDIF

//---------------------------------------------------------
//>>>>>>>>>>>>>>>>>>   EXIT POSITIONS    <<<<<<<<<<<<<<<<<<
//---------------------------------------------------------

mySAR=SAR[0.007,0.007,0.7]
// ---> exit long
IF longonmarket then

IF close < lowest[Ps](low[1]) THEN
SELL AT MARKET
ENDIF

IF close crosses under MySAR THEN
SELL AT MARKET
ENDIF

IF b0 and close>POSITIONPRICE THEN
SELL AT MARKET
ENDIF

IF close > (POSITIONPRICE+0.5*stoplosslong*pipsize) and close>mySAR then
SET STOP pLOSS min((close-MySAR)/pipsize+2*spread, maxrisk)
ENDIF

IF TIME > 224500 and DayOfWeek=5 then
SELL AT MARKET
ENDIF
endif

// ---> exit long
IF shortonmarket then

IF close > highest[Ps](high[1])  THEN
EXITSHORT AT MARKET
ENDIF

IF close crosses over MySAR THEN
EXITSHORT AT MARKET
ENDIF

IF a0 and close < POSITIONPRICE then
EXITSHORT AT MARKET
ENDIF

IF close < (POSITIONPRICE-0.5*StopLossShort*pipsize) and close<mySAR then
SET STOP pLOSS min( (MySAR-close)/pipsize+2*spread , maxrisk)
ENDIF

IF TIME > 224500 and DayOfWeek=5 then
EXITSHORT AT MARKET
ENDIF
endif

//Quit the robot if things are going bad
Q=MAX(Q,(STRATEGYPROFIT/pipvalue/n))
R=Q-STRATEGYPROFIT/pipvalue/n
IF R > totalrisk THEN
QUIT
ENDIF

IF STRATEGYPROFIT < (-1*totalrisk) THEN
QUIT
ENDIF

Screen-Shot-2018-02-23-at-22.32.08.png