Eccolo, prova se fa esattamente quello che è previsto (mi sembra di si):

DEFPARAM CumulateOrders = False
ONCE UPflag   = 0
ONCE DOWNflag = 0
ONCE GAPstart = 0
ONCE GAPend   = 0
Bullish       = close > open
Bearsih       = close < open
BullGAP       = open > high[1]
BearGAP       = open < low[1]
// rilevare il GAP principale
IF BullGAP THEN
   IF DOWNflag = 0 THEN
      GAPstart = high[1]
      GAPend   = open
      UPflag   = 1
   ENDIF
ELSIF BearGAP THEN
   IF UPflag = 0 THEN
      GAPstart = low[1]
      GAPend   = open
      DOWNflag = 1
   ENDIF
ENDIF
// annullare il Pattern se il GAP viene assorbito
IF UPflag THEN
   GAPend = min(GAPend,low)
   IF GAPend <= GAPstart THEN
     UPflag = 0
   ENDIF
ELSIF DOWNflag THEN
   GAPend = max(GAPend,high)
   IF GAPend >= GAPstart THEN
      DOWNflag = 0
   ENDIF
ENDIF
// Entrare a mercato alla verifica di un GAP inverso
IF UPflag THEN
   IF BearGAP THEN
      SELLSHORT 1 CONTRACT AT Market
   ENDIF
ENDIF
IF DOWNflag THEN
   IF BullGAP THEN
      BUY 1 CONTRACT AT Market
   ENDIF
ENDIF
SET TARGET pPROFIT 450
SET STOP   pLOSS   300

Scusami, ho sbagliato ed ho fatto una strategia.
Rimedio subito, ecco lo screener:

IF BarIndex = 0 THEN
UPflag   = 0
DOWNflag = 0
GAPstart = 0
GAPend   = 0
ENDIF
Segnale     = 0
BullGAP     = open > high[1]
BearGAP     = open < low[1]
// rilevare il GAP principale
IF BullGAP THEN
IF DOWNflag = 0 THEN
GAPstart = high[1]
GAPend   = open
UPflag   = 1
ENDIF
ELSIF BearGAP THEN
IF UPflag = 0 THEN
GAPstart = low[1]
GAPend   = open
DOWNflag = 1
ENDIF
ENDIF
// annullare il Pattern se il GAP viene assorbito
IF UPflag THEN
GAPend = min(GAPend,low)
IF GAPend <= GAPstart THEN
UPflag = 0
ENDIF
ELSIF DOWNflag THEN
GAPend = max(GAPend,high)
IF GAPend >= GAPstart THEN
DOWNflag = 0
ENDIF
ENDIF
// Entrare a mercato alla verifica di un GAP inverso
IF UPflag THEN
IF BearGAP THEN
Segnale = 2
ENDIF
ENDIF
IF DOWNflag THEN
IF BullGAP THEN
Segnale = 1
ENDIF
ENDIF
SCREENER[Segnale](Segnale AS "1=↑, 2=↓")