Pubblica il tuo argomento nel forum corretto, l’ho spostato io da ProBuilder a ProScreener in quanto di tratta di uno SCREENER. Grazie 🙂

Eccolo:

//PRC_Wick Pressure | indicator
//23.05.2022
//Nicolas @ http://www.prorealcode.com
//Sharing ProRealTime knowledge
//converted from pinescript

// — settings
atrmult = 0.7 //ATR Multiplier (The Wick area is filtered on the basis of atr and this is multiplier to that ATR. The more the multiplier value, the less the signals and vice versa)
//boxlength = 16 //Length of Wick Pressure Box
rsiob = 60 //RSI based on which signnals are filtered
rsios = 40 //RSI based on which signnals are filtered
// — end of settings

meersi = rsi[14](close)

Segnale = 0

//bullish wick pressure
rsibullishcond = meersi < rsios or meersi[1] < rsios or meersi[2] < rsios
ll3 = lowest[3](low)
lc3 = min(lowest[3](close),lowest[3](open))
if low<=lc3 and low[1]<=lc3 and low[2]<=lc3 and open>=lc3 and open[1]>=lc3 and open[2]>=lc3 and lc3-ll3>(atrmult*AverageTrueRange[14](close)) and rsibullishcond and close>open then
//drawrectangle(barindex,lc3,barindex+boxlength, ll3) coloured("green",50) bordercolor("green")
Segnale = 1
endif

//bearish wick pressure
rsibearishcond = meersi > rsiob or meersi[1] > rsiob or meersi[2] > rsiob
hh3 = highest[3](high)
hc3 = max(highest[3](close), highest[3](open))
if high>=hc3 and high[1]>=hc3 and high[2]>=hc3 and open<=hc3 and open[1]<=hc3 and open[2]<=hc3 and hh3-hc3>(atrmult*AverageTrueRange[14](close)) and rsibearishcond and close<open then
//drawrectangle(barindex,hh3,barindex+boxlength, hc3) coloured("red",50) bordercolor("red")
Segnale = 2
endif

Screener[Segnale](Segnale AS "1=Verde, 2=Rosso")

Eccolo:

//PRC_RSILinearRegressionSignals| indicator
//25.09.2020
//Nicolas @ http://www.prorealcode.com
//Sharing ProRealTime knowledge
//converted from tradingview
//https://www.prorealcode.com/topic/rsi-linear-regresion/

// — settings
len = 21 //RSI Length
period = 200 //Period
deviations = 2.0 //Deviation(s)
// — end of settings

irsi = rsi[len](close)
periodMinusOne = period-1

Ex = 0.0
Ey = 0.0
Ex2 = 0.0
Exy = 0.0
for i=0 to periodMinusOne
closeI = (irsi[i])
Ex = Ex + i
Ey = Ey + closeI
Ex2 = Ex2 + (i * i)
Exy = Exy + (closeI * i)
ExEx = Ex * Ex
next
//slope
if Ex2=ExEx then
slope = 0.0
else
slope= (period * Exy - Ex * Ey) / (period * Ex2 - ExEx)
endif
ilinearRegression = (Ey - slope * Ex) / period
intercept = ilinearRegression + barindex * slope
deviation = 0.0
for i=0 to periodMinusOne
deviation = deviation + square((irsi[i]) - (intercept - slope * (barindex[i])))
next
deviation = deviations * sqrt(deviation / periodMinusOne)
startingPointY = ilinearRegression + slope / periodMinusOne
//lineColor
//if startingPointY > startingPointY[1] then
////color.blue
//r=0
//b=255
//else
////color.red
//r=255
//b=0
//endif
a = startingPointY-deviation
//c1 = startingPointY
b = startingPointY+deviation

up=irsi crosses over a
down=irsi crosses under b
Segnale = 0
if up then
//drawtext("↑ up",barindex,irsi-5,dialog,standard,20) coloured(0,255,0)
Segnale = 1
endif
if down then
//drawtext("↓ down",barindex,irsi+5,dialog,standard,20) coloured(255,0,0)
Segnale = 2
endif

//return irsi, a coloured(r,0,b) style(line,3) as "curve low",c1 coloured(r,0,b) style(line,3) as "curve", b coloured(r,0,b) style(line,3) as "curve high"
SCREENER[Segnale](Segnale AS "1=UP, 2=DOWN")