Salut
Je tiens d’abord à vous féliciter pour votre tentative.
Je réponds en fonction de vos questions :
J’en viens maintenant à ma demande sur le «Bollinger»
1.- Le « milieu » bollinger peut être mis en couleur s’il chute et également s’il téléski avec entre les 2, le point de retour
Voici le code indicateur des bandes de Bollinger comme demandé :
////Bollinger bands
bbup = BollingerUp[20](close)
bbdown = BollingerDown[20](close)
bbavg = (bbup+bbdown)/2 //same as simple moving average
//ma = average[20](close)
if bbavg > bbavg[1] then
rline = 0
gline = 250
bline = 0
else
rline = 250
gline = 0
bline = 0
endif
RETURN bbavg as "Bollinger Avg" coloured(rline,gline,bline), bbup as "Bollinger Up",bbdown as "Bollinger down"
2.- Comment définir cette courbe de Bollinger millieu ? Direz-vous : BB = moyenne[BBval,(0)](close) ?
Les bandes de Bollinger supérieure et inférieure sont construites par défaut autour d’une moyenne mobile simple sur 20 périodes.
Par conséquent, la bande de Bollinger moyenne est la moyenne mobile simple.
Vous pouvez également calculer la valeur de la bande supérieure et de la bande inférieure et calculer le point médian. Le résultat sera le même.
3.- Commentaire définir ce point de retour (chute… point de retour… remontée ?
Tournant haussier : lorsque la bande de Bollinger médiane cesse de monter et commence à baisser.
Tournant baissier : lorsque la bande de Bollinger médiane cesse de baisser et commence à monter.
Ci-dessous, vous pouvez voir un indicateur montrant les points de retournement haussier (+1) et baissier (-1).
////Bollinger bands
bbup = BollingerUp[20](close)
bbdown = BollingerDown[20](close)
bbavg = (bbup+bbdown)/2 //same as simple moving average
//ma = average[20](close)
//
if bbavg > bbavg[1] and bbavg[1] < bbavg[2] then
infl = 1
rbar=0
gbar=250
bbar=0
elsif bbavg < bbavg[1] and bbavg[1]>bbavg[2] then
infl = -1
rbar=250
gbar=0
bbar=0
else
infl = 0
endif
RETURN infl as "Point d'inflexion" coloured(rbar,gbar,bbar)style(histogram),0 as "0"style(dottedline,1)
Concernant le screener que vous avez programmé. Vous cherchez cela?
1.- Prix supérieur à 3 $ ou €
2.- Volume supérieur à 50 000
3.- Croisement haussier de la moyenne de Bollinger avec la moyenne pondérée de 14 périodes au cours des 10 dernières périodes.
Si c’est le cas, le code serait le suivant :
////Bollinger bands
bbup = BollingerUp[20](close)
bbdown = BollingerDown[20](close)
bbavg = (bbup+bbdown)/2 //same as simple moving average
///close
c1 = close > 3
///Volume
c2 = average[20](volume)>50000
///
wma = weightedaverage[14](close)
//c3 = bbavg crosses over wma
for i=0 to 10 do
if wma[i] crosses over bbavg[i] then
c3=1
x=i
break
else
c3 = 0
endif
next
screener [c1 and c2 and c3 and x<10](x as "periods")
