Heikin Ashi Short Setup after Correction

Viewing 3 posts - 1 through 3 (of 3 total)

Author

Posts

03/28/2022 at 1:39 PM #190661 quote

Participant

Veteran

Hi I am using the ‘Heikin Ashi Long Setup after Correction’ screener from member #odin for quite a while now with good results. However I seemed to miss (no, I am not a FOMO patient for sure😀) a lot of very well promising opportunities to the shortside.

I was wondering if anybody (#Odin or #Nicolas , #robertogozzi if Odin is no longer around) is able to rebuilt the screener to a ‘Heikin Ashi Short Setup after Correction’ version, or even better a combined screener for the long and short side?

A simple change of > into < and < into > does not do the trick.

// Trend Template
 
c1 = Average[13](close) > Average[26](close)
c2 = Average[26](close)> Average[52](close)
c3 = average[52](volume*close) > 3000000
 
n = 0
 
if barindex = 0 then
 haOpen = open
 haClose = close
 
elsif N = 0 then
 haClose =(Open+High+Low+Close)/4
 haOpen =(haOpen[1]+haClose[1])/2
 
elsif (barindex MOD N) = 0 then
 haClose =(Open[N]+Highest[N](high)+Lowest[N](low)+Close)/4
 haOpen =(haOpen[1]+haClose[1])/2
endif
 
c4 = haclose > haopen
c5 = haclose[1] < haopen[1]
c6 = haclose[2] < haopen[2]
c7 = haclose[3] < haopen[3]
 
 
 
SCREENER[c1 and c2 and c3 and c4 and c5 and c6 and c7 ](volume*close as "traded volume")

03/29/2022 at 9:55 AM #190707 quote

robertogozzi

Moderator

Legend

This the combined Long & Short version (I have modified the HA setup, but this won’t affect the output):

// Trend Template

haClose = (open + close + high + low) / 4
haOpen  = open
if barindex > 0 then
haOpen  = (haOpen[1] + haClose[1]) / 2
endif
Bullish = haclose > haopen
Bearish = haclose < haopen

// LONG
c1a = Average[13](close) > Average[26](close)
c2a = Average[26](close) > Average[52](close)
c3a = average[52](volume*close) > 3000000
c4a = Bullish
c5a = Bearish[1]
c6a = Bearish[2]
c7a = Bearish[3]
cL  = c1a AND c2a AND c3a AND c4a AND c5a AND c6a AND c7a

// SHORT
c1b = Average[13](close) < Average[26](close)
c2b = Average[26](close) < Average[52](close)
c3b = c3a
c4b = Bearish
c5b = Bullish[1]
c6b = Bullish[2]
c7b = Bullish[3]
cS  = c1b AND c2b AND c3b AND c4b AND c5b AND c6b AND c7b

Result = cL OR cS

SCREENER[Result](volume*close as "traded volume")

Marcel van Vliet thanked this post

03/29/2022 at 1:01 PM #190729 quote

Marcel van Vliet

Participant

Veteran

Thank you very much, excellent job. I wil test the screener during this week.