Eccolo:

ONCE fineTrading = 230000   // 240000 per non terminare mai, altrimenti indicare l'ora corretta
ONCE MaxCandele  = 5        // durata dell'ordine STOP (che va comunque piazzato ad ogni candela)
ONCE myTime      = 153000   // data di riferimento
ONCE refPrice    = 0        // prezzo di riferimento delle 153000
ONCE Ribasso     = 200 * PipSize // ribasso oltre il quale piazzare l'ordine STOP
ONCE Entrata     = 100 * PipSize // prezzo d'entrata a +100 punti
ONCE Trading     = 0
//
IF OnMarket OR (Conteggio > MaxCandele) THEN
   Trading = 0
ENDIF
//
// alle 15:30 prendere come riferimento la chiusura della candela (cioè quello delle ore 15:45)
IF OpenTime = myTime THEN
   refPrice  = close
   Trading   = 1
   Conteggio = 0
ENDIF
//
IF OpenTime = fineTrading THEN
   SELL AT MARKET
   Trading  = 0
ENDIF
//
IF (OpenTime < fineTrading) AND (OpenTime > myTime) AND Trading AND Not OnMarket THEN
   IF (refPrice - Ribasso) >= close THEN
      BUY 1 CONTRACT at close + Entrata STOP
      Conteggio = Conteggio + 1
   ENDIF
ENDIF
//graphonprice refPrice           coloured("Black") AS "Prezzo 15:30"
//graphonprice refPrice - Ribasso coloured("Red")   AS "Prezzo per entrare"
//graphonprice close + Entrata    coloured("Blue")  AS "Prezzo d'entrata"
//graph Trading
//graph Conteggio