Voilà le code en question, j’ai placé des flèches pour visualiser les breakouts (dépassement) des plus hauts et bas formés par les moyennes de Hull (matérialisés en lignes pointillés).

period = 20

hullma = Weightedaverage[round(SQRT(period))]( 2*Weightedaverage[round(period/2)](close)-Weightedaverage[period](close))

bottom = hullma>hullma[1] and hullma[1]<hullma[2]
top = hullma<hullma[1] and hullma[1]>hullma[2]

//plus bas HullMA
if bottom then 
ll = lowest[max(1,barindex-llbar)](hullma)
llbar = barindex
r=0
g=255
endif
//plus haut HullMA
if top then 
hh = highest[max(1,barindex-hhbar)](hullma)
hhbar = barindex
r=255
g=0
endif

signal=0
//croise à la baisse le plus bas 
if hullMA crosses under ll then 
signal=-1
drawarrowdown(barindex,hullma+averagetruerange[14]/2) coloured(r,g,0)
endif
//croise à la hausse le plus haut 
if hullMA crosses over hh then
signal=1
drawarrowup(barindex,hullma-averagetruerange[14]/2) coloured(r,g,0)
endif

return hullma coloured(r,g,0), hh style(dottedline), ll style(dottedline), signal style(histogram)

Si tu veux les signaux en histogramme sous le graphique, il faut modifier la dernière ligne du code par :

return signal coloured(r,g,0) style(histogram)

La période de la MM de Hull se règle en tête de code avec la variable “period”.

hullma-highest-high-and-lowest-low-breakout.png