Hello all,

I have developed a simple trend following system which I apply to USDJPY. The system is very simple. It marks out the opening price at 22:00 (UK time). It then buys or sell an m5 close either side of this line in the sand. The initial stop loss is behind the most recent swing high/low and the position size is determined from the distance to the stop and the max risk percentage of equity (1% in this example). There is a breakeven stop loss which kicks in after price has moved in our favour by a certain multiple of the 10 period ATR. Positions are then held until 20:00 (1 hour before the futures markets close) or until they are stopped out.

The backtest delivers incredible returns – >4000% between 2016 and 2019 from a 5k initial equity and 0.8 point spread (average spread from IG is 0.79 for USDJPY) – see attached performance report. It has the typical drawdowns expected from a trend following system, but nevertheless the system performance in the 200k backtest is pretty incredible. I have done no optimisation so the performance can’t be driven by overfitting (or at least I think it can’t). So my question for you is… is this system too good to be true? Surely anything that looks this good has to be wrong somehow? If its not then merry Christmas here’s a new trend following system for your Arsenal.

Thally

// strategy looks for break above or below previous days 20:00 price
// stop loss behnind swing high or low
// position size is 1% risk based on distance to stop loss
// positions managed with a breakeven stoploss after an ATR multiple move in our favour
// positions are exited at 20:00

DEFPARAM CumulateOrders = False // Cumulating positions deactivated
DEFPARAM FlatAfter = 200000
 
// Spread
ONCE sp = 0.8
 
// money management
ONCE Capital = 5000
ONCE Risk = 0.01
equity = Capital + StrategyProfit
maxrisk = round(equity*Risk)
PositionSizeL = abs(round((maxrisk/StopLossL)/PointValue)*pipsize)
PositionSizeS = abs(round((maxrisk/StopLossS)/PointValue)*pipsize)
 
// window for calculating yesterdays 22:00 price
ONCE starttime = 220000
ONCE endtime = 220500
 
if opentime = starttime then
op = open
endif
 
if opentime = endtime then
lastop = op
endif

graphonprice lastop as "op"

// Trade Counter
ONCE TradeCount = 0
IF INTRADAYBARINDEX=0 then
TradeCount = 0
ENDIF

// Time Filters
ExitPos = Time >= 200000

// Long
IF Not ONMARKET AND close CROSSES OVER lastop AND TradeCount < 10 THEN
BUY PositionSizeL PERPOINT AT MARKET
TradeCount = TradeCount + 1
StopLossL = abs(close - LOWEST[10](low)) + sp
SET STOP LOSS StopLossL
ENDIF

// exit longs
IF LONGONMARKET AND ExitPos THEN
SELL AT MARKET
ENDIF

// short
IF Not ONMARKET AND close CROSSES UNDER lastop AND TradeCount < 10 THEN
SELLSHORT PositionSizeS PERPOINT AT MARKET
TradeCount = TradeCount + 1
StopLossS = abs(close - HIGHEST[10](high)) + sp
SET STOP LOSS StopLossS
ENDIF

// exit shorts
IF SHORTONMARKET AND ExitPos THEN
EXITSHORT AT MARKET
ENDIF

// Breakeven stop loss
//reset the stoploss value
IF NOT ONMARKET THEN
newSL = 0
ENDIF

// Parameters for determining when BE stop kicks in
TrailingStart = 4 * AverageTrueRange[10] * pipsize
TrailingStep = 1 * AverageTrueRange[10] * pipsize

// Longside
IF LONGONMARKET THEN
// move to breakeven
IF newSL = 0 AND CLOSE - TRADEPRICE(1) >= TrailingStart THEN
newSL = TRADEPRICE(1) + TrailingStep
ENDIF
ENDIF
 
//Shortside
IF SHORTONMARKET THEN
// move to breakeven
IF newSL = 0 AND TRADEPRICE(1) - CLOSE >= TrailingStart THEN
newSL = TRADEPRICE(1) - TrailingStep
ENDIF
ENDIF
 
//stop order to exit the positions
IF newSL > 0 THEN
SELL AT newSL STOP
EXITSHORT AT newSL STOP
ENDIF

Screenshot-2019-08-27-at-20.00.06.png