Bonjour
Je voudrais sur prorealtime ,à la fois en screener et en indicateur, cette stratégie utilisant Keltner, Volume et Heikin Ashi (voir MT5 img )
——————————————————————————————-
Voici les indicateurs utilisés :
1> vol = indicateur volume tick
1a> avg_Vol = moyenne mobile simple de 50 périodes sur volume
2 > ema = moyenne mobile exponentielle de période 50
3 > atr = Average True Range de période 50
4 > K_Dn_Out = ema – 3.5*atr
5 > K_Up_Out = ema + 3.5*atr
6 > K_Dn_In = ema – 2.5*atr
7 > K_Up_In = ema + 2.5*atr
8 > HaC = Heikin Ashi Close
——————————————————————————–
==> signal d’achat
>HaC doit clôturer sous K_Dn_Out
>puis aux bougies suivantes , HaC doit clôturer au-dessus de K_Dn_In avec vol > avg_Vol
——————————————————————————–
==> signal de vente
>HaC doit clôturer au-dessus K_Up_Out
> puis aux prochaines bougies , HaC doit clôturer en-dessous de K_Up_In avec vol > avgVol
——————————————————————————–
Hola Aquí a l’indicateur. Il peut y avoir un maximum de 5 voiles pour produire la croix à l'intérieur ou à la base du KUpout ou du KDout. Sólo tienes que modificarlo a tu gusto.
//-------Heikin Ashi-----------------
once haopen=open
haclose=(open+close+high+low)/4
if barindex> 0 then
haopen=(haopen+haclose[1])/2
endif
halow=min(low,min(haclose,haopen))
hahigh=max(high,max(haclose,haopen))
if haclose > haopen then
r=0
g=250
else
r=250
g=0
endif
//----------------------------------
ema = average[50,1](haclose)
//----------------------------------
vol = volume
avgvol = average[50](vol)
//----------------------------------
atr = averagetruerange[50]
//------Bands-----------------------
kDnout = ema - 3.5*atr
KUpout = ema + 3.5*atr
KDnIn = ema - 2.5*atr
KUpIn = ema + 2.5*atr
//-----Long condition---------------//
n = barssince(haclose crosses under KDnOut)
longcondition = haclose crosses over KDnIn and n <= 5 and vol > avgvol
//-----Short condition--------------//
m = barssince(haclose crosses over KUpOut)
shortconidition = haclose crosses under KUpIn and m <=5 and vol > avgvol
if longcondition then
drawarrowup(barindex,halow-0.25*atr)coloured("green")
elsif shortconidition then
drawarrowdown(barindex,hahigh+0.25*atr)coloured("red")
endif
DRAWCANDLE(haopen, hahigh, halow, haclose)coloured(r,g,0,70)
return ema coloured("green")style(dottedline,2),kDnout coloured("red"),KDnIn coloured("purple"),kUpout coloured("red"),KUpIn coloured("purple")
Le screener sera celui-ci :
//once haopen=open
haclose=(open+close+high+low)/4
//if barindex> 0 then
//haopen=(haopen+haclose[1])/2
//endif
//halow=min(low,min(haclose,haopen))
//hahigh=max(high,max(haclose,haopen))
ema = average[50,1](haclose)
vol = volume
avgvol = average[50](vol)
atr = averagetruerange[50]
kDnout = ema - 3.5*atr
KUpout = ema + 3.5*atr
KDnIn = ema - 2.5*atr
KUpIn = ema + 2.5*atr
//-----long condition---------------//
n = barssince(haclose crosses under KDnOut)
m = barssince(haclose crosses over KUpOut)
if haclose crosses over KDnIn and n <= 5 and vol > avgvol then
res=1
elsif haclose crosses under KUpIn and m <=5 and vol > avgvol then
res=-1
else
res=0
endif
screener[res=1 or res=-1]
