Bonjour,
Je cherche le code pour trouver le plus haut des volumes de la veille et de J-2 sur une unité de temps différente du daily (exemple M5 ou M15).
J’ai trouvé pour le plus haut du jour : Highest[intradaybarindex+1](volume) mais je sèche pour le reste… Help, please!
Bjr,
Tu peux essayer avec:
if intradaybarindex<intradaybarindex[1] then
VolMaxJmoins2 = VolMaxJmoins1
VolMaxJmoins1 = VolMaxJ
endif
VolMaxJ = Highest[intradaybarindex+1](volume)
Attention, il faut que dans l’unité inférieure utilisée, l’historique en chandeliers soit suffisant (en général on trouve 256 pour PRT complete, 1024 pour PRT premium) pour avoir le jour, la veille et l’avant-veille.
Merci pour ta réponse. J’avoue avoir du mal à comprendre la formule et du coup je ne vois pas trop comment l’intégrer dans mon code. J’en aurais besoin pour remplacer ma définition du plus haut volume sur les 3 derniers jours que je traduis par : VMAX = Highest[100](myvolume) où 100 barres correspondent à peu près à 3 jours en M15. As-tu une idée de comment intégrer ta formule dans mon code ?
// Liste des titres dont le plus haut des volumes du jour casse le plus haut des 3 derniers jours en M15
TIMEFRAME(15mn)
// Définition du volume sans la clôture "myvolume"
// pour éviter le pic de volume de la clôture qui écrase le graphe
IF opentime < 173000 THEN
myvolume = volume
ELSE
myvolume = average[100](volume)
ENDIF
// Définition du +H volume sur les 3 derniers jours "VMAX"
VMAX = Highest[100](myvolume)
// Définition du +H volume du jour "VJour"
VJour = Highest[intradaybarindex+1](myvolume)
// Critère à afficher
IF VJour >= VMAX THEN
Criteria = 1
ELSE
Criteria = 0
ENDIF
SCREENER (Criteria AS "Max")
Si chercher les plus hauts volumes des 2 jours précédents est fait pour remplacer Vmax, et si je remplace le nom VolMaxJ par VJour, alors on obtient ceci (avec aussi modification de la dernière ligne “screener” pour ajouter entre [ ] le critère de screen, puisque la partie entre ( ) ne fait que la mise en ordre pas la sélection):
// Liste des titres dont le plus haut des volumes du jour casse le plus haut des 3 derniers jours en M15
TIMEFRAME(15mn)
// Définition du volume sans la clôture "myvolume"
// pour éviter le pic de volume de la clôture qui écrase le graphe
IF opentime < 173000 THEN
myvolume = volume
ELSE
myvolume = average[100](volume)
ENDIF
// Définition du +H volume sur les 3 derniers jours "VMAX"
//VMAX = Highest[100](myvolume)
// Définition du +H volume du jour "VJour"
if intradaybarindex<intradaybarindex[1] then
VolMaxJmoins2 = VolMaxJmoins1
VolMaxJmoins1 = VJour
endif
VJour = Highest[intradaybarindex+1](myvolume)
VMAX = max(VolMaxJmoins1,VolMaxJmoins2)
// Critère à afficher
IF VJour >= VMAX THEN
Criteria = 1
ELSE
Criteria = 0
ENDIF
SCREENER[Criteria](Criteria AS "Max")
