Bonjour,

Voici, utilisable dans toute ut dont les horaires de bougies sont compatibles avec les horaires de début et fin de range choisis “start” et “finish” (et horaire de fin de session “eodtime” pour le tracé des lignes sur toute la journée). Pour être utilisable en screener, le code renvoie les 2 valeurs dans sa ligne return, qui sont mises en transparence pour ne pas interférer avec le tracé des 2 lignes:

defparam drawonlastbaronly=true

start=153000
finish=154500
eodtime=220000

eod=eodtime+opendate*1000000
if opentime=start then
 barstart=barindex
 myhigh=high
 mylow=low
endif
if opentime>=start and opentime<finish then
 myhigh=max(high,myhigh)
 mylow=min(low,mylow)
endif

drawsegment(barstart,mylow,datetobarindex(eod),mylow) coloured(255,0,0)
drawsegment(barstart,myhigh,datetobarindex(eod),myhigh) coloured(255,0,0)
//drawrectangle(barstart,mylow,datetobarindex(eod),myhigh) coloured(255,0,0) // rectangle qui peut remplacer les segments, au choix
 
return mylow coloured(0,0,0,0), myhigh coloured(0,0,0,0)

Exemple de ligne call dans un screener, avec le nom du fichier tel que sauvegardé dans ma plateforme, mais bien sûr modifiable si on l’a enregistré sous un autre nom, et les deux variables utilisables dans le screener lowline et highline retournées grâce au call, elles ausi pouvant être nommées différemment si on veut:

lowline, highline = CALL "PRC_req_openrange"

Si on veut un screener qui se sert des 2 lignes, il faut dans le code du screener appeler l’indicateur (instruction CALL) pour qu’il retourne les 2 valeurs, en leur donnant des noms (j’ai pris par exemple lowline et highline pour voir facilement à quoi elles correspondent sans relire le code de l’indicateur, mais on peut choisir ce qu’on veut). Tout cela est fait avec la simple ligne fournie à insérer dans votre screener.

On se sert ensuite des valeurs stockées sous ces 2 noms pour faire ce qu’on veut en faire dans le screener.

Pourquoi ça ne fonctionne pas avec ce ratiovol callé, je ne saurais pas te dire à ce stade, mais en testant sans aucun call c’est à dire en intégrant directement dans le screener les quelques lignes de code des 2 sous-programmes au lieu de faire des call, ça semble fonctionner sur tests effectués. Je te laisse tester à ton tour:

TIMEFRAME(15 minutes)

start=153000
finish=154500
if opentime=start then
 myhigh=high
 mylow=low
endif
if opentime>=start and opentime<finish then
 myhigh=max(high,myhigh)
 mylow=min(low,mylow)
endif
c1 = (close <= myhigh)
c2 = (close >= mylow)

TIMEFRAME(daily)

c3 = (Average[50](Volume) >= 200000)

Voljour = Volume
Volmoy = Average[50](Volume)
ok = ((Voljour/Volmoy)*100)-100

SCREENER[c1 AND c2 AND c3](ok AS "ratio volume")