El manual dice que puedes usar:

SET STOP LOSS sl pTRAILING tl

pero en realidad solo puede hacerlo en backtests, NO en autotrading, ya que no puede escribir dos tipos diferentes de stop loss en la misma línea.

Necesitas usar uno de estos dos:

SET STOP pLOSS sl      //or SET STOP LOSS sl
SET STOP pTRAILING tl  //or SET STOP TRAILING tl

si usa ambos, la segunda línea anulará la primera, ya que el código se lee secuencialmente de arriba a abajo.

Agregue, al final de su código, este escrito por Nicolás (lo modifiqué ligeramente para que los puntos se guardaran en el punto de breakeven).

Solo tienes que poner los valores que prefieras a los tres parámetros:

• trailingstart
• trailingstep
• PointsToKeep

//*********************************************************************************
// https://www.prorealcode.com/blog/trading/complete-trailing-stop-code-function/
// (lines 17- 56)
//
//trailing stop function
trailingstart = 20   //trailing will start @trailinstart points profit
trailingstep  = 5    //trailing step to move the "stoploss"
PointsToKeep  = 2    //keep rhese points when it is first triggered
 
//reset the stoploss value
IF NOT ONMARKET THEN
 newSL=0
ENDIF
 
//manage long positions
IF LONGONMARKET THEN
//first move (breakeven)
 IF newSL=0 AND (close-tradeprice(1)) >= trailingstart*pipsize THEN
  newSL = tradeprice(1)+PointsToKeep*pipsize
 ENDIF
//next moves
 IF newSL>0 AND close-newSL>=trailingstep*pipsize THEN
  newSL = newSL+trailingstep*pipsize
 ENDIF
ENDIF
 
//manage short positions
IF SHORTONMARKET THEN
//first move (breakeven)
 IF newSL=0 AND tradeprice(1)-close>=trailingstart*pipsize THEN
  newSL = tradeprice(1)-PointsToKeep*pipsize
 ENDIF
//next moves
 IF newSL>0 AND newSL-close>=trailingstep*pipsize THEN
  newSL = newSL-trailingstep*pipsize
 ENDIF
ENDIF
 
//stop order to exit the positions
IF newSL>0 THEN
 SELL AT newSL STOP
 EXITSHORT AT newSL STOP
ENDIF
//*********************************************************************************

Te invito a releer el post  https://www.prorealcode.com/topic/proorder-no-permite-el-uso-de-stops-combinados/#post-201795.

Esto funciona:

DEFPARAM CumulateOrders = False

// quitado filtro horario: AND Time > 143000 AND Time < 220000

periodos = 100
lotes    = 1
sl       = 50
tp       = 150

// Condiciones para entrada de posiciones largas
IF NOT LongOnMarket AND Open < ExponentialAverage[periodos](Close) AND Close > ExponentialAverage[periodos](Close) THEN
BUY lotes CONTRACTS AT MARKET
SET STOP LOSS sl
SET TARGET pPROFIT tp
ENDIF

// Condiciones de entrada de posiciones cortas
IF NOT ShortOnMarket AND Open > ExponentialAverage[periodos](Close) AND Close < ExponentialAverage[periodos](Close) THEN
SELLSHORT lotes CONTRACTS AT MARKET
SET STOP LOSS sl
SET TARGET pPROFIT tp
ENDIF
//
//*********************************************************************************
// https://www.prorealcode.com/blog/trading/complete-trailing-stop-code-function/
// (lines 17- 56)
//
//trailing stop function
trailingstart = 20   //trailing will start @trailinstart points profit
trailingstep  = 5    //trailing step to move the "stoploss"
PointsToKeep  = 2    //keep rhese points when it is first triggered
 
//reset the stoploss value
IF NOT ONMARKET THEN
newSL=0
ENDIF
 
//manage long positions
IF LONGONMARKET THEN
//first move (breakeven)
IF newSL=0 AND (close-tradeprice(1)) >= trailingstart*pipsize THEN
newSL = tradeprice(1)+PointsToKeep*pipsize
ENDIF
//next moves
IF newSL>0 AND close-newSL>=trailingstep*pipsize THEN
newSL = newSL+trailingstep*pipsize
ENDIF
ENDIF
 
//manage short positions
IF SHORTONMARKET THEN
//first move (breakeven)
IF newSL=0 AND tradeprice(1)-close>=trailingstart*pipsize THEN
newSL = tradeprice(1)-PointsToKeep*pipsize
ENDIF
//next moves
IF newSL>0 AND newSL-close>=trailingstep*pipsize THEN
newSL = newSL-trailingstep*pipsize
ENDIF
ENDIF
 
//stop order to exit the positions
IF newSL>0 THEN
SELL AT newSL STOP
EXITSHORT AT newSL STOP
ENDIF
//*********************************************************************************
graphonprice TradePrice
graphonprice NewSL      coloured(255,0,0,255)