Hello everyone.

I have found this strategy on the FTSE 100 by playing with candlestick pattern.

In particular here I assumed that 2 doji bull/bear candle are followed by an hammerdown/hammerup candle.

I then added some momentum filter condition based on 3 simple moving average.

The optimization involve:

• the parameter x that define how much doji are the candle
• the profit target
• the trailing stop

Moving averages are not optimized, and long and short trailing stops are set to be the same to avoid overfitting.

Hope you like it.

Francesco

defparam cumulateorders = false
///money management
reinv = 0
leverage= 3

IF REINV = 1 THEN  // réinvestissement
capital = 10000 + strategyprofit
n = (capital / 10000) *leverage
else
n = 1
ENDIF

///market conditions

av1 = average[5](close)
av2 = average[10](close)
av3 = average[50](close)
bull = close> av1 and close >av2 and close > av3
bear = close <av1 and close <av2 and close <av3

///optimized variables
x = 0.6
PR = 50
timestart = 070000
timeend = 230000
TG = 40


///candle pattern defirnitions

timeok = time>timestart and time < timeend
dojibull2 = open[2]<close[2] and abs(open[2]-close[2])/(high[2]-low[2])<x
dojibull1 = open[1]<close[1] and abs(open[1]-close[1])/(high[1]-low[1])<x
dojibear2 = open[2]>close[2] and abs(open[2]-close[2])/(high[2]-low[2])<x
dojibear1 = open[1]>close[1] and abs(open[1]-close[1])/(high[1]-low[1])<x
hammerup = min(open,close)>high-(high-low)/2 //and max(open,close) < min(open[1],close[1])
hammerdown = max(open,close)<low+(high-low)/2 //and max(open,close)<min(open[1],close[1])//and timeok

//trade conditions
cl = (dojibull2 and dojibull1) and hammerdown and bull
cs=  (dojibear2 and dojibear1) and hammerup and bear




if cs  and timeok then
sellshort n contract at market
endif

if cl  and timeok then
buy n contract at market
endif

///ttailing stops
if not onmarket then
MAXPRICE = 0
MINPRICE = close
PREZZOUSCITA = 0
ENDIF
if longonmarket then
MAXPRICE = MAX(MAXPRICE,close)
if MAXPRICE-tradeprice(1)>=TG*pointsize then
PREZZOUSCITA = MAXPRICE-TG*pointsize
ENDIF
ENDIF
if shortonmarket then
MINPRICE = MIN(MINPRICE,close)
if tradeprice(1)-MINPRICE>=TG*pointsize then
PREZZOUSCITA = MINPRICE+TG*pointsize
ENDIF
ENDIF
if onmarket and PREZZOUSCITA>0 then
EXITSHORT AT PREZZOUSCITA STOP
SELL AT PREZZOUSCITA STOP
ENDIF

//fixed profit target
set target pprofit PR

ftsedojihammer-14996121824cp8l.png wf_results_3.png wf_results_2.png wf_results_1.png doji_and_hammer_ftse100_1hr.itf