@Nicolas –  when I mirror the conditions for long and short I normally have the long a bit lower and the short a bit higher for a better result. In this case there’s an error in the buying condition as I pointed out later on. It should be “cross over -150” (almost the same as cross under 140) and not -240.

@GraHal – Thanks for the link, I’ll check it out! The draw down visible on the picture I uploaded is smoothen out with the correct buying condition so I’m hoping that the real test will be okay. Let’s have a review after a few trades.

I’m short too on my demo and I’ll let it run to see how the exit is handled. If you are stopping now I can congratulate you to 60 pips 🙂

Hi Nicolas, Yes the long trades was solved buy updating the entry criteria.

The system closed the position on 1.07708 (about 45 pips profit) and has now opened a new short. You can put the code in the library but I’m afraid I don’t have time at the moment to rewrite it more nicely were every indicator is specified only once. I have attached the correct code and I have updated this one with an additional criteria on

// Definition of code parameters
DEFPARAM CumulateOrders = False // Cumulating positions deactivated

// Prevents the system from placing new orders on specified days of the week
daysForbiddenEntry = OpenDayOfWeek = 6 OR OpenDayOfWeek = 0

// Conditions to enter long positions
indicator1 = CCI[8]
c1 = (indicator1 CROSSES OVER -150)
indicator2 = BollingerBandWidth[20](close)
c2 = (indicator2 > 0.003)
indicator3 = TRIX[12](close)
indicator4 = Average[9](indicator3)
c3 = (indicator3 > indicator4)
indicator5 = TRIX[15](close)
c4 = (indicator5 < 0.015)

IF (c1 AND c2 AND c3 AND c4) AND not daysForbiddenEntry THEN
BUY 1 CONTRACT AT MARKET
ENDIF

// Conditions to enter short positions
indicator7 = CCI[8]
c5 = (indicator7 CROSSES UNDER 140)
indicator8 = BollingerBandWidth[20](close)
c6 = (indicator8 > 0.003)
indicator9 = Average[9](TRIX[12](close))
indicator10 = TRIX[12](close)
c7 = (indicator9 > indicator10)
c8 = (indicator5 > -0.015)

IF (c5 AND c6 AND c7 AND c8) AND not daysForbiddenEntry THEN
SELLSHORT 1 CONTRACT AT MARKET
ENDIF

// Stoploss
SET STOP pLOSS 55
trailingstart = 50 //trailing will start @trailinstart points profit
trailingstep = 5 //trailing step to move the "stoploss"

//reset the stoploss value
IF NOT ONMARKET THEN
newSL=0
ENDIF

//manage long positions
IF LONGONMARKET THEN
//first move (breakeven)
IF newSL=0 AND close-tradeprice(1)>=trailingstart*pipsize THEN
newSL = tradeprice(1)+trailingstep*pipsize
ENDIF
//next moves
IF newSL>0 AND close-newSL>=trailingstep*pipsize THEN
newSL = newSL+trailingstep*pipsize
ENDIF
ENDIF

//manage short positions
IF SHORTONMARKET THEN
//first move (breakeven)
IF newSL=0 AND tradeprice(1)-close>=trailingstart*pipsize THEN
newSL = tradeprice(1)-trailingstep*pipsize
ENDIF
//next moves
IF newSL>0 AND newSL-close>=trailingstep*pipsize THEN
newSL = newSL-trailingstep*pipsize
ENDIF
ENDIF

//stop order to exit the positions
IF newSL>0 THEN
SELL AT newSL STOP
EXITSHORT AT newSL STOP
ENDIF

both long and short which prevents from entering positions following the shorter trend when the price is in an oversold or overbought stage. This only excluded 10 trades out of 400+ so I think it’s acceptable.