Hi guys, @Eric, thank you for sharing this idea, which I quite like; @victormork thank you for your contribution with the stop logic. I have optimized some of the logic statements and added few more “bells and whistles” (modules) to the system which can be easily switched on and off. Most of the modules are in the interest of increasing hit rate and reducing equity curve volatility. As it stands, I have optimized a bit on DAX M30 and experimented a little on DAX H1. I think it may almost be ready to submit this to the library (Nicolas?) but hoping you guys will test it out and play around on different markets etc. Add or remove modules as you wish until it makes sense. I suggest to disengage all the modules when trying a new asset or asset class, optimize the basic variables and then add the modules one by one. Please post your results here. The modules I have added are:

• Variable-set selection framework You can optimize differently for whatever asset and timeframe  and save the set inside a

  elsif optimization = (x) then

• Soft time stop The soft time stop simply counts the total number of bars of in loss endured during the trade (not consecutive but total bars of loss) and once a threshold is reached, triggers a break even signal so that the trade will at least break even if/when given the chance. The variable to adjust is softTimeStopBars (0 for off else positive number for number of bars in loss to trigger)

• Second chance Stop The second chance stop, if engaged, monitors for a trade going into profit, followed by losing x% of the maximum gain  (typically 70-90% retracement towards original entry). If this occurs a trigger is set to exit the trade when the gain reaches or exceeds the highest high of that trade’s equity curve (a second chance).  The variable scRetraceTrigger is used to set the percentage retrace before we grab a second chance exit. 0.5 = 50% retracement. 1 =  100% retracement. It can also be set to negative value for monitoring if it went into loss after first being profitable). scMinBarsInTrade suspends monitoring until the trade has been on for at least a given number of bars.

• ATR based target (limit) Often times you want limit orders to be a proportion of the current market volatility (so that you don’t set them too far or too near). Set useATRTarget to 1 to engage the system. atrTargetMultiple determines the limit order target by multiple of atr[40]

• ATR filter When ATR filter is engaged, no trades will be taken unless atr[40] is above the given threshold. This reduces the likelihood of weak setups.

// -- // -- // -- // -- // -- |
// // -- // -- // -- // -- // |
// == Aroon System DAX M30 == |
// -- // -- // -- // -- // -- |
// // -- // -- // -- // -- // |

// Aroon System
// Version 1.01
// Contributors:
//    Eric @ prorealcode.com
//    Victormork @ prorealcode.com
//    Maz @ prorealcode.com
// --------------
// Modules:
//    Variable set selection framework
//    Optional donchian stop      (useDonchianStop)
//    Optional trailing stop      (useTrailingStop)
//    Optional soft time stop     (softTimeStopBars > 0)
//    Optional second chance Stop (useSecondChanceStop) [version 0.11 alpha]
//    Optional ATR based target   (useATRTarget)
//    Optional ATR filter         (useATRFilter)
// --------------
// Originally developed for DAX M30

DEFPARAM CumulateOrders = false

// -- Variable Selection --
once positionSize = 1
once optimization = 1

if optimization = 1 then // DAX M30 (June 2016 - Apr 2017)
useDonchianStop     = 1                    // Engage Donchian Stop? 0:no | 1: yes
useTrailingStop     = 1                    // Engage trailing stop? 0:no | 1: yes
trailingStop        = 51 //50                // trailing stop distance
once tsLongDistance = trailingStop
once tsShortDistance= trailingStop

useATRTarget        = 1                   // Engage ATR Limit 0:no | 1: yes
atrTargetMultiple   = 21                    // Limit is x times current ATR[40]

useATRFilter        = 1                   // Engage ATR filter 0: no | 1: yes
atrThreshold        = 15 // 11              // only trade if ATR is above x

useSecondChanceStop = 0                   // Engage 2nd chance stop. 0: off | 1: on
scRetraceTrigger    = 0.5 // 0.4            // % of max profit reduction to trigger 
scMinBarsInTrade    = 14  // 2              // min # bars before trigger     

softTimeStopBars    = 37 // 35 // 0: off | lower = higher hit rate

maShortPeriod       = 50                  // short term MA period
maLongPeriod        = 90                  // long term MA period
arroonPeriod        = 14
once arroonUpPeriod = arroonPeriod
once arroonDnPeriod = arroonPeriod

stMultiplier        = 2                   // Super trend multiplier
stPeriods           = 7 // 10             // Super trend period
donchianChPeriod    = 61 //70

tradingTime         = 1//(time >= 080000 and time < 163000)

elsif optimization = 2 then // DAX H1 (experimental)
useATRTarget         = 0
atrTargetMultiple   = 21
softTimeStopBars    = 0
useATRFilter         = 0
atrThreshold         = 15
useSecondChanceStop = 0
//scRetraceTrigger    = 0.5 // 0.4
//scMinBarsInTrade    = 14  // 2

useDonchianStop      = 1
useTrailingStop      = 1
trailingStop         = 45 // 48 //43
once tsLongDistance  = trailingStop
once tsShortDistance = trailingStop

arroonPeriod         =  14 // 15
once arroonUpPeriod = arroonPeriod
once arroonDnPeriod = arroonPeriod

stMultiplier        = 3.5 // 3.75
stPeriods           = 14 // 13
donchianChPeriod    = 50 // 55 //70

maShortPeriod       = 53
maLongPeriod        = 90

tradingTime = 1 //(time >= 080000 and time < 163000)

endif


// -- Indicators -----
maShrt = exponentialAverage[maShortPeriod](close)
maLong = exponentialAverage[maLongPeriod](close)
arUp   = aroonUp[arroonUpPeriod]
arDn   = aroonDown[arroonDnPeriod]
sTrend = supertrend[stMultiplier, stPeriods]
atr    = averageTrueRange[40]
inProfit = onMarket and positionPerf > 0 // ignore for now

// -- Entry conditions -----
// - Long entry -
bc1 = not longOnMarket and tradingTime
bc1 = bc1 and (arUp CROSSES OVER arDn)
bc1 = bc1 and (maShrt > maLong[1]) and (close > sTrend)
bc1 = (bc1 and useATRFilter and atr > atrThreshold) or (bc1 and (not useATRFilter))

// -- Short entry conditions (AKA long exit) ----
sc1 = not ShortOnMarket
sc1 = sc1 and (arUp crosses under arDn)
sc1 = sc1 and (maShrt < maLong[1]) and (close < sTrend)
//sc1 = sc1 and (maLong < maLong[2])


// -- Donchian Stop Logic -----
if useDonchianStop and onMarket then
if longOnMarket  then
dcLo = lowest[donchianChPeriod](low)
dcLastStop = dcLo[1]
sell at dcLastStop stop
elsif shortOnMarket  then
dcHi = highest[donchianChPeriod](high)
dcLastStop = dcHi[1]
exitshort at dcLastStop stop
endif
endif


// -- Trailing Stop Logic -----
if useTrailingStop then
once tsLong  = tsLongDistance  * pointsize
once tsShort = tsShortDistance * pointsize
if (not onMarket) then
tsMaxPrice = 0
tsMinPrice = close
tsExitLevel = 0
elsif (onMarket and tsExitLevel > 0) then
exitShort at tsExitLevel stop
sell      at tsExitLevel stop
elsif longOnMarket then
tsMaxPrice = max(tsMaxPrice,close)
if tsMaxPrice-tradeprice(1) >= tsLong then
tsExitLevel = tsMaxPrice - tsLong
endif
elsif shortOnMarket then
tsMinPrice = MIN(tsMinPrice,close)
if tradePrice(1)-tsMinPrice >= tsShort then
tsExitLevel = tsMinPrice + tsShort
endif
endif
endif


// -- ATR based target --
if onMarket and useATRTarget then
set target pProfit (atr * atrTargetMultiple) * pointSize
endif


// -- Soft Time Stop --
if onMarket and softTimeStopBars > 0 then
if not inProfit then
countLosingBars = countLosingBars + 1
endif
if countLosingBars >= softTimeStopBars and inProfit then
sc1 = 1 /// can exit
endif
elsif not onMarket and countLosingBars > 0 then
countLosingBars = 0
endif


// -- Second chance profit lock -----
if onMarket and useSecondChanceStop then
once scTriggered = 0
once maxPerf     = 0
if scTriggered and positionPerf >= maxPerf then
sc1 = 1
else
maxPerf     = max(maxPerf, positionPerf)
scTriggered = (barIndex - tradeIndex >= scMinBarsInTrade) 
scTriggered = scTriggered and positionPerf <= (maxPerf * scRetraceTrigger)
endif
elsif useSecondChanceStop and (not onMarket) and maxPerf > 0 then
// Reset when off market
maxPerf = 0
scTriggered = 0
endif


// -- execution logic -----
if bc1 then
buy positionSize contracts at market
elsif sc1 then // and (not inProfit) then
if onmarket then
sell at market // exit long position if short setup triggerd
endif
//sellshort positionSize contracts at market
endif

Hi Guys, here below test results 200.000 as soon a possible I’ll test variables optim. by Walk farward Regards Ale