There you go:

DEFPARAM CumulateOrders = false
//-------------------------------------------------------------------------
//                          Bollinger Bands 1
ONCE BBperiods1 = 50                                          //50   BB periods
ONCE BBdev1     = 2.0                                         //2.0  BB deviation
ONCE AvgType1   = 0                                           //0=sma, 1=ema, etc...
BBavg1          = average[BBperiods1,AvgType1](close)         //BB mean (middle line)
BollUP1         = BBavg1 + ((std[BBperiods1](close)) * BBdev1)//BB Upper Band
BollDN1         = BBavg1 - ((std[BBperiods1](close)) * BBdev1)//BB Lower Band
//-------------------------------------------------------------------------
//                          Bollinger Bands 2
ONCE BBperiods2 = 50                                          //50   BB periods
ONCE BBdev2     = 3.0                                         //3.0  BB deviation
ONCE AvgType2   = 0                                           //0=sma, 1=ema, etc...
BBavg2          = average[BBperiods2,AvgType2](close)         //BB mean (middle line)
BollUP2         = BBavg2 + ((std[BBperiods2](close)) * BBdev2)//BB Upper Band
BollDN2         = BBavg2 - ((std[BBperiods2](close)) * BBdev2)//BB Lower Band
//-------------------------------------------------------------------------
//                          Bollinger Bands 3
ONCE BBperiods3 = 50                                          //50   BB periods
ONCE BBdev3     = 4.0                                         //4.0  BB deviation
ONCE AvgType3   = 0                                           //0=sma, 1=ema, etc...
BBavg3          = average[BBperiods3,AvgType3](close)         //BB mean (middle line)
BollUP3         = BBavg3 + ((std[BBperiods3](close)) * BBdev3)//BB Upper Band
BollDN3         = BBavg3 - ((std[BBperiods3](close)) * BBdev3)//BB Lower Band
//-------------------------------------------------------------------------
//                          Stochastic
MyStoch         = Stochastic[14,3](close)
//-------------------------------------------------------------------------
//
//                          Rsi
MyRsi           = Rsi[8](close)
//-------------------------------------------------------------------------
// Entry conditions
c1              = low     < BollDN2
c2              = MyStoch < 20
c3              = MyRsi   < 30
// Exit  conditions
d1              = high <= BBavg1
//-------------------------------------------------------------------------
// enter a position
IF c1 AND c2 AND c3 AND Not LongOnMarket THEN
   BUY 1 CONTRACT AT Market
   SL = abs(close - BollDN3)
   SET STOP LOSS SL
ENDIF
// update Stop Loss according to TRADEPRICE (instead of close) when known
IF LongOnMarket AND Not LongOnMarket[1] THEN
   SL = abs(TradePrice - BollDN3[1])
   SET STOP LOSS SL
ENDIF
// exit any open position
IF d1 AND LongOnMarket THEN
   SELL AT Market
ENDIF
//
//graphonprice TradePrice
//graphonprice TradePrice - SL