Bitte starten Sie für jede Frage ein neues Thema, das keinen Bezug zu anderen bestehenden hat. Danke 🙂

Ich werde es so schnell wie möglich überprüfen.

Versuchen Sie dies, es scheint mir, dass es funktioniert:

ONCE Capital    = 10000  //10000€ initial Capital
ONCE Investment = 5      //5%     max Investment for each trade
ONCE MinLots    = 0.5    //0.5    min lot size (Dax)
ONCE Margin     = 5      //5%     Margin required by the broker for each lot
IF (StrategyProfit = 0) OR (Not OnMarket AND OnMarket[1]) THEN
   Invested        = Capital * Investment / 100 / PipValue
   CurrentMargin   = close * Margin / 100
   TempLots1       = Capital / CurrentMargin
   TempLots2       = round(((Invested / CurrentMargin) * 10) - 0.5) / 10  //round to 1 decimal digit
   PositionSize    = max(MinLots,TempLots2)  //never below the minimum lots
   MainSize        = PositionSize
ENDIF
ONCE MainSize   = PositionSize
ONCE LossSize   = MainSize
IF StrategyProfit < StrategyProfit[1] THEN
   LossSize     = LossSize + MainSize
   PositionSize = LossSize
ELSIF StrategyProfit > StrategyProfit[1] THEN
   PositionSize = MainSize
   LossSize     = PositionSize
ENDIF
c1 = DayOfWeek=1              // Day of Week = Montag
c2 = time=174500              // Buy on Monday at 17.45h Local Time Frankfurt
TIMEFRAME(daily)              // Switch to daily chart candles
c3 = close<average[34](close) // Close on Monday is below 34-Tg-SMA (daily-TF)
TIMEFRAME(default)            // Switch back to default TF (5m or 15m)
IF c1 AND c2 AND c3 THEN
   BUY Positionsize SHARES AT MARKET
ENDIF
exit1 = DayOfWeek = 3         // Exit on Wednesday at 09.00h
exit2 = time=090000
If LongOnMarket AND exit1 AND exit2 THEN
   sell at market
ENDIF
PCTgSL = 2.6
set stop %loss PCTgSL
PCTtp  = 2.3
set target %Profit PCTtp
//graph PositionSize
//graph StrategyProfit < Strategyprofit[1]
//graph LossSize
//graph MainSize

Ja, das sind die Zeilen 13-20, zusätzlich zu Zeile 11.