Indicador de Sesiones

Viewing 5 posts - 1 through 5 (of 5 total)

Author

Posts

04/29/2021 at 9:15 AM #168343 quote

Participant

New

Hola a todos, necesito ayuda para crear una indicador que me muestre en la cotización del precio el máximo y el mínimo de sesión, el máximo y el mínimo de la primera hora de cotización y el precio de apertura de sesión. Para sesiones Europa y USA.

Gracias de antemano

04/30/2021 at 1:07 AM #168422 quote

robertogozzi

Moderator

Legend

Ahi esta:

DEFPARAM DrawOnLastBarOnly = TRUE
//
ONCE StartEU  = 090000
ONCE EndEU    = 173000
ONCE h1EUend  = StartEU  + 010000
ONCE OffsetEU = 10
//
ONCE StartUSA = 143000
ONCE EndUSA   = 230000
ONCE h1USAend = StartUSA + 010000
ONCE OffsetUSA= 45
//
ONCE OpenEU   = 0
ONCE MaxEU    = 0
ONCE MinEU    = 0
ONCE Max1EU   = 0
ONCE Min1EU   = 0
ONCE BarEU    = 0
//
ONCE OpenUSA  = 0
ONCE MaxUSA   = 0
ONCE MinUSA   = 0
ONCE Max1USA  = 0
ONCE Min1USA  = 0
ONCE BarUSA   = 0
//------------------------------------------------------------------------
// -- EU --
//
IF OpenTime = StartEU THEN
   OpenEU   = open
   MaxEU    = high
   MinEU    = low
   Max1EU   = high
   Min1EU   = low
   BarEU    = 0
ENDIF
IF (OpenTime >= StartEU) AND (Time <= h1EUend) AND (Time > StartEU) THEN
   Max1EU   = max(Max1EU,high)
   Min1EU   = min(Min1EU,low)
ENDIF
//
IF (OpenTime >= StartEU) AND (Time <= EndEU) AND (Time > StartEU) THEN
   MaxEU    = max(MaxEU,high)
   MinEU    = min(MinEU,low)
ENDIF
IF (Time = EndEU) THEN
   BarEU    = BarIndex
ENDIF
//------------------------------------------------------------------------
// -- USA --
//
IF OpenTime = StartUSA THEN
   OpenUSA  = open
   MaxUSA   = high
   MinUSA   = low
   Max1USA  = high
   Min1USA  = low
   BarUSA   = 0
ENDIF
IF (OpenTime >= StartUSA) AND (Time <= h1USAend) AND (Time >= StartUSA) THEN
   Max1USA  = max(Max1USA,high)
   Min1USA  = min(Min1USA,low)
ENDIF
//
IF (OpenTime >= StartUSA) AND (Time <= EndUSA) AND (Time >= StartUSA) THEN
   MaxUSA   = max(MaxUSA,high)
   MinUSA   = min(MinUSA,low)
ENDIF
IF Time = EndUSA THEN
   BarUSA   = BarIndex
ENDIF
//------------------------------------------------------------------------
BarEndEU = BarEU
IF BarEU = 0 THEN
   BarEndEU = BarIndex
ENDIF
DrawText("- EU -",BarEndEU - OffsetEU, high * 1.020)            coloured(150,50,205,255)  //Purple
DrawText("Open  #OpenEU#",BarEndEU - OffsetEU, high * 1.019)    coloured(150,50,205,255)  //Purple
DrawText("Max   #MaxEU#" ,BarEndEU - OffsetEU, high * 1.017)    coloured(150,50,205,255)  //Purple
DrawText("Min   #MinEU#" ,BarEndEU - OffsetEU, high * 1.016)    coloured(150,50,205,255)  //Purple
DrawText("MaxH1 #Max1EU#",BarEndEU - OffsetEU, high * 1.014)    coloured(150,50,205,255)  //Purple
DrawText("MinH1 #Min1EU#",BarEndEU - OffsetEU, high * 1.013)    coloured(150,50,205,255)  //Purple
//------------------------------------------------------------------------
BarEndUSA = BarUSA
IF BarUSA = 0 THEN
   BarEndUSA = BarIndex
ENDIF
DrawText("- USA -",BarEndUSA - OffsetUSA, high * 1.020)         coloured(50,205,50,255)   //Green
DrawText("Open  #OpenUSA#",BarEndUSA - OffsetUSA, high * 1.019) coloured(50,205,50,255)   //Green
DrawText("Max   #MaxUSA#" ,BarEndUSA - OffsetUSA, high * 1.017) coloured(50,205,50,255)   //Green
DrawText("Min   #MinUSA#" ,BarEndUSA - OffsetUSA, high * 1.016) coloured(50,205,50,255)   //Green
DrawText("MaxH1 #Max1USA#",BarEndUSA - OffsetUSA, high * 1.014) coloured(50,205,50,255)   //Green
DrawText("MinH1 #Min1USA#",BarEndUSA - OffsetUSA, high * 1.013) coloured(50,205,50,255)   //Green
//------------------------------------------------------------------------
RETURN

x-14.jpg

04/30/2021 at 7:33 PM #168494 quote

Radobu99

Participant

New

Genial, muchas gracias Roberto.

05/01/2021 at 5:19 PM #168522 quote

Radobu99

Participant

New

Hola compañeros, les pido ayuda para poder conseguir un indicador mas gráfico para la identificación de sesiones.

Saludos y gracias

Sesiones.png

Sesiones-1.png

05/02/2021 at 10:06 AM #168552 quote

robertogozzi

Moderator

Legend

Ahi esta:

ONCE ASIAstart = 230000
ONCE EUstart   = 090000
ONCE USAstart  = 143000
ONCE r         = 255
ONCE g         = 255
ONCE b         = 255
ONCE t         = 100
IF OpenTime = ASIAstart THEN
   r = 30
   g = 144
   b = 255
   t = 100
ELSIF OpenTime = EUstart THEN
   r = 205
   g = 0
   b = 205
   t = 100
ELSIF OpenTime = USAstart THEN
   r = 0
   g = 205
   b = 0
   t = 100
ENDIF
BackgroundColor(r,g,b,t)
RETURN

Catálogo de colores http://cloford.com/resources/colours/500col.htm