Here’s the code:

BBper  = 20                                                //20   periods
BBdev  = 3.0                                               //3.0  deviation
BBavg  = average[BBper,0](close)                           //BB mean (middle line)
BollUP = BBavg + ((std[BBper](close)) * BBdev)             //BB Upper Band
BollDN = BBavg - ((std[BBper](close)) * BBdev)             //BB Lower Band
UPhit  = high >= BollUP
DNhit  = low  <= BollDN
MyRSI  = Rsi[14](close)
RsiOB  = MyRSI > 65
RsiOS  = MyRSI < 30
LongCond  = UPhit AND RsiOB
ShortCond = DNhit AND RsiOS
RETURN LongCond AS "Long", -ShortCond AS "Short"

unfortunately PRT doesn’t allow to set more than 5 conditions for an alert, so if you need 3 different TF’s you’ll have to set two conditions for two of them and only one for the third TF. In your case you only need ONE condition per TF, since the above indicator returns a signal when BOTH Rsi and Bollinger Bands return valid signals.

You’ll have to create two different alerts, one for LONG conditions and one for SHORT conditions.

Anyway, this is a screener that returns a valid scan with a beep:

TIMEFRAME(1 hour)
BBper1  = 20                                                //20   periods
BBdev1  = 3.0                                               //3.0  deviation
BBavg1  = average[BBper1,0](close)                          //BB mean (middle line)
BollUP1 = BBavg1 + ((std[BBper1](close)) * BBdev1)          //BB Upper Band
BollDN1 = BBavg1 - ((std[BBper1](close)) * BBdev1)          //BB Lower Band
UPhit1  = high >= BollUP1
DNhit1  = low  <= BollDN1
MyRSI1  = Rsi[14](close)
RsiOB1  = MyRSI1 > 65
RsiOS1  = MyRSI1 < 30
//
TIMEFRAME(15 minute)
BBper2  = 20                                                //20   periods
BBdev2  = 3.0                                               //3.0  deviation
BBavg2  = average[BBper2,0](close)                          //BB mean (middle line)
BollUP2 = BBavg2 + ((std[BBper2](close)) * BBdev2)          //BB Upper Band
BollDN2 = BBavg2 - ((std[BBper2](close)) * BBdev2)          //BB Lower Band
UPhit2  = high >= BollUP2
DNhit2  = low  <= BollDN2
MyRSI2  = Rsi[14](close)
RsiOB2  = MyRSI2 > 65
RsiOS2  = MyRSI2 < 30
//
TIMEFRAME(5 minute)
BBper3  = 20                                                //20   periods
BBdev3  = 3.0                                               //3.0  deviation
BBavg3  = average[BBper3,0](close)                          //BB mean (middle line)
BollUP3 = BBavg3 + ((std[BBper3](close)) * BBdev3)          //BB Upper Band
BollDN3 = BBavg3 - ((std[BBper3](close)) * BBdev3)          //BB Lower Band
UPhit3  = high >= BollUP3
DNhit3  = low  <= BollDN3
MyRSI3  = Rsi[14](close)
RsiOB3  = MyRSI3 > 65
RsiOS3  = MyRSI3 < 30
//
TIMEFRAME(default)
LongCond  = (UPhit1 AND RsiOB1) AND (UPhit2 AND RsiOB2) AND (UPhit3 AND RsiOB3)
ShortCond = (DNhit1 AND RsiOS1) AND (DNhit2 AND RsiOS2) AND (DNhit3 AND RsiOS3)
x = 0
IF LongCond THEN
   x = 1
ELSIF ShortCond THEN
   x = 2
ENDIF
SCREENER[x](x AS "1=↑,2=↓")

Pic1.jpg Pic2.jpg Pic3.jpg pic4.jpg Pic5.jpg Pic6.jpg