What is / are  the other Timeframe(s) in your code?

If it were me I would updateonclose  or not use updateonclose depending on which gives the ‘best’ results taking all performance factors into account?

Maybe if you post an equity curve with positions under equity curve and price curve under positions then we might be able advise somethng moe meaningful?

It’s a personal choice, whether to use signals while a candle is being formed or wait for its closing.

That’s what MTF is for, before that you could only wait for its closing, now you have a choice.

I prefer waiting the closing to enter a position and use the live data to confirm it. This code will enter on a SMA crossover, on a 4h-timefrane, provided on the Daily TF the SMA is currently rising. You may use it on a 4h-timeframe or lower:

DEFPARAM CumulateOrders = False
//
Timeframe(Daily,default)
SmaD = average[20,0](close)
//
Timeframe(4h,UpdateOnClose)
Sma4 = average[20,0](close)
IF (close CROSSES OVER Sma4) AND (SmaD > SmaD[1]) THEN
BUY AT MARKET
SET TARGET pPROFIT 300
SET  STOP  pLOSS   150
ENDIF
//
Timeframe(default)
//*********************************************************************************
// https://www.prorealcode.com/blog/trading/complete-trailing-stop-code-function/
// (lines 17- 56)
//
//trailing stop function
trailingstart = 10   //trailing will start @trailinstart points profit
trailingstep  = 1    //trailing step to move the "stoploss"
 
//reset the stoploss value
IF NOT ONMARKET THEN
newSL=0
ENDIF
 
//manage long positions
IF LONGONMARKET THEN
//first move (breakeven)
IF newSL=0 AND close-tradeprice(1)>=trailingstart*pipsize THEN
newSL = tradeprice(1)+trailingstep*pipsize
ENDIF
//next moves
IF newSL>0 AND close-newSL>=trailingstep*pipsize THEN
newSL = newSL+trailingstep*pipsize
ENDIF
ENDIF
 
//manage short positions
IF SHORTONMARKET THEN
//first move (breakeven)
IF newSL=0 AND tradeprice(1)-close>=trailingstart*pipsize THEN
newSL = tradeprice(1)-trailingstep*pipsize
ENDIF
//next moves
IF newSL>0 AND newSL-close>=trailingstep*pipsize THEN
newSL = newSL-trailingstep*pipsize
ENDIF
ENDIF
 
//stop order to exit the positions
IF newSL>0 THEN
SELL AT newSL STOP
EXITSHORT AT newSL STOP
ENDIF
//*********************************************************************************