Bonjour a tous,
Existe t-il un indicateur sur prix pour un croisement entre la Kijun et la SSB sur l’indicateur nuage ichimoku ?
Merci d’avance
Bonjour. Vous voulez dire quelque chose comme ça ?
// Settings
tenkanPeriod = 9
kijunPeriod = 26
spanBPeriod = 52
atr = averagetruerange[14](close)
kijunLine = KijunSen[tenkanPeriod, kijunPeriod, spanBPeriod]
ssbLine = SenkouSpanB[tenkanPeriod, kijunPeriod, spanBPeriod]
bullishCross = kijunLine CROSSES OVER ssbLine
bearishCross = kijunLine CROSSES UNDER ssbLine
IF bullishCross THEN
DRAWARROWUP(barindex, ssbLine - ticksize *0.35*atr) COLOURED(0, 255, 0)
ENDIF
IF bearishCross THEN
DRAWARROWDOWN(barindex, ssbLine + ticksize *0.35*atr) COLOURED(255, 0, 0)
ENDIF
RETURN kijunLine AS "Kijun Sen" COLOURED(0, 0, 255), ssbLine AS "Senkou Span B" COLOURED(255, 0, 0)
C’est 👌
Quelques modif pour le separer du graphique +lui rajouter une étiquette et c’est parfait !
Pour le séparer du graphique des prix, ajoutez-le simplement EN DESSOUS du graphique (comme le RSI, etc.).
Quant à l’étiquette, où souhaitez-vous la placer et quel texte souhaitez-vous y afficher ?
La version du code de croisement entre la Kijun et la SSB ci-dessous afficher un histogramme sous le graphique.
Les barres vertes (+1) apparaissent au-dessus de zéro sur les croisements haussiers, les barres rouges (-1) en dessous sur les croisements baissiers. Le reste du temps, les valeurs sont à 0, donc rien n’est affiché, ce qui garde le sous-graphique lisible.
// Settings
tenkanPeriod = 9
kijunPeriod = 26
spanBPeriod = 52
atr = averagetruerange[14](close)
kijunLine = KijunSen[tenkanPeriod, kijunPeriod, spanBPeriod]
ssbLine = SenkouSpanB[tenkanPeriod, kijunPeriod, spanBPeriod]
bullishCross = kijunLine CROSSES OVER ssbLine
bearishCross = kijunLine CROSSES UNDER ssbLine
bullSignal = 0
bearSignal = 0
IF bullishCross THEN
bullSignal = 1
ENDIF
IF bearishCross THEN
bearSignal = -1
ENDIF
RETURN bullSignal AS "Bullish Cross" COLOURED(0, 200, 0) STYLE(Histogram), bearSignal AS "Bearish Cross" COLOURED(255, 0, 0) STYLE(Histogram)
Je viens de trouver le soucis sur le graph … l’indicateur s’affiche uniquement au croisement de ssB alors que je voulais dire lorsque kijun sort du nuage…
Je suppose qu’il faut faire une comparaison entre ssA et ssB et ensuite pour que kijun sorte du nuage il me faut la condition suvante :
Si kijun < “la plus basse entre ssA et ssB” alors DRAWARROWDOWN // kijun sort du nuage par le bas
Si kijun > “la plus haute entre ssA et ssB” alors DRAWARROWUP // kijun sort du nuage par le haut
J’ai aussi 2 autres questions :
- Existe t-il d’autres dessins (autre que DRAWARROWUP / DOWN ) que l’on puisse ajouter ? par exemple thumbup ?
- Comment peut on modifier la taille du “arrowup/down” ?
Merci d’avance.😉
Essayons avec cette version, j’espère avoir bien compris cette fois ?
// Settings
tenkanPeriod = 9
kijunPeriod = 26
spanBPeriod = 52
atr = averagetruerange[14](close)
kijunLine = KijunSen[tenkanPeriod, kijunPeriod, spanBPeriod]
ssaLine = SenkouSpanA[tenkanPeriod, kijunPeriod, spanBPeriod]
ssbLine = SenkouSpanB[tenkanPeriod, kijunPeriod, spanBPeriod]
cloudTop = MAX(ssaLine, ssbLine)
cloudBottom = MIN(ssaLine, ssbLine)
bullishExit = kijunLine CROSSES OVER cloudTop
bearishExit = kijunLine CROSSES UNDER cloudBottom
IF bullishExit THEN
DRAWARROWUP(barindex, cloudBottom - ticksize * 0.35 * atr) COLOURED(0, 255, 0)
ENDIF
IF bearishExit THEN
DRAWARROWDOWN(barindex, cloudTop + ticksize * 0.35 * atr) COLOURED(255, 0, 0)
ENDIF
RETURN kijunLine AS "Kijun Sen" COLOURED(0, 0, 255), ssaLine AS "Senkou Span A" COLOURED(0, 200, 0), ssbLine AS "Senkou Span B" COLOURED(255, 0, 0)
C’est 👌, tout fonctionne !!
Merci
