Je tente sans succès d’écrire un indicateur.
Les lignes 7 et 8 me renvoient une erreur . Les limites de mes connaissances butent sur la correction.
Pouvez vous m’aider . En vous remerciant par avance.
Ci joint copie d’écran.
avec la lecture du code cela sera plus facile . Avec mes excuses.
// Retournement haussier - Daily - MM20/50 + SuperTrend(3,10) + PRT Bands
// Version swing / positionnel sur actions FR/NL/DE
// 1. Croisement haussier MM (récent ou déjà fait)
c_MM = Average[20](Close) CROSSES OVER Average[50](Close)
OR (Average[20](Close) > Average[50](Close)
AND Average[20](Close)[1] <= Average[50](Close)[1])
// 2. Flip SuperTrend haussier
c_ST = Close CROSSES OVER SuperTrend[3,10]
OR (Close > SuperTrend[3,10]
AND Close[1] <= SuperTrend[3,10][1])
// 3. PRT Bands : breakout ou flip vers haussier
c_PRT = (Close CROSSES OVER PRTBANDSUP)
OR (Close > PRTBANDSUP
AND PRTBANDSSHORTTERM > PRTBANDSMEDIUMTERM
AND PRTBANDSSHORTTERM[1] <= PRTBANDSMEDIUMTERM[1])
// 4. Filtres qualité
c_Vol = Volume > Average[20](Volume) * 1.4
c_RSI = RSI[14](Close) > 48
c_Prix = Close > Average[200](Close) * 0.92
// Synthèse : au moins 2 confirmations sur les 3 + filtres
SCREENER [ (c_MM OR c_ST OR c_PRT) AND (c_MM + c_ST + c_PRT >= 2) AND c_Vol AND c_RSI AND c_Prix ]
(Close AS "Prix",
Average[20](Close) AS "MM20",
Average[50](Close) AS "MM50",
SuperTrend[3,10] AS "SuperT 3/10",
RSI[14] AS "RSI14")
SORT BY Volume DESC
JSParticipant
Senior
Bonjour,
Vous ne pouvez pas utiliser de tiret bas (« underscore ») dans le nom d’une variable…
Vous ne pouvez pas utiliser « RETURN » au milieu de conditions liées entre elles…
JSParticipant
Senior
// Retournement haussier – Daily – MM20/50 + SuperTrend(3,10) + PRT Bands
// Version swing / positionnel sur actions FR/NL/DE
// 1. Croisement haussier MM (récent ou déjà fait)
cMM = Average[20](Close) CROSSES OVER Average[50](Close)OR (Average[20](Close) > Average[50](Close) AND Average[20](Close)[1] <= Average[50](Close)[1])
// 2. Flip SuperTrend haussier
cST = Close CROSSES OVER SuperTrend[3,10] OR (Close > SuperTrend[3,10] AND Close[1] <= SuperTrend[3,10][1])
// 3. PRT Bands : breakout ou flip vers haussier
cPRT = (Close CROSSES OVER PRTBANDSUP) OR (Close > PRTBANDSUP AND PRTBANDSSHORTTERM > PRTBANDSMEDIUMTERM AND PRTBANDSSHORTTERM[1] <= PRTBANDSMEDIUMTERM[1])
// 4. Filtres qualité
cVol = Volume > Average[20](Volume) * 1.4
cRSI = RSI[14](Close) > 48
cPrix = Close > Average[200](Close) * 0.92
// Synthèse : au moins 2 confirmations sur les 3 + filtres
SCREENER [ (cMM OR cST OR cPRT) AND (cMM + cST + cPRT >= 2) AND cVol AND cRSI AND cPrix ] (Close AS “Prix”,Average[20](Close) AS “MM20”,Average[50](Close) AS “MM50”,SuperTrend[3,10] AS “SuperT 3/10”,RSI[14] AS “RSI14”)
//SORT BY Volume DESC
Merci de votre réponse.
Je pensais que le problème se trouvait sur les espaces en ligne 7 et 8 sur mon dossier joint en copie . Je n’ai pas trouvé la fonction “RETURN”. Merci pour vos conseils.
JSParticipant
Senior
Bonjour,
Ce que je voulais dire par “return”, c’est que lorsque vous définissez une condition, elle doit être écrite sur une seule ligne, sans utiliser de saut de ligne (la touche “Entrée” du clavier, appelée “hard Return”)…
Par exemple :
cST = … or … and … (cela doit être sur une seule ligne)
Pas :
cST = … or … (saut de ligne)
and …
J’espère que c’est un peu plus clair ainsi…
Merci JS .
Effectivement cela devient plus clair. Il va falloir que je progresse.
Bonne journée a toi.
Cordialement.
