horizontal trend lines in prorealtime

Viewing 4 posts - 1 through 4 (of 4 total)
  • Author
    Posts
  • 09/26/2021 at 4:36 PM #178456 quote
    gnellas77
    Participant
    Average

    hi there,

    if you press the horizontal trend lines button in prorealtime you get major and secondary support and resistance lines in a specific chart.

    what it the theory or programming commands the prorealtime uses in order to draw the lines?

    i ‘m interested in this because i want to program the computer to find triple tops (the resistance line of the 3 peaks)

    if i posted in wrong section please pardon me.

    thanx.

    09/27/2021 at 12:53 PM #178562 quote
    Rainer (RFW)
    Participant
    Senior

    Hello,
    not the same, but it may help you.
    This indicator looks for Double/Triple Tops/Bottoms. Please try it out.
    Regards
    Rainer

    //  Rainer-Franz Wirth  Rainer (RFW) @ prorealcode.com
//***************************************************************************************************************************************
Defparam Drawonlastbaronly = True
//***************************************************************************************************************************************
//// Variables ////
//*****************
StartPeriod     = Max(0,StartPeriod)    // StartPeriod
SearchPeriod    = Max(10,SearchPeriod)  // LookBack Search-Periods, min.10
MaxDistance     = Max(0,MaxDistance)    // Allowed Distance beetween Highs/Lows Double/Triple - 1 = 0.001%, 2 = 0.002% etc...
MinBarDistance  = Max(5,MinBarDistance) // Min Distance Candle Highs/Lows
DisplayMod      = Max(-1,DisplayMod)    // -1 Check - 0 HLine - 1 HLine+Points - 2 HLine+Points+VLine - 3 All Lines+Points
ColourMod       = Max(1,ColourMod)      // 1 Green/Red - 2 Blue/Orange - 3 Red/Green - 4 Orange/Blue
//***************************************************************************************************************************************
//// Colours ////
//***************************************************************************************************************************************
// ColourMod 1: High Green, Low Red
// ColourMod 2: High Red, Low Green
// ColourMod 3: High Blue, Low Orange
// ColourMod 4: High Orange, Low Blue
//************************************
If ColourMod = 1 Then
// High Green
RCH1 = 0
GCH1 = 255
BCH1 = 0
// Low Red
RCL1 = 255
GCL1 = 0
BCL1 = 0
ElsIf ColourMod = 2 Then
// High Red
RCH1 = 255
GCH1 = 0
BCH1 = 0
// Low Green
RCL1 = 0
GCL1 = 255
BCL1 = 0
ElsIf ColourMod = 3 Then
// High Blue
RCH1 = 0
GCH1 = 150
BCH1 = 255
// Low Orange
RCL1 = 255
GCL1 = 100
BCL1 = 0
ElsIf ColourMod = 4 Then
// High Orange
RCH1 = 255
GCH1 = 100
BCH1 = 0
// Low Blue
RCL1 = 0
GCL1 = 150
BCL1 = 255
Endif
//***************************************************************************************************************************************
//// SearchPeriods ////
//********************
SP0 = StartPeriod
SPS = SearchPeriod+SP0
//***********************************************
//// Check/Visualize Search Periods-Sections ////
//***********************************************
If (DisplayMod = -1) Or (DisplayMod > 2) Then
DRAWVLINE(BarIndex-SP0)Coloured(0,0,255)
DRAWVLINE(BarIndex-SPS)Coloured(0,0,255)
Endif
//***************************************************************************************************************************************
If IsLastBarupdate Then
// 1. High
HDT1 = 0
For HDT1x = SP0 To SPS Do
If High[HDT1x] > HDT1 Then
HDT1  = High[HDT1x]
HDT1B = BarIndex[HDT1x]
EndIf
Next
HDTDUP = (HDT1*(1+(MaxDistance/100000)))
HDTDDO = (HDT1*(1-(MaxDistance/100000)))
If (DisplayMod = -1) Or (DisplayMod > 2) Then
DRAWPOINT(HDT1B,HDT1,3)Coloured(RCH1,GCH1,BCH1)Bordercolor(RCH1,GCH1,BCH1)
DRAWHLINE(HDT1)Coloured(255,255,255)
DRAWHLINE(HDTDDO)Coloured(255,0,0)
DRAWHLINE(HDTDUP)Coloured(0,255,0)
Endif
//******************************************************************
// 2. High
For HDTC2x = SP0 To SPS Do
If (High[HDTC2x] > HDTDUP) Then
Break
Else
//************************************************************
For HDT2x = SP0 To SPS Do
If ((High[HDT2x] >= HDTDDO) And (High[HDT2x] =< HDTDUP)) And ((Abs(HDT1B-(BarIndex[HDT2x]))) >= MinBarDistance) Then
HDT2  = High[HDT2x]
HDT2B = BarIndex[HDT2x]
DTH = 2 // Double-Top
If (DisplayMod = -1) Or (DisplayMod > 2) Then
DRAWPOINT(HDT2B,HDT2,2)Coloured(RCH1,GCH1,BCH1)Bordercolor(RCH1,GCH1,BCH1)
EndIf
Break
EndIf
Next //************ 2. High
//***********************************************************
// 3. High
For HDT3x = SP0 To SPS Do
If (High[HDT3x] >= HDTDDO) And (High[HDT3x] =< HDTDUP) And ((Abs(HDT2B-(BarIndex[HDT3x]))) >= MinBarDistance) And ((Abs(HDT1B-(BarIndex[HDT3x]))) >= MinBarDistance) Then
HDT3  = High[HDT3x]
HDT3B = BarIndex[HDT3x]
DTH = 3 // Triple-Top
If (DisplayMod = -1) Or (DisplayMod > 2) Then
DRAWPOINT(HDT3B,HDT3,2)Coloured(RCH1,GCH1,BCH1)Bordercolor(RCH1,GCH1,BCH1)
EndIf
Break
EndIf
Next //************ 3. High
//***********************************************************
Endif
Next //************ 1. Higher Check
//******************************************************************
If (DTH = 2) Then
DRAWHLINE(HDT1)Coloured(RCH1,GCH1,BCH1)Style(Line,2)
If (DisplayMod > 0) Then                     // Line-Horizontal+Point
DRAWPOINT(HDT1B,HDT1,2)Coloured(RCH1,GCH1,BCH1)Bordercolor(RCH1,GCH1,BCH1)
DRAWPOINT(HDT2B,HDT2,2)Coloured(RCH1,GCH1,BCH1)Bordercolor(RCH1,GCH1,BCH1)
EndIf
If (DisplayMod > 1) Then                  // Line-Horizontal+Point+Line-Vertical
DRAWPOINT(HDT1B,HDT1,2)Coloured(RCH1,GCH1,BCH1)Bordercolor(RCH1,GCH1,BCH1)
DRAWPOINT(HDT2B,HDT2,2)Coloured(RCH1,GCH1,BCH1)Bordercolor(RCH1,GCH1,BCH1)
DRAWVLINE(HDT1B)Coloured(RCH1,GCH1,BCH1)
DRAWVLINE(HDT2B)Coloured(RCH1,GCH1,BCH1)
Endif
EndIf
If (DTH = 3) Then
DRAWHLINE(HDT1)Coloured(RCH1,GCH1,BCH1)Style(Line,2)
If (DisplayMod > 0) Then                     // Line-Horizontal+Point
DRAWPOINT(HDT1B,HDT1,2)Coloured(RCH1,GCH1,BCH1)Bordercolor(RCH1,GCH1,BCH1)
DRAWPOINT(HDT2B,HDT2,2)Coloured(RCH1,GCH1,BCH1)Bordercolor(RCH1,GCH1,BCH1)
DRAWPOINT(HDT3B,HDT3,2)Coloured(RCH1,GCH1,BCH1)Bordercolor(RCH1,GCH1,BCH1)
EndIf
If (DisplayMod > 1) Then                  // Line-Horizontal+Point+Line-Vertical
DRAWPOINT(HDT1B,HDT1,2)Coloured(RCH1,GCH1,BCH1)Bordercolor(RCH1,GCH1,BCH1)
DRAWPOINT(HDT2B,HDT2,2)Coloured(RCH1,GCH1,BCH1)Bordercolor(RCH1,GCH1,BCH1)
DRAWPOINT(HDT3B,HDT3,2)Coloured(RCH1,GCH1,BCH1)Bordercolor(RCH1,GCH1,BCH1)
DRAWVLINE(HDT1B)Coloured(RCH1,GCH1,BCH1)
DRAWVLINE(HDT2B)Coloured(RCH1,GCH1,BCH1)
DRAWVLINE(HDT3B)Coloured(RCH1,GCH1,BCH1)
Endif
Endif
//***************************************************************************************************************************************
//***************************************************************************************************************************************
// 1. Low
LDT1 = 999999
For LDT1x = SP0 To SPS Do
If Low[LDT1x] < LDT1 Then
LDT1  = Low[LDT1x]
LDT1B = BarIndex[LDT1x]
EndIf
Next
LDTDUP = (LDT1*(1+(MaxDistance/100000)))
LDTDDO = (LDT1*(1-(MaxDistance/100000)))
If (DisplayMod = -1) Or (DisplayMod > 2) Then
DRAWPOINT(LDT1B,LDT1,2)Coloured(RCL1,GCL1,BCL1)Bordercolor(RCL1,GCL1,BCL1)
DRAWHLINE(LDT1)Coloured(255,255,255)
DRAWHLINE(LDTDDO)Coloured(255,0,0)
DRAWHLINE(LDTDUP)Coloured(0,255,0)
Endif
//******************************************************************
// 2. Low
For LDTC2x = SP0 To SPS Do
If (Low[LDTC2x] < LDTDDO) Then
Break
Else
//************************************************************
For LDT2x = SP0 To SPS Do
If ((Low[LDT2x] >= LDTDDO) And (Low[LDT2x] =< LDTDUP)) And ((Abs(LDT1B-(BarIndex[LDT2x]))) >= MinBarDistance) Then
LDT2  = Low[LDT2x]
LDT2B = BarIndex[LDT2x]
DTL = 2 // Double-Bottom
If (DisplayMod = -1) Or (DisplayMod > 2) Then
DRAWPOINT(LDT2B,LDT2,2)Coloured(RCL1,GCL1,BCL1)Bordercolor(RCL1,GCL1,BCL1)
EndIf
Break
EndIf
Next //************ 2. Low
//***********************************************************
// 3. Low
For LDT3x = SP0 To SPS Do
If (Low[LDT3x] >= LDTDDO) And (Low[LDT3x] =< LDTDUP) And ((Abs(LDT2B-(BarIndex[LDT3x]))) >= MinBarDistance) And ((Abs(LDT1B-(BarIndex[LDT3x]))) >= MinBarDistance) Then
LDT3  = Low[LDT3x]
LDT3B = BarIndex[LDT3x]
DTL = 3 // Triple-Bottom
If (DisplayMod = -1) Or (DisplayMod > 2) Then
DRAWPOINT(LDT3B,LDT3,2)Coloured(RCL1,GCL1,BCL1)Bordercolor(RCL1,GCL1,BCL1)
EndIf
Break
EndIf
Next //************ 3. Low
//***********************************************************
Endif
Next //************ 1. Lower Check
//******************************************************************
If (DTL = 2) Then
DRAWHLINE(LDT1)Coloured(RCL1,GCL1,BCL1)Style(Line,2)
If (DisplayMod > 0) Then                     // Line-Horizontal+Point
DRAWPOINT(LDT1B,LDT1,3)Coloured(RCL1,GCL1,BCL1)Bordercolor(RCL1,GCL1,BCL1)
DRAWPOINT(LDT2B,LDT2,3)Coloured(RCL1,GCL1,BCL1)Bordercolor(RCL1,GCL1,BCL1)
EndIf
If (DisplayMod > 1) Then                  // Line-Horizontal+Point+Line-Vertical
DRAWPOINT(LDT1B,LDT1,3)Coloured(RCL1,GCL1,BCL1)Bordercolor(RCL1,GCL1,BCL1)
DRAWPOINT(LDT2B,LDT2,3)Coloured(RCL1,GCL1,BCL1)Bordercolor(RCL1,GCL1,BCL1)
DRAWVLINE(LDT1B)Coloured(RCL1,GCL1,BCL1)
DRAWVLINE(LDT2B)Coloured(RCL1,GCL1,BCL1)
Endif
EndIf
If (DTL = 3) Then
DRAWHLINE(LDT1)Coloured(RCL1,GCL1,BCL1)Style(Line,2)
If (DisplayMod > 0) Then                     // Line-Horizontal+Point
DRAWPOINT(LDT1B,LDT1,2)Coloured(RCL1,GCL1,BCL1)Bordercolor(RCL1,GCL1,BCL1)
DRAWPOINT(LDT2B,LDT2,2)Coloured(RCL1,GCL1,BCL1)Bordercolor(RCL1,GCL1,BCL1)
DRAWPOINT(LDT3B,LDT3,2)Coloured(RCL1,GCL1,BCL1)Bordercolor(RCL1,GCL1,BCL1)
EndIf
If (DisplayMod > 1) Then                  // Line-Horizontal+Point+Line-Vertical
DRAWPOINT(LDT1B,LDT1,2)Coloured(RCL1,GCL1,BCL1)Bordercolor(RCL1,GCL1,BCL1)
DRAWPOINT(LDT2B,LDT2,2)Coloured(RCL1,GCL1,BCL1)Bordercolor(RCL1,GCL1,BCL1)
DRAWPOINT(LDT3B,LDT3,2)Coloured(RCL1,GCL1,BCL1)Bordercolor(RCL1,GCL1,BCL1)
DRAWVLINE(LDT1B)Coloured(RCL1,GCL1,BCL1)
DRAWVLINE(LDT2B)Coloured(RCL1,GCL1,BCL1)
DRAWVLINE(LDT3B)Coloured(RCL1,GCL1,BCL1)
Endif
Endif
//***************************************************************************************************************************************
//***************************************************************************************************************************************
EndIf // IsLastBarupdate
//***************************************************************************************************************************************
Return
    gnellas77 thanked this post
    RFW_DoubleTriple_Top_Bottom.itf
    09/27/2021 at 8:52 PM #178604 quote
    Rainer (RFW)
    Participant
    Senior

    Sorry, I uploaded an old File/Code, now the correct .itf-File.
    Best Regards
    Rainer

    gp38super thanked this post
    RFW_Double_Triple_Top_Bottom.itf
    09/27/2021 at 9:04 PM #178606 quote
    Rainer (RFW)
    Participant
    Senior

    ..and the Code:

    //  Rainer-Franz Wirth  Rainer (RFW) @ prorealcode.com
//***************************************************************************************************************************************
Defparam Drawonlastbaronly   = True
DH = 0
DL = 0
//***************************************************************************************************************************************
//// Variables ////
//*****************
StartPeriod    = Max(0,StartPeriod)      // StartPeriod
SearchPeriod   = Max(10,SearchPeriod)    // LookBack Search-Periods, min.10
MaxDistance    = Max(0,MaxDistance)      // Allowed Distance Highs/Lows Double/Triple - 1 = 0.001%, 2 = 0.002% etc...
MinBarDistance = Max(1,MinBarDistance)   // Min BarDistance Candle Highs/Lows
DisplayMod     = Max(-1,DisplayMod)      // -1 Check - 0 HLine - 1 HLine+Points - 2 HLine+Points+VLine - 3 All
ColourMod      = Max(1,ColourMod)        // 1 Green/Red - 2 Blue/Orange - 3 Red/Green - 4 Orange/Blue
//***************************************************************************************************************************************
//// Colours ////
//***************************************************************************************************************************************
// ColourMod 1: High Green, Low Red
// ColourMod 2: High Red, Low Green
// ColourMod 3: High Blue, Low Orange
// ColourMod 4: High Orange, Low Blue
//************************************
If ColourMod = 1 Then
// High Green
RCH1 = 0
GCH1 = 255
BCH1 = 0
// Low Red
RCL1 = 255
GCL1 = 0
BCL1 = 0
ElsIf ColourMod = 2 Then
// High Red
RCH1 = 255
GCH1 = 0
BCH1 = 0
// Low Green
RCL1 = 0
GCL1 = 255
BCL1 = 0
ElsIf ColourMod = 3 Then
// High Blue
RCH1 = 0
GCH1 = 150
BCH1 = 255
// Low Orange
RCL1 = 255
GCL1 = 100
BCL1 = 0
ElsIf ColourMod = 4 Then
// High Orange
RCH1 = 255
GCH1 = 100
BCH1 = 0
// Low Blue
RCL1 = 0
GCL1 = 150
BCL1 = 255
Endif
//***************************************************************************************************************************************
If IsLastBarupdate Then
MaxBarindex = BarIndex
//*********************
//// SearchPeriods ////
//********************
SP0 = StartPeriod
SPS = Min(MaxBarindex-1,(SearchPeriod-SP0-1))
//***********************************************
//// Check/Visualize Search Periods-Sections ////
//***********************************************
If (DisplayMod = -1) Or (DisplayMod > 2) Then
DRAWVLINE(BarIndex-SP0)Coloured(0,0,255)
DRAWVLINE(BarIndex-SPS)Coloured(0,0,255)
Endif
//***************************************************************************************************************************************
//************ 1. High
HDT1 = Highest[SPS](High[SP0])
For HDT1x = SP0 To SPS Do
If High[HDT1x] = HDT1 Then
HDT1  = High[HDT1x]
HDT1B = BarIndex[HDT1x]
Break
EndIf
Next
HDTDUP = (HDT1*(1+(MaxDistance/100000)))
HDTDDO = (HDT1*(1-(MaxDistance/100000)))
If (DisplayMod = -1) Or (DisplayMod > 2) Then
DRAWHLINE(HDTDDO)Coloured(255,0,0)
DRAWHLINE(HDTDUP)Coloured(0,255,0)
DRAWPOINT(HDT1B,HDT1,2)Coloured(RCH1,GCH1,BCH1)Bordercolor(RCH1,GCH1,BCH1)
EndIf
//************ 2. High
For HDT2x = SP0 To SPS Do
If ((High[HDT2x] >= HDTDDO) And (High[HDT2x] =< HDTDUP)) And ((Abs(HDT1B-(BarIndex[HDT2x]))) >= MinBarDistance) Then
HDT2  = High[HDT2x]
HDT2B = BarIndex[HDT2x]
DH = 2 // Double-Top
If (DisplayMod = -1) Or (DisplayMod > 2) Then
DRAWPOINT(HDT2B,HDT2,2)Coloured(RCH1,GCH1,BCH1)Bordercolor(RCH1,GCH1,BCH1)
EndIf
Break
EndIf
Next
//************ 3. High
For HDT3x = SP0 To SPS Do
If (High[HDT3x] >= HDTDDO) And (High[HDT3x] =< HDTDUP) And ((Abs(HDT2B-(BarIndex[HDT3x]))) >= MinBarDistance) And ((Abs(HDT1B-(BarIndex[HDT3x]))) >= MinBarDistance) Then
HDT3  = High[HDT3x]
HDT3B = BarIndex[HDT3x]
DH = 3 // Triple-Top
If (DisplayMod = -1) Or (DisplayMod > 2) Then
DRAWPOINT(HDT3B,HDT3,2)Coloured(RCH1,GCH1,BCH1)Bordercolor(RCH1,GCH1,BCH1)
EndIf
Break
EndIf
Next
//***************************************************************************************************************************************3.
If (DH = 2) Then
DRAWHLINE(HDT1)Coloured(RCH1,GCH1,BCH1)Style(Line,2)
If (DisplayMod > 0) Then                     // Line-Horizontal+Point
DRAWPOINT(HDT1B,HDT1,2)Coloured(RCH1,GCH1,BCH1)Bordercolor(RCH1,GCH1,BCH1)
DRAWPOINT(HDT2B,HDT2,2)Coloured(RCH1,GCH1,BCH1)Bordercolor(RCH1,GCH1,BCH1)
EndIf
If (DisplayMod > 1) Then                    // Line-Horizontal+Point+Line-Vertical
DRAWPOINT(HDT1B,HDT1,2)Coloured(RCH1,GCH1,BCH1)Bordercolor(RCH1,GCH1,BCH1)
DRAWPOINT(HDT2B,HDT2,2)Coloured(RCH1,GCH1,BCH1)Bordercolor(RCH1,GCH1,BCH1)
DRAWVLINE(HDT1B)Coloured(RCH1,GCH1,BCH1)
DRAWVLINE(HDT2B)Coloured(RCH1,GCH1,BCH1)
Endif
EndIf
If (DH = 3) Then
DRAWHLINE(HDT1)Coloured(RCH1,GCH1,BCH1)Style(Line,2)
If (DisplayMod > 0) Then                     // Line-Horizontal+Point
DRAWPOINT(HDT1B,HDT1,2)Coloured(RCH1,GCH1,BCH1)Bordercolor(RCH1,GCH1,BCH1)
DRAWPOINT(HDT2B,HDT2,2)Coloured(RCH1,GCH1,BCH1)Bordercolor(RCH1,GCH1,BCH1)
DRAWPOINT(HDT3B,HDT3,2)Coloured(RCH1,GCH1,BCH1)Bordercolor(RCH1,GCH1,BCH1)
EndIf
If (DisplayMod > 1) Then                     // Line-Horizontal+Point+Line-Vertical
DRAWPOINT(HDT1B,HDT1,2)Coloured(RCH1,GCH1,BCH1)Bordercolor(RCH1,GCH1,BCH1)
DRAWPOINT(HDT2B,HDT2,2)Coloured(RCH1,GCH1,BCH1)Bordercolor(RCH1,GCH1,BCH1)
DRAWPOINT(HDT3B,HDT3,2)Coloured(RCH1,GCH1,BCH1)Bordercolor(RCH1,GCH1,BCH1)
DRAWVLINE(HDT1B)Coloured(RCH1,GCH1,BCH1)
DRAWVLINE(HDT2B)Coloured(RCH1,GCH1,BCH1)
DRAWVLINE(HDT3B)Coloured(RCH1,GCH1,BCH1)
EndIf
Endif
//***************************************************************************************************************************************3.
//***************************************************************************************************************************************3.
//************ 1. Low
LDT1 = Lowest[SPS](Low[SP0])
For LDT1x = SP0 To SPS Do
If Low[LDT1x] = LDT1 Then
LDT1  = Low[LDT1x]
LDT1B = BarIndex[LDT1x]
Break
EndIf
Next
LDTDUP = (LDT1*(1+(MaxDistance/100000)))
LDTDDO = (LDT1*(1-(MaxDistance/100000)))
If (DisplayMod = -1) Or (DisplayMod > 2) Then
DRAWHLINE(LDTDDO)Coloured(255,0,0)
DRAWHLINE(LDTDUP)Coloured(0,255,0)
DRAWPOINT(LDT1B,LDT1,2)Coloured(RCL1,GCL1,BCL1)Bordercolor(RCL1,GCL1,BCL1)
EndIf
//************ 2. Low
For LDT2x = SP0 To SPS Do
If ((Low[LDT2x] >= LDTDDO) And (Low[LDT2x] =< LDTDUP)) And ((Abs(LDT1B-(BarIndex[LDT2x]))) >= MinBarDistance) Then
LDT2  = Low[LDT2x]
LDT2B = BarIndex[LDT2x]
DL = 2 // Double-Bottom
If (DisplayMod = -1) Or (DisplayMod > 2) Then
DRAWPOINT(LDT2B,LDT2,2)Coloured(RCL1,GCL1,BCL1)Bordercolor(RCL1,GCL1,BCL1)
EndIf
Break
EndIf
Next
//************ 3. Low
For LDT3x = SP0 To SPS Do
If (Low[LDT3x] >= LDTDDO) And (Low[LDT3x] =< LDTDUP) And ((Abs(LDT2B-(BarIndex[LDT3x]))) >= MinBarDistance) And ((Abs(LDT1B-(BarIndex[LDT3x]))) >= MinBarDistance) Then
LDT3  = Low[LDT3x]
LDT3B = BarIndex[LDT3x]
DL = 3 // Triple-Bottom
If (DisplayMod = -1) Or (DisplayMod > 2) Then
DRAWPOINT(LDT3B,LDT3,2)Coloured(RCL1,GCL1,BCL1)Bordercolor(RCL1,GCL1,BCL1)
EndIf
Break
EndIf
Next
//***************************************************************************************************************************************3.
If (DL = 2) Then
DRAWHLINE(LDT1)Coloured(RCL1,GCL1,BCL1)Style(Line,2)
If (DisplayMod > 0) Then                     // Line-Horizontal+Point
DRAWPOINT(LDT1B,LDT1,2)Coloured(RCL1,GCL1,BCL1)Bordercolor(RCL1,GCL1,BCL1)
DRAWPOINT(LDT2B,LDT2,2)Coloured(RCL1,GCL1,BCL1)Bordercolor(RCL1,GCL1,BCL1)
EndIf
If (DisplayMod > 1) Then                    // Line-Horizontal+Point+Line-Vertical
DRAWPOINT(LDT1B,LDT1,2)Coloured(RCL1,GCL1,BCL1)Bordercolor(RCL1,GCL1,BCL1)
DRAWPOINT(LDT2B,LDT2,2)Coloured(RCL1,GCL1,BCL1)Bordercolor(RCL1,GCL1,BCL1)
DRAWVLINE(LDT1B)Coloured(RCL1,GCL1,BCL1)
DRAWVLINE(LDT2B)Coloured(RCL1,GCL1,BCL1)
Endif
EndIf
If (DL = 3) Then
DRAWHLINE(LDT1)Coloured(RCL1,GCL1,BCL1)Style(Line,2)
If (DisplayMod > 0) Then                     // Line-Horizontal+Point
DRAWPOINT(LDT1B,LDT1,2)Coloured(RCL1,GCL1,BCL1)Bordercolor(RCL1,GCL1,BCL1)
DRAWPOINT(LDT2B,LDT2,2)Coloured(RCL1,GCL1,BCL1)Bordercolor(RCL1,GCL1,BCL1)
DRAWPOINT(LDT3B,LDT3,2)Coloured(RCL1,GCL1,BCL1)Bordercolor(RCL1,GCL1,BCL1)
EndIf
If (DisplayMod > 1) Then                     // Line-Horizontal+Point+Line-Vertical
DRAWPOINT(LDT1B,LDT1,2)Coloured(RCL1,GCL1,BCL1)Bordercolor(RCL1,GCL1,BCL1)
DRAWPOINT(LDT2B,LDT2,2)Coloured(RCL1,GCL1,BCL1)Bordercolor(RCL1,GCL1,BCL1)
DRAWPOINT(LDT3B,LDT3,2)Coloured(RCL1,GCL1,BCL1)Bordercolor(RCL1,GCL1,BCL1)
DRAWVLINE(LDT1B)Coloured(RCL1,GCL1,BCL1)
DRAWVLINE(LDT2B)Coloured(RCL1,GCL1,BCL1)
DRAWVLINE(LDT3B)Coloured(RCL1,GCL1,BCL1)
EndIf
Endif
//***************************************************************************************************************************************
EndIf // IsLastBarupdate
//***************************************************************************************************************************************
Return
    Nicolas, gnellas77 and gp38super thanked this post
    RFW_Double_Triple_Top_Bottom-1.itf
  • Author
    Posts
Viewing 4 posts - 1 through 4 (of 4 total)
  • You must be logged in to reply to this topic.

horizontal trend lines in prorealtime


General Trading: Market Analysis & Manual Trading

New Reply
Author
author-avatar
gnellas77 @gnellas77 Participant
Summary

This topic contains 3 replies,
has 2 voices, and was last updated by Rainer (RFW)
4 years, 4 months ago.

Topic Details
Forum: General Trading: Market Analysis & Manual Trading
Language: English
Started: 09/26/2021
Status: Active
Attachments: 3 files
Logo Logo
Loading...
Do you like cookies? 🍪 We use cookies to ensure you get the best experience on our website. (Learn more)
©2026 ProRealCode - Trading & Coding with ProRealTime™