“Mi aspettavo che gli ordini inseriti con ProOrder, una volta a mercato si presentassero allo stesso modo degli ordini fatti a mano e
potessero essere gestiti anche manualmente dalla piattaforma. Non è così?”
– Si, si presentano uguali, nel senso che sulla piattaforma del Broker li vedi allo stesso modo, mentre su ProRealTime li vedi diversamente perché quelli automatici, una volta a mercato vanno fuori dal controllo diretto di ProRealTime
– Puoi gestirli manualmente dalla piattaforma del Broker, non di ProRealTime (per il motivo anzidetto), puoi chiuderli, cambiare stop e target. PERO’ a quel punto ProOrder ne perde tutto il controllo e proseguono solo manualmente, quindi dovrai gestirle tu e la piattaforma NON saprà mai il risultato ottenuto.

“Vorrei quindi poter i poter vedere sul grafico su cui ho collegato il trading system alcune INFORMAZIONI per esempio un livello,
un testo, ….”
Le strategie NON possono stampare, né emettere avvisi, ecc…
Però puoi farti un indicatore, che dovrà essere la copia esatta della strategia, dove dovrai togliere tutte le istruzioni per gli ordini, stop e target e fargli visualizzare quello che desideri. Ovviamente se dopo un pò di tempo cambierai qualcosa nella strategia, dovrai ricordarti di cambiare anche l’indicatore, altrimenti non combaceranno i dati.

Questo è un esempio di una strategia e, più sotto, della stessa trasformata in indicatore. Siccome gli indicatori NON possono usare le stesse istruzioni di ProOrder, a queste istruzioni ho semplicemente aggiunto una X maiuscola alla fine e devo essere io a farmi carico di segnalare che è OnMarket o LongOnMarket, ecc…:

c1 = Average[15,0](close) CROSSES OVER  Average[30,0](close)
c2 = Average[15,0](close) CROSSES UNDER Average[30,0](close)
IF not OnMarket and c1  THEN
   BUY 1 Contract AT MARKET
   set stop   %loss   0.5
   set target %profit 1.0
ENDIF
IF not OnMarket and c2 THEN
   SELLSHORT 1 Contract AT MARKET
   set stop   %loss   0.5
   set target %profit 1.0
ENDIF

ONCE OnMarketX      = 0
ONCE LongOnMarketX  = 0
ONCE ShortOnMarketX = 0
ONCE TP             = close
ONCE SL             = close
ONCE t              = 255
// Uscita Long  in STOP o in PROFITTO
IF LongOnMarketX THEN
   IF high >= TP THEN
      DrawText("TP",BarIndex,TP + range*2,dialog,bold,15) coloured("Green",t)
      OnMarketX      = 0
      LongOnMarketX  = 0
      t              = 255
   ENDIF
   IF low <= SL THEN
      DrawText("SL",BarIndex,SL - range*2,dialog,bold,15) coloured("Red",t)
      OnMarketX      = 0
      LongOnMarketX  = 0
      t              = 255
   ENDIF
ENDIF
// Uscita Short in STOP o in PROFITTO
IF ShortOnMarketX THEN
   IF high >= SL THEN
      DrawText("SL",BarIndex,TP + range*2,dialog,bold,15) coloured("Red",t)
      OnMarketX      = 0
      ShortOnMarketX = 0
      t              = 255
   ENDIF
   IF low <= TP THEN
      DrawText("TP",BarIndex,SL - range*2,dialog,bold,15) coloured("Green",t)
      OnMarketX      = 0
      ShortOnMarketX = 0
      t              = 255
   ENDIF
ENDIF
// condizioni
c1 = Average[15,0](close) CROSSES OVER  Average[30,0](close)
c2 = Average[15,0](close) CROSSES UNDER Average[30,0](close)
// Entrata LONG
IF not OnMarketX and c1   THEN
   OnMarketX      = 1
   LongOnMarketX  = 1
   ShortOnMarketX = 0
   Entrata        = close
   SL             = Entrata * 0.995
   TP             = Entrata * 1.010
   t              = 255
   DrawText("♢",BarIndex+1,close + range*4,dialog,bold,25) coloured("Cyan",t)
ENDIF
// Entrata SHORT
IF not OnMarketX and c2  THEN
   OnMarketX      = 1
   ShortOnMarketX = 1
   LongOnMarketX  = 0
   Entrata        = close
   TP             = Entrata * 0.990
   SL             = Entrata * 1.005
   t              = 255
   DrawText("♢",BarIndex+1,close - range*4,dialog,bold,25) coloured("Gold",t)
ENDIF
RETURN TP AS "Target Profit" coloured("Green",t),SL AS "StopLoss" coloured("Red",t)

ovviamente i dati relativi all’entrata, allo stop loss ed al take profit saranno leggermente diversi perché ProBackTest considera anche un certo slippage, mentre l’indicatore no.

L’indicatore mettilo SUL grafico dei prezzi, non sotto.