defparam drawonlastbaronly   = true
defparam calculateonlastbars = 1000
P = 200
X= highest[P](high)
A= lowest[P](low)
 
RangeMax = (X - A) * 0.618
RangeMin = (X - A) * 0.500
BarraA = 0
BarraB = 0
For i = 1 To 1000
If high <= RangeMax  Then
BarraB = BarIndex[i]
Endif
If low = A Then
BarraA = BarIndex[i]
Endif
If BarraA and BarraB Then
Break
Endif
Next
DRAWSEGMENT(BarraA,A,BarraB,RangeMax)
return

scusami ma non avevo capito…allora ho unito il tutto ma mi dice comunque di definire il “rangemin”

(forse sono io che non riesco nemmeno ad unire le due cose insieme…)

Capisco la vostra attesa, ma è abbastanza macchinoso riuscire a fare quello che chiedi.

Prendere un Massimo ed un Minimo e visualizzare i livelli di Fibonacci è di una semplicità estrema e ce ne sono di codici qui sul forum.

Partire da un minimo A, poi individuare B (se nel frattempo il prezzo scende sotto A, questo diventa la nuova A), se poi il prezzo supera B questo diventa la nuova B, se poi il prezzo scende occorre individuare C che sia tra le due percentuali indicate, se scende sotto 76.4 occorre riazzerare tutto e ricominciare nuovamente a trovare A, ecc…. è una cosa difficile, non tanto concettualmente, quanto nella scrittura del codice perché prevede molti intrecci.

Io ho scritto intanto i punti A e B, sto cercando di mettere a punto C, ma devo fare ancora delle prove.

Qusto è il codice, fino al punto C. Nella foto del DAX h1 di adesso il punto C non è stato ancora raggiunto, ma spero lo faccia per vedere se viene stampato correttamente, dopodiché diventa semplice fare la proiezione per il punto D:

DEFPARAM DrawOnLastBarOnly = true
IF BarIndex = 0 OR (Barra > MaxBarre) THEN
   MaxBarre = 100
   Distanza = 5 * pipsize
   PuntoA   = low
   BarraA   = BarIndex
   PuntoB   = high
   BarraB   = BarIndex
   PuntoC   = 0
   BarraC   = 0
   PuntoD   = 0
   BarraD   = 0
   Barra    = 0
ENDIF
Barra = Barra + 1                //incrementare il passare delle barre per azzerare tutto quando arriva a 100
//
// Determinare se il prezzo scende sotto A, in tal caso avremo una nuova A più bassa e ripartiremo daccapo con B,C e D
PuntoA = min(PuntoA,low)
IF PuntoA < PuntoA[1] THEN
   BarraA = BarIndex
   Barra  = 0
   PuntoB = high
   BarraB = BarIndex
   PuntoC = 0
   BarraC = 0
   PuntoD = 0
   BarraD = 0
ENDIF
//
// Determinare se il prezzo sale sopra B, in tal caso avremo una nuova B più alta e ripartiremo daccapo con C e D
PuntoB = max(PuntoB,high)
IF PuntoB > PuntoB[1] THEN
   PuntoC = 0
   BarraC = 0
   PuntoD = 0
   BarraD = 0
ENDIF
// Calcolare la differenza tra i punti A e B e le due percentuali di fibonacci da usare per la verifica di C
DiffAB = PuntoB - PuntoA
FibC1  = DiffAB * 0.618
FibC2  = DiffAB * 0.786
IF low <= (PuntoB - FibC1) AND low >= (PuntoB - FibC2) THEN
   // se il MINIMO è tra 0.618 e 0.786 abbiamo trovato il punto C....
   PuntoC = low
   BarraC = BarIndex
ELSIF low < (PuntoB - FibC2) THEN
   // ...altrimenti si riparte daccapo con un nuovo punto A ed un nuovo punto B
   PuntoA = low
   BarraA = BarIndex
   PuntoB = high
   BarraB = BarIndex
   PuntoC = 0
   BarraC = 0
   PuntoD = 0
   BarraD = 0
   Barra  = 0
ENDIF
// si stampano i punti trovati, ognuno dipendente dal precedente, si stampa A, poi B solo se A è stato stampato, poi C solo se B è stato stampato ed infine D se anche C è stato stampato
IF PuntoA > 0 THEN
   DRAWSEGMENT(BarraA,PuntoA,BarIndex,PuntoA) COLOURED(255,0,0,255)            //Rosso
   DRAWTEXT("A",BarraA,PuntoA - Distanza,Dialog,Bold,14) coloured(205,0,205,255))
   IF PuntoB > 0 THEN
      DRAWSEGMENT(BarraB,PuntoB,BarIndex,PuntoB) COLOURED(0,255,0,255)         //Verde
      DRAWTEXT("B",BarraB,PuntoB + Distanza,Dialog,Bold,14) coloured(205,0,205,255))
      IF PuntoC > 0 THEN
         DRAWSEGMENT(BarraC,PuntoC,BarIndex,PuntoC) COLOURED(0,0,255,255)      //Blu
         DRAWTEXT("C",BarraC,PuntoC - Distanza,Dialog,Bold,14) coloured(205,0,205,255))
         IF PuntoD > 0 THEN
            DRAWSEGMENT(BarraD,PuntoD,BarIndex,PuntoD) COLOURED(238,201,0,255) //Oro
            DRAWTEXT("D",BarraD,PuntoD + Distanza,Dialog,Bold,14) coloured(205,0,205,255))
         ENDIF
      ENDIF
   ENDIF
ENDIF
RETURN

x-14.jpg