Bonjour,

Pour la 1re question, le code s’éxécute dans le sens du défilement du temps (donc de gauche à droite pour reprendre les termes de la question). Comme je vois que tu as tenté une solution avec boucles, par extension pour la même question je rajouterais ceci: même une boucle que tu ferais aller de droite vers gauche ne signifie pas que le code va aller s’éxécuter dans d’autres bougies vers la gauche, la boucle a lieu dans la bougie, mais en faisant éventuellement appel aux données enregistrées de bougies précédentes.

Pour la 2ème question, ceci devrait faire ce que tu cherches toutes les 30 (ou period à modifier en ligne 1) barres. La ligne 8 en drawrectangle est mise en commentaire, mais tu peux enlever les // devant pour faire apparaitre un rectangle encadrant chaque groupe de period barres et vérifier tes couples +haut+bas:

Period = 30

if barindex mod period = 0 then
 DRAWTEXT(HighestV, HighestI, HighestV+2, Dialog, Standard, 12)COLOURED(0,255,0)
 DRAWARROWDOWN(HighestI,HighestV+1) COLOURED(0,255,00)
 DRAWTEXT(LowestV, LowestI, LowestV-2, Dialog, Standard, 12)COLOURED(200,0,0)
 DRAWARROWUP(LowestI,LowestV-1) COLOURED(255,0,00)
 //DRAWRECTANGLE(barindex[period], LowestV, barindex, HighestV)
 HighestV=low
 LowestV=high
endif

if high>HighestV then
 HighestV=high
 HighestI=barindex
endif
if low<LowestV then
 LowestV=low
 LowestI=barindex
endif
 
RETURN

Rien n’empêche de se servir de boucles si tu veux, mais quand c’est possible il vaut mieux privilégier une solution sans boucle pour la vitesse d’éxécution. J’ai changé la logique pour me débarrasser de la boucle, et j’ai gardé tes noms de variables pour s’y retrouver facilement. A tester pour confirmation.

Il n’a pas été question d’un calculateonlastbars=50 dans le message auquel j’ai répondu, tu le rajoutes ensuite et ça impacte le comportement au début: en effet dans ce cas il ne faut pas regarder 10 barres avant le premier rectangle, mais 50 barres avant la bougie de lancement, et si par exemple il y en a eu 4 après le dernier rectangle au moment du lancement, tu n’en auras que 6 sur 10 qui comptent dans ce que tu penses être les 10 premières barres (c’est à dire que tu as limité à 50 le calcul mais tu espères voir des choses à partir de la 56ème précédente, ça va pas le faire…)

En ce qui concerne les 10 dernières, et l’affichage des rectangles là ce n’est pas lié au calculateonlastbars, mais à ta demande de ne pas avoir d’effet glissant et je cite “que le code se réexécute sur l’historique uniquement après chaque période de 20-30jrs”. La fin d’un rectangle marque la fin d’une période de “20-30” (ou de period=10 dans ta capture écran), et donc le code t’affichera le dernier rectangle, le plus haut et le plus bas de la période de “period” jours quand le nouvel intervalle de “period” jours sera terminé. Si tu veux compter les “period” jours dans l’autre sens, alors tu réintroduirais l’effet glissant, ce que tu as explicitement dit ne pas vouloir. Ou sinon il faut expliquer différemment comment tu veux ta période de 20-30 jours, de là je peux voir si c’est modifiable.

DEFPARAM DRAWONLASTBARONLY=true
DEFPARAM CALCULATEONLASTBARS = 51

Period = 10
nb=5
HighestV = Highest[Period](high)
LowestV = Lowest[Period](low)

if IsLastBarUpdate then
 
 For j = 1 To nb do
  for i = 0 To Period-1 do
 
   IF High[period*(j-1)+i]=HighestV[(j-1)*period] Then
    HighestI = BarIndex[period*(j-1)+i]
    DRAWTEXT(HighestV[(j-1)*period], HighestI, HighestV[(j-1)*period]+2, Dialog, Standard, 12) COLOURED(0,255,0)
    DRAWARROWDOWN(HighestI,HighestV[(j-1)*period]+1) COLOURED(0,255,00)
   endif
   IF Low[period*(j-1)+i]=LowestV[(j-1)*period] Then
    LowestI = BarIndex[period*(j-1)+i]
    DRAWTEXT(LowestV[(j-1)*period], LowestI, LowestV[(j-1)*period]-2, Dialog, Standard, 12) COLOURED(200,0,0)
    DRAWARROWUP(LowestI,LowestV[(j-1)*period]-1) COLOURED(255,0,00)
   endif
 
  next
  DRAWRECTANGLE(barindex[j*(period)]+1, LowestV[(j-1)*period], barindex[(j-1)*period], HighestV[(j-1)*period])
 next

endif

RETURN