Ci-dessous une demande qui a été envoyée à ProRealTime :
Bonjour,
Je voudrais vous demander de coder ce système de trading pour autant que tous les critères soit effectivement codable.
Essentiellement pour du trading Forex en H1 sur EURUSD.
Indicateur: Ichimoku Kinko Hyo (Paramètre par défaut)
RSI 4 : Niveau 60-40-75-25
ATR 20.
Condition D’achat:
Le RSI 4 Donne les entrées de cette façon: RSI 4 passe SOUS le niveau 25
RSI 4 Repasse AU-DESSUS de 40.
( Le signal d’achat est donné lorsque le RSI passe sous 25 AVANT de repasser le niveau 40 à la hausse )
A la Clôture de la bougie qui donne le signal:
Le PRIX doit être SUPERIEUR à Senkou Span A et B.
Le PRIX doit être SUPERIEUR à KijunSen ET TenkanSen
CHIKOU doit être SUPERIEUR Au prix de clôture de la bougie sur laquelle il se trouve
Type d’Ordre: AU MARCHE ( Toujours )
Quantité: 20 x 1000 ( forex )
Objectif et Stop Loss:
Le stop est = 3 fois l’ATR20 de la bougie signal. ( Ou de celle qui la précède si ce n’est pas codable )
L’Objectif est = 6 fois l’ATR20 de la bougie signal. ( Ou de celle qui la précède si ce n’est pas codable )
Breakeven dés que 3 fois ATR20 Atteint.
Condition de Vente:
Le RSI 4 Donne les entrées de cette façon: RSI 4 passe AU DESSUS du niveau 75
RSI 4 Repasse EN DESSOUS de 60.
( Le signal de Vente est donné lorsque le RSI passe au-dessus de 75 AVANT de repasser le niveau 60 à la baisse )
A la Clôture de la bougie qui donne le signal:
Le PRIX doit être INFERIEUR à Senkou Span A et B.
Le PRIX doit être INFERIEUR à KijunSen ET TenkanSen
CHIKOU doit être INFERIEUR Au prix de Clôture de la bougie sur laquelle il se trouve
Type d’Ordre: AU MARCHE ( Toujours )
Quantité: 20 x 1000 ( forex )
Objectif et Stop Loss:
Le stop est = 3 fois l’ATR20 de la bougie signal. ( Ou de celle qui la précède si ce n’est pas codable )
L’Objectif est = 6 fois l’ATR20 de la bougie signal. ( Ou de celle qui la précède si ce n’est pas codable )
Breakeven dès que 3 fois ATR20 Atteint.
Et une proposition de réponse:
MyRSI=RSI[4](close)
MyATR=AverageTrueRange[20](close)
SSA=SenkouSpanA[9,26,52]
SSB=SenkouSpanB[9,26,52]
Kijun=KijunSen[9,26,52]
Tenkan=TenkanSen[9,26,52]
if MyRSI crosses under 25 then
c1=1
endif
c2=MyRSI crosses over 40
c3=close > max (SSA,SSB)
c4=close > max (Kijun,Tenkan)
c5=close > close[26]
if c1 and c2 then
if c3 and c4 and c5 then
buy 20 shares at market
set stop loss 3*MyATR
set target profit 6*MyATR
LongATR=MyATR
endif
c1=0
endif
If Longonmarket then
if LongBreakeven=0 and close >= tradeprice+3*LongATR then
LongBreakeven=1
elsif LongBreakeven=1 then
sell at tradeprice stop
endif
else
LongBreakeven=0
endif
if MyRSI crosses over 75 then
c6=1
endif
c7=MyRSI crosses under 60
c8=close < min (SSA,SSB)
c9=close < min (Kijun,Tenkan)
c10=close < close[26]
if c6 and c7 then
if c8 and c9 and c10 then
sellshort 20 shares at market
set stop loss 3*MyATR
set target profit 6*MyATR
ShortATR=MyATR
endif
c6=0
endif
If SHORTONMARKET then
if ShortBreakeven=0 and close <= tradeprice-3*ShortATR then
ShortBreakeven=1
elsif ShortBreakeven=1 then
exitshort at tradeprice stop
endif
else
ShortBreakeven=0
endif
