Here’s a nice simply strategy for the SP 1h, long only. WF is good, robustness reasonably good. 4 year backtest with MM is v nice.

Position size is €9, comparable margin to €1 on the DJ.

All suggestions welcome…

// Definition of code parameters
DEFPARAM CumulateOrders = false // Cumulating positions deactivated
DEFPARAM preloadbars = 5000

Capital = 10000
MinSize = 9                 //The minimum position size allowed for the instrument.
MM1stType = 0               //Starting type of moneymanagement. Set to 0 for level stakes. Set to 1 for increasing stake size as profits increase and decreasing stake size as profits decrease. Set to 2 for increasing stake size as profits increase with stake size never being decreased.
MM2ndType = 1               //Type of money management to switch to after TradesQtyForSwitch number of trades and ProfitNeededForSwitch profit has occurred
TradesQtyForSwitch = 5    //Quantity of trades required before switching to second money management choice.
ProfitNeededForSwitch = 2   //% profit needed before allowing a money management type change to MM2ndType.
DrawdownNeededToSwitch = 8 //% draw down from max equity needed before money management type is changed back to MM1stType.
DrawdownNeededToQuit = 25   //% draw down from max equity needed to stop strategy
 
Once MoneyManagement = MM1stType
 
Equity = Capital + StrategyProfit
maxequity = max(equity,maxequity)
 
if equity < maxequity * (1 - (DrawdownNeededToSwitch/100)) then
enoughtrades = 0
tradecount = 0
moneymanagement = MM1stType
endif
 
if equity < maxequity * (1 - (DrawdownNeededToQuit/100)) then
quit
endif
 
if not EnoughTrades then
if abs(countofposition) > abs(countofposition[1]) then
tradecount = tradecount + 1
endif
if tradecount > TradesQtyForSwitch and maxequity >= Capital * (1 + (ProfitNeededForSwitch/100)) then
EnoughTrades = 1
MoneyManagement = MM2ndType
endif
endif
 
IF MoneyManagement = 1 THEN
PositionSize = Max(MinSize, Equity * (MinSize/Capital))
ENDIF
 
IF MoneyManagement = 2 THEN
PositionSize = Max(LastSize, Equity * (MinSize/Capital))
LastSize = PositionSize
ENDIF
 
IF MoneyManagement <> 1 and MoneyManagement <> 2 THEN
PositionSize = MinSize
ENDIF
 
PositionSize = Round(PositionSize*100)
PositionSize = PositionSize/100
 
// Size of POSITIONS
PositionSizeLong = 1 * positionsize

TIMEFRAME(240minutes,updateonclose)
indicator2 = Average[6](typicalPrice)
indicator3 = Average[10](typicalPrice)
c1 = (indicator2 > indicator3)

TIMEFRAME(60 minutes,updateonclose)
indicator1 = SuperTrend[6,15]
c2 = (close > indicator1)

// Conditions to enter long positions
IF  c1 and c2  THEN
BUY PositionSizeLong CONTRACT AT MARKET
ENDIF
SET STOP %LOSS 2.2
SET TARGET %PROFIT 1.6

//trailing stop function
trailingstart = 30 //trailing will start @trailinstart points profit
trailingstep = 1 //trailing step to move the "stoploss"
 
//reset the stoploss value
IF NOT ONMARKET THEN
newSL=0
ENDIF
 
//manage long positions
IF LONGONMARKET THEN
//first move (breakeven)
IF newSL=0 AND close-tradeprice(1)>=trailingstart*pipsize THEN
newSL = tradeprice(1)+trailingstep*pipsize
ENDIF
//next moves
IF newSL>0 AND close-newSL>=trailingstep*pipsize THEN
newSL = newSL+trailingstep*pipsize
ENDIF
ENDIF
 
//manage short positions
IF SHORTONMARKET THEN
//first move (breakeven)
IF newSL=0 AND tradeprice(1)-close>=trailingstart*pipsize THEN
newSL = tradeprice(1)-trailingstep*pipsize
ENDIF
//next moves
IF newSL>0 AND newSL-close>=trailingstep*pipsize THEN
newSL = newSL-trailingstep*pipsize
ENDIF
ENDIF
 
//stop order to exit the positions
IF newSL>0 THEN
SELL AT newSL STOP
EXITSHORT AT newSL STOP
ENDIF

SP-1h-MADMEN-70-30.jpg SP-1h-MADMEN-VRT.jpg SP-1h-MADMEN-MM.jpg SP-1h-MADMEN.itf