Indicateur VWAP avec contrainte horraire

Viewing 11 posts - 1 through 11 (of 11 total)
  • Author
    Posts
  • 11/20/2019 at 2:59 PM #113244 quote
    Luciole
    Participant
    Senior

    Bonjour,

    je cherche à ce que l’indicateur vwap ci dessous ne se calcul que sur une certaine plage horaire (08h – 17h30)

    Il n’est pas nécessaire de forcément se baser sur ce code même s’il est fonctionnel en l’état mais sans borne horaire.

     

    J’ai fait quelques essais infructueux malheureusement d’où ma demande d’aide par ici.

    En vous remerciant sincèrement.

     

    if intradaybarindex=0 then
pv=TypicalPrice*volume
 
else
 
pv=pv+(TypicalPrice*volume)
 
endif

// Indicateur incremental volume
// Calcul du volume total de la journée en Intraday
// On réinitialise le volume à chaque changement de jour

IF IntradayBarIndex=0 THEN
incvol=volume
 
else
 
//REM Volume incrémental
incvol=incvol+volume
 
endif

myVWAP2= pv/incvol

return myVWAP2
    11/29/2019 at 11:46 AM #113910 quote
    Luciole
    Participant
    Senior

    Rebonjour,

     

    Pourriez-vous m’aidez svp à ce sujet ?

    11/29/2019 at 2:14 PM #113919 quote
    Nicolas
    Keymaster
    Master

    Avec ce code, on remplace la condition pour tester la première bougie de la journée par une condition horaire, tout simplement. A tester :

    tc = time>=080000 and time<=173000

if not tc then
pv=TypicalPrice*volume
 else
pv=pv+(TypicalPrice*volume)
endif

// Indicateur incremental volume
// Calcul du volume total de la journée en Intraday
// On réinitialise le volume à chaque changement de jour

IF not tc THEN
incvol=volume
else
 //REM Volume incrémental
incvol=incvol+volume
endif

myVWAP2= pv/incvol

return myVWAP2
    Luciole thanked this post
    12/01/2019 at 11:47 AM #113992 quote
    Luciole
    Participant
    Senior

    Merci Nicolas , je regarde ça demain en temps réel , merci à toi

    01/23/2020 at 5:31 PM #117633 quote
    Luciole
    Participant
    Senior

    Hello Nicolas -ou autres –

    J’aimerais apporter 2 modifications à ce code :

    • Changer la base horaire en fonction de l’indice
    • Si possible que la ligne vwap n’apparaisse pas quand la condition horaire + indice n’est pas respectée. Pour ne pas polluer inutilement la vue avec une ligne qui suit le prix sur les bougie..

     

    Pour la condition de l’indice PRT ne détecte pas l’instrument du coup je pensais à une option de ce type mais je n’arrive pas à l’intégrer au code ci dessus (qu’un seul des deux fonctionne) :/

    // DOW
if close>20000 and close<30000 then<code></code>// DAX if close>9000 and close<15000 then

     

    Merci

    01/24/2020 at 3:18 PM #117718 quote
    Nicolas
    Keymaster
    Master

    J’ai intégré ta condition de prix, que tu pourras agrémenter d’autres conditions avec des ELSIF pour ‘configurer’ d’autres instruments différemment.

    Pour cacher la ligne, j’utilise un alpha à 0 (transparence) hors horaires, avec une couleur lambda (que tu pourras modifier dans COLOURED).

    if close>20000 and close<30000 then
tc = time>=080000 and time<=173000
endif 

if not tc then
pv=TypicalPrice*volume
alpha=0
else
pv=pv+(TypicalPrice*volume)
alpha=255
endif

// Indicateur incremental volume
// Calcul du volume total de la journée en Intraday
// On réinitialise le volume à chaque changement de jour

IF not tc THEN
incvol=volume
else
//REM Volume incrémental
incvol=incvol+volume
endif

myVWAP2= pv/incvol

return myVWAP2 coloured(255,159,159,alpha)
    Luciole thanked this post
    vwap-custom-hours.png vwap-custom-hours.png
    01/24/2020 at 3:47 PM #117730 quote
    Luciole
    Participant
    Senior

    Parfait Nicolas, merci

    05/10/2020 at 11:35 AM #130867 quote
    Luciole
    Participant
    Senior

    Bonjour,

    Je cherche à ajouter à l’indicateur ci dessus des bandes d’écarts types à la manière de celui-ci dans la librairie :

    VWAP intraday

    Je tâtonne mais je ne suis pas arrivé à combiner les 2.

     

    L’idée est toujours de cibler le calcul de la vwap sur la plage horaire indiquée en variable tc (time condition)

    En rajoutant 3 niveaux d’écarts types supérieurs et 3 inférieurs.

    bon WE, en vous remerciant

    05/13/2020 at 6:19 PM #131547 quote
    Luciole
    Participant
    Senior

    Rebonjour,

    Je remarque que le code de la librairie fait commencer la vwap au début de l’historique du graphique.

    Ca me semble plus pertinent de partir sur le code de Nicolas 3 messages au dessus.

    Néanmoins je sèche toujours pour intégrer ces 6 standard déviations , que ça soit calculée ou avec la fonction STDEV .

    Un petit coup de pouce serait avec grand plaisir.

    05/14/2020 at 1:28 PM #131661 quote
    JC_Bywan
    Moderator
    Master

    Mélange des 2 codes et capture écran de ce que ça donne sur Dow ut5mn:

    if close>20000 and close<30000 then
tc = time>=080000 and time<=173000
endif

if not tc then
pv=TypicalPrice*volume
alpha=0
incvol=volume
d=0
else
pv=pv+(TypicalPrice*volume)
alpha=255
incvol=incvol+volume
d=d[1]+1
endif

myVWAP2= pv/incvol

IF not tc THEN
sd=0
else
sd = SUMMATION[d](max(abs(high-myVWAP2),abs(myVWAP2-low)))/d
endif

SDup1 = myVWAP2+sd
SDlw1 = myVWAP2-sd
SDup2 = myVWAP2+sd*2
SDlw2 = myVWAP2-sd*2
SDup3 = myVWAP2+sd*3
SDlw3 = myVWAP2-sd*3

return myVWAP2 coloured(255,159,159,alpha), SDup1 coloured(102,102,102,alpha) STYLE(DOTTEDLINE,1) as "upper 1 STD", SDlw1 coloured(102,102,102,alpha) STYLE(DOTTEDLINE,1) as "lower 1 STD", SDup2 coloured(102,102,102,alpha) STYLE(DOTTEDLINE,1) as "upper 2 STD", SDlw2 coloured(102,102,102,alpha) STYLE(DOTTEDLINE,1) as "lower 2 STD", SDup3 coloured(102,102,102,alpha) STYLE(DOTTEDLINE,1) as "upper 3 STD", SDlw3 coloured(102,102,102,alpha) STYLE(DOTTEDLINE,1) as "lower 3 STD"
    Luciole thanked this post
    PRC_VWAPdowLucioleUT5.png PRC_VWAPdowLucioleUT5.png
    05/14/2020 at 2:29 PM #131668 quote
    Luciole
    Participant
    Senior

    Merci !

  • Author
    Posts
Viewing 11 posts - 1 through 11 (of 11 total)
  • You must be logged in to reply to this topic.

Indicateur VWAP avec contrainte horraire


ProBuilder : Indicateurs & Outils Personnalisés

New Reply
Author
author-avatar
Luciole @karl_kondor7_kerons Participant
Summary

This topic contains 10 replies,
has 3 voices, and was last updated by Luciole
5 years, 9 months ago.

Topic Details
Forum: ProBuilder : Indicateurs & Outils Personnalisés
Language: French
Started: 11/20/2019
Status: Active
Attachments: 2 files
Logo Logo
Loading...
Do you like cookies? 🍪 We use cookies to ensure you get the best experience on our website. (Learn more)
©2026 ProRealCode - Trading & Coding with ProRealTime™