Questa è una semplice strategia che puoi lanciare in autotrading (SL e TP elevati perché fatta sul Dax Daily):

DEFPARAM CumulateOrders = FALSE
IF close CROSSES OVER  Average[100,0](close) AND Not LongOnMarket  THEN
   BUY       1 Contract at Market
   SET TARGET pPROFIT 1000
   SET STOP   pLOSS   300
ENDIF
IF close CROSSES UNDER Average[100,0](close) AND Not ShortOnMarket THEN
   SELLSHORT 1 Contract at Market
   SET TARGET pPROFIT 1000
   SET STOP   pLOSS   300
ENDIF

questa è la stessa, sotto forma d’indicatore da mettere sul prezzo. Stampa una linea blu al livello di entrata a mercato quando è Long, rossa quando è Short (niente quando non è a mercato):

r = 0
g = 0
b = 255
t = 255
// LONG
IF close CROSSES OVER  Average[100,0](close) AND Not IamLong  THEN
   IamLong  = 1
   IamShort = 0
   EntryPrice = close
ENDIF
// SHORT
IF close CROSSES UNDER Average[100,0](close) AND Not IamShort THEN
   IamLong  = 0
   IamShort = 1
   EntryPrice = close
ENDIF
// Tp o Sl LONG
IF IamLong THEN
   IF ((close - EntryPrice)  >= 1000) OR ((EntryPrice - close) >= 300) THEN
      IamLong  = 0
   ENDIF
ENDIF
// Tp o Sl SHORT
IF IamShort THEN
   IF ((close - EntryPrice)  >= 300) OR ((EntryPrice - close) >= 1000) THEN
      IamShort = 0
   ENDIF
ENDIF
//
IamOnMarket = IamLong OR IamShort
IF IamShort THEN
   r = 255
   b = 0
ENDIF
//
IF Not IamOnMarket THEN
   EntryPrice = close
   t = 0
ENDIF
RETURN EntryPrice COLOURED(r,g,b,t) STYLE(line,2) AS "EntryPrice"

x-4.jpg