//--- ichimoku parameters
p1=9
p2=26
p3=52
p4=26
// ---
tenkan=(highest[p1](high)+lowest[p1](low))/2
kijun=(highest[p2](high)+lowest[p2](low))/2
SpanA=(tenkan[p4]+kijun[p4])/2
SpanB=(highest[p3](high[p4])+lowest[p3](low[p4]))/2
signal =0
// *** sell signals
//Nuage au dessus de la zone tenkan-kijun avec SSA en dessous de SSB
s1 = min(spana,spanb)>max(tenkan,kijun) and spana<spanb
//Tenkan en dessous de Kijun en M1
s2 = tenkan<kijun
//Chikou Span en dessous du prix décalé de 26 périodes - chikou valide la baisse
s3 = close<close[26]
//le prix clôture dans la zone tenkan-kijun en M1 puis une bougie impulsive baissière m1 clôture à l’extérieur de la zone tenant-kijun - dans l’idéal pas plus de 5 bougies qui range dans la zone tendant-kijun
s4 = summation[5](close[0]>min(tenkan[0],kijun[0]) and close[0]<max(tenkan[0],kijun[0]))<5 and close crosses under min(tenkan[0],kijun[0])
isell = s1 and s2 and s3 and s4
if isell then
selltrigger = low
endif
if selltrigger>0 and close crosses under selltrigger then
signal = -1
r=255
g=0
selltrigger = 0
endif
// *** buy signals
//Nuage au dessous de la zone tenkan-kijun avec SSA au dessus de SSB
b1 = max(spana,spanb)<min(tenkan,kijun) and spana>spanb
//Tenkan au dessus de Kijun en M1
b2 = tenkan>kijun
//Chikou Span au dessus du prix décalé de 26 périodes - chikou valide la hausse
b3 = close>close[26]
//le prix clôture dans la zone tenkan-kijun en M1 puis une bougie impulsive haussière M1 clôture à l’extérieur de la zone tenant-kijun - dans l’idéal pas plus de 5 bougies qui range dans la zone tenkan-kijun
b4 = summation[5](close[0]>min(tenkan[0],kijun[0]) and close[0]<max(tenkan[0],kijun[0]))<5 and close crosses over max(tenkan[0],kijun[0])
ibuy = b1 and b2 and b3 and b4
if ibuy then
buytrigger = high
endif
if buytrigger>0 and close crosses over buytrigger then
signal = 1
r=0
g=255
buytrigger = 0
endif
return signal coloured(r,g,0) style(histogram)
.
