Me he dado cuenta de que en todos tus posts siempre escribes los títulos en mayúsculas y desde hace aproximadamente un año añades al final de ellos muchos símbolos repetidos obsesivamente (asteriscos, signos de exclamación, etc…).
Evidentemente es un intento de buscar mayor atención y una respuesta más rápida.
Les recuerdo que NETIQUETTE desaconseja el uso de todas las letras mayúsculas, excepto excepcionalmente para poner énfasis en una palabra específica. El uso de MAYÚSCULAS se considera de mala educación ya que se equipara a “gritar” para hacerse oír entre los demás.
Gracias por tu cooperación 🙂

Buenas tardes.
Ahí va el código:

//--------------------------------------------------//
//PRC_Radius Trend
//version = 0
//03.10.2024
//Iván González @ www.prorealcode.com
//Sharing ProRealTime knowledge
//--------------------------------------------------//
//-------------------Inputs-------------------------//
//--------------------------------------------------//
step=0.15 //Radius step
multi=2 //Start Points Distance
n=3
//--------------------------------------------------//
//-----------Indicator Calculations-----------------//
//--------------------------------------------------//
//Calculate distance for band placement
distance=average[100](high-low)*multi
distance1=average[100](high-low)*0.2
//--------------------------------------------------//
//Initialize trend and band on 101st bar
once trend=0
once band=0
if barindex=101 then
trend=1
band=low*0.8
endif
//--------------------------------------------------//
//Update trend based on price relation to band
if close<band then
trend=0
r=207
g=43
b=43
elsif close>band then
trend=1
r=84
g=182
b=212
endif
//--------------------------------------------------//
//Adjust band on trend changes
if trend[1]=0 and trend<>trend[1]then
band=low-distance
alpha=0
elsif trend[1]=1 and trend<>trend[1]then
band=high+distance
alpha=0
else
alpha=255
endif
//--------------------------------------------------//
//Apply step angle to trend lines
once multi1=0
once multi2=0
if barindex MOD n = 0 and trend=1 then
multi1=0
multi2=multi2+step
band=band+distance1*multi2
endif
if barindex MOD n = 0 and trend=0 then
multi1=step+multi1
multi2=0
band=band-distance1*multi1
endif
//--------------------------------------------------//
//Smooth the band
Sband=average[n](band)
//--------------------------------------------------//
//Calculate upper and lower bands
bandUpper=average[n](band+distance*0.5)
bandLower=average[n](band-distance*0.5)
if trend=1 then
band1=bandUpper
else
band1=bandLower
endif
//--------------------------------------------------//
//Fill color
avgHL2=average[20]((high+low)/2)
if barindex>101 then
colorbetween(Sband,avgHL2,r,g,b,alpha*0.2)
endif
//--------------------------------------------------//
return sband coloured("grey",alpha)style(line,2), band1 coloured("grey",alpha)style(dottedline,1)