Ciao. Ecco una prima parte. Se calcola il POC di 8 giorni e poi cerca i valori che crucen por debajo del POC.

//-----Inputs-------------------------------------------//
res=15
//------------------------------------------------------//
//-----Calculate 8 days --------------------------------//
once plook=40
if intradaybarindex=0 and countDay<7 then
countDay=countDay+1
bars=bars+1
elsif intradaybarindex=0 and countDay>=7 then
plook=bars
countDay=0
bars=0
else
bars=bars+1
endif
//------------------------------------------------------//
//-----Create arrays for High, Low and volume-----------//
maxx = highest[plook](high)
minn = lowest[plook](low)
step = (maxx-minn)/res //height of the rectangle
//------------------------------------------------------//
//-----Calculation POC----------------------------------//
for i=0 to res-1 do
volsize=0
mybot=minn+(i*step)
mytop=minn+((i+1)*step)
$bottomboundaries[i]=mybot
$topboundaries[i]=mytop
for j=0 to plook-1 do
if close[j]>=mybot and close[j]<=mytop then
volsize=volsize+volume[j]
endif
next
$VolLen[i]=volsize
next

for k=0 to res-1 do
if $VolLen[k]=ArrayMax($VolLen) then
x = k
break
endif
next

poc = ($topboundaries[x]+$bottomboundaries[x])/2

screener[close crosses under poc]