Watanabix wrote:

Because the close happens at the end of the bar, it will only try to go long at the next bar, which is not ideal but I don’t think I should worry about that aspect right now while I still have several things to polish/fix.

It is very correct that you should not be bothered by this now. But for later, write down : MultiTimeFrame (you can use a faster timeframe for quicker responses). But indeed not know, as you first need to get the base right.

IF close >= LongEntryPoint  AND Tally < MaxTrades  THEN 
 
  Graph 2 as "ReadyForTrade1Check"
 
  BUY CON CONTRACTS At LongEntryPoint limit  
  Graph Tally  as "Tally"
  SET TARGET PPROFIT PT 
  SET STOP PRICE LO - Candlelength * StopAdjuster
 
  if LONGTRIGGERED THEN // tried to use this function to help with the tally variable accumulated number but didn't go much farther
    Graph 5 as "OrderPlaced"
    Tally = Tally +1
  ENDIF 
ENDIF

You can clearly (?) see that this can never work. So when your code is called after this 15 minutes where you want to enter, the order is not there yet, so LongTriggered will still be false (0).
This should solve that :

IF close >= LongEntryPoint  AND Tally < MaxTrades  THEN 
 
  Graph 2 as "ReadyForTrade1Check"
 
  BUY CON CONTRACTS At LongEntryPoint limit  
  Graph Tally  as "Tally"
  SET TARGET PPROFIT PT 
  SET STOP PRICE LO - Candlelength * StopAdjuster
Endif

if LONGTRIGGERED THEN // Was a Long order created during the previous bar ?
  Graph 5 as "OrderPlaced"
  Tally = Tally +1
ENDIF 

For you it is crucial to realise that both If’s above do not become true during the same call of your code; the first may be true when your Entry condition complies and the 2nd If may be true later or much later, when the Limit order was filled, which always occurs in the previous bar (never in the bar AFTER which your code is called at the close).
If you can’t grasp this latter sentence (which is imaginable), sit back and think as long as needed to get what actually happens. For understanding, it could be a good idea to make it a normal Market order first. Then you’re not dependent on the invisible (is your order filled or not). Do you have that working ? then make it a Limit order again.

IF close >= LongEntryPoint  AND Tally < MaxTrades  THEN 
 
  Graph 2 as "ReadyForTrade1Check"
 
  BUY CON CONTRACTS At LongEntryPoint limit  
  Graph Tally  as "Tally"
  SET TARGET PPROFIT PT 
  SET STOP PRICE LO - Candlelength * StopAdjuster

This is an example again which will make it unreadable to  yourself. Out of context I cannot understand what you’re doing there. Change that to this :

If Tally < MaxTrades  THEN   // Number of trades for the day not reached yet ?

  IF close >= LongEntryPoint
 
    Graph 2 as "ReadyForTrade1Check"
 
    BUY CON CONTRACTS At LongEntryPoint limit  
    Graph Tally  as "Tally"
    SET TARGET PPROFIT PT 
    SET STOP PRICE LO - Candlelength * StopAdjuster

and suddenly I don’t NEED the context. It does exactly the same as how you have it, but in one go your eyes can go to under the main EndIf of this when needed.
It will make you see where things are – or can be wrong elsewhere.

The same thing is going on with your line checking the dead times (100000 and 160000) and the On Market. You should have a main if for not OnMarket and under that the remainder. Now suddenly your code becomes “small”, never mind additional lines were added. Just try it.

If Not OnMarket then

  if OpenTime >= 100000 and opentime < 160000
 
    Graph 12 as "StartOfSystem"
    Graph 1 as "ReadyForTrade1Check"
    Graph Tally  as "Tally"
 
      If Tally < MaxTrades  THEN 

        [...]

You will now soon get there. You will see … 🙂
And in case you now readily achieve things : I think you should do something about the dead time logic because you will (?) soon see that this makes things unworkable for you, before it starts to work. Thus next advice is, remove the FlatBefore and FlatAfter commands for now. They WILL be in your way of understanding, because things happen which are out of your control and they will obfuscate. The If for the Entry times is fine.
Anyway just think of what happens when you enter at 15:45 (which of course will be 16:00 because of being one bar behind always). Your further logic in the program does not cope with this by any means (that I can see).
When the base works you can add those commands again, and you may soon see that they are impossible to work with to begin with. But this is for later.

Have fun !

Hi,
Here is the base code with the adjustments…
The code will execute one profitable order per day, and if this order is a losing one, an additional order will be executed…

DefParam CumulateOrders=False

DefParam FlatBefore=094500
DefParam FlatAfter=160000

Once MaxTrades=2
Once Buffer=0
Once PT=200

IF IntraDayBarIndex=0 THEN
TradeCount=0
TradeOn=1
ENDIF

If StrategyProfit>StrategyProfit[1] then
TradeOn=0
EndIf

If LongTriggered or ShortTriggered then
TradeCount=TradeCount+1
EndIf

If OpenTime=094500 then
HI=High
LO=Low
CandleLength=HI-LO
EndIf

If NOT ONMARKET and TradeOn=1 and TradeCount<MaxTrades then
If Close>HI+buffer then
BUY 1  CONTRACTS AT HI+buffer limit
SET STOP PRICE LO
SET TARGET pProfit PT
EndIf

IF Close<LO-buffer then
SELLSHORT 1 CONTRACTS AT LO-buffer limit
SET STOP PRICE HI
SET TARGET pProfit PT
EndIf
EndIf

Graph TradeCount as "TradeCount"
Graph TradeOn as "TradeOn"
GraphOnPrice HI as "HI"
GraphOnPrice LO as "LO"
  

Hi Tiago,

As you already mentioned, undesirable actions occur after partial sessions due to holidays.

Naturally, this happens because the code cannot be executed “normally” on these days.

The best solution is to avoid such days, for example, with:

Date1=20241001

Date2=20241129

If OpenDate<>Date1 and OpenDate<>Date2 then

(Your Strategy)

EndIf

(This topic has also been extensively discussed on the forum)