DEFPARAM CumulateOrders = true
ONCE Lotti = 1
ONCE Distanza = 1 * pipsize //1 pip sopra/sotto massimo/minimo
ONCE NumeroBarre = 2 //2 ultime barre per settare Min/Max
ONCE SL = 15 //15 pips Stop Loss
ONCE TP = 10 //10 pips Target Profit
ONCE Profitto = 0
ONCE Tradare = 1
ONCE Soglia1 = 60 //60 euro perdita
ONCE Soglia2 = 100 //100 euro perdita
ONCE SostaOraria = 0
IF IntraDayBarIndex = 0 THEN
Profitto = StrategyProfit
Tradare = 1
SostaOraria = 0
ENDIF
IF SostaOraria THEN
Tradare = 0
ENDIF
IF StrategyProfit <> StrategyProfit[1] THEN
x = Profitto - StrategyProfit
IF x >= Soglia2 THEN
Tradare = 0
SostaOraria = 0
ELSIF x >= Soglia1 THEN
SostaOraria = ((OpenHour + 1) * 10000) + (OpenMinute * 100)
Tradare = 0
ENDIF
ENDIF
DaysForbidden = OpenDayOfWeek < 1 OR OpenDayOfWeek > 5//tradare solo da Lunedì a Venerdì
TimeForbidden = OpenTime < 090000 OR OpenTime > 190000//tradare solo dalle 9 alle 19
Massimo = highest[Numerobarre](high)
Minimo = lowest[Numerobarre](low)
IF Not OnMarket AND Not DaysForbidden AND Not TimeForbidden AND Tradare THEN
BUY Lotti CONTRACTS AT Massimo + Distanza STOP
SELLSHORT Lotti CONTRACTS AT Minimo - Distanza STOP
SET Target pProfit TP
SET Stop pLoss SL
ENDIF
IF SostaOraria AND (OpenTime >= SostaOraria) THEN
SostaOraria = 0
Tradare = 1
ENDIF
//graph OnMarket
//graph OnMarket[1]
//graph StrategyProfit
//graph Profitto
//graph OpenTime
//graph SostaOraria
//graph Tradare
//graph x
//graph Soglia1
//graph Soglia2
