Indicator: MTF trend dashboard with 200 SMA

Viewing 5 posts - 1 through 5 (of 5 total)

Author

Posts

02/13/2026 at 3:55 PM #258011 quote

Participant

Veteran

I want to create a Dashboard . I have started coding but I am stuck. Attached is the code

//--------------------------------------------------------------//
// INDICATOR: MTF_Trend_Dashboard
// Inspired by BKTrend SMA/EMA Meter
//--------------------------------------------------------------//

// 1. DATA COLLECTION FROM MULTIPLE TIMEFRAMES
// Timeframe 1: 5 Minutes
TIMEFRAME(5 minutes)
sma5M = Average[200](close)
cond5M = close > sma5M

// Timeframe 2: 15 Minutes
TIMEFRAME(15 minutes)
sma15M = Average[200](close)
cond15M = close > sma15M

// Timeframe 3: 1 Hour
TIMEFRAME(1 hour)
sma1H = Average[200](close)
cond1H = close > sma1H

// Timeframe 4: 4 Hours
TIMEFRAME(4 hours)
sma4H = Average[200](close)
cond4H = close > sma4H

// Timeframe 5: Daily
TIMEFRAME(daily)
sma1D = Average[200](close)
cond1D = close > sma1D

// 2. DASHBOARD RENDERING (Only on the last bar)
IF IsLastBarUpdate THEN
// Table Headers
DRAWTEXT(" 5M | 15M | 1H | 4H | 1D ", 20, 30, SansSerif, Bold, 12) COLOURED(255,255,255)
   
// Status Indicators (Row 1: Price vs 200 SMA)
// 5M
IF cond5M THEN
DRAWTEXT(" BULL ", 22, 15, SansSerif, Bold, 10) COLOURED(0,255,0)
ELSE
DRAWTEXT(" BEAR ", 22, 15, SansSerif, Bold, 10) COLOURED(255,0,0)
ENDIF
   
// 15M
IF cond15M THEN
DRAWTEXT(" BULL ", 45, 15, SansSerif, Bold, 10) COLOURED(0,255,0)
ELSE
DRAWTEXT(" BEAR ", 45, 15, SansSerif, Bold, 10) COLOURED(255,0,0)
ENDIF

// 1H
IF cond1H THEN
DRAWTEXT(" BULL ", 68, 15, SansSerif, Bold, 10) COLOURED(0,255,0)
ELSE
DRAWTEXT(" BEAR ", 68, 15, SansSerif, Bold, 10) COLOURED(255,0,0)
ENDIF

// 4H
IF cond4H THEN
DRAWTEXT(" BULL ", 91, 15, SansSerif, Bold, 10) COLOURED(0,255,0)
ELSE
DRAWTEXT(" BEAR ", 91, 15, SansSerif, Bold, 10) COLOURED(255,0,0)
ENDIF

// 1D
IF cond1D THEN
DRAWTEXT(" BULL ", 114, 15, SansSerif, Bold, 10) COLOURED(0,255,0)
ELSE
DRAWTEXT(" BEAR ", 114, 15, SansSerif, Bold, 10) COLOURED(255,0,0)
ENDIF
ENDIF

RETURN

I want it to be similar to the dashboard shown below

02/13/2026 at 4:11 PM #258015 quote

Iván González

Moderator

Legend

image missing

02/13/2026 at 6:28 PM #258045 quote

oyinloyea

Participant

Veteran

I can’t add a chart to the page

02/13/2026 at 6:32 PM #258049 quote

oyinloyea

Participant

Veteran

Attached is the file

Dashboard-1.jpg

02/14/2026 at 6:13 PM #258075 quote

robertogozzi

Moderator

Legend

There you go:

//--------------------------------------------------------------//
// INDICATOR: MTF_Trend_Dashboard
// Inspired by BKTrend SMA/EMA Meter
//--------------------------------------------------------------//
DEFPARAM DrawOnLastBarOnly = true
// 1. DATA COLLECTION FROM MULTIPLE TIMEFRAMES
// Timeframe 1: 5 Minutes
TIMEFRAME(5 minutes)
sma5M = Average[200](close)
cond5M = close > sma5M

// Timeframe 2: 15 Minutes
TIMEFRAME(15 minutes)
sma15M = Average[200](close)
cond15M = close > sma15M

// Timeframe 3: 1 Hour
TIMEFRAME(1 hour)
sma1H = Average[200](close)
cond1H = close > sma1H

// Timeframe 4: 4 Hours
TIMEFRAME(4 hours)
sma4H = Average[200](close)
cond4H = close > sma4H

// Timeframe 5: Daily
TIMEFRAME(daily)
sma1D = Average[200](close)
cond1D = close > sma1D

Timeframe(default)
// 2. DASHBOARD RENDERING (Only on the last bar)
IF IsLastBarUpdate THEN
// Table Headers
//--------------------------------------------------------------------------------------------------------------------
drawrectangle(-250,0,-10,-40)                                                 anchor(TopRight) coloured("LightGray") bordercolor("Black")
drawtext ("    5M    |    15M    |    1H    |    4H    |    1D    ", -130,-10, SansSerif, Bold, 12) anchor(TopRight) coloured("Black")
//--------------------------------------------------------------------------------------------------------------------
// Status Indicators (Row 1: Price vs 200 SMA)
// 5M
IF cond5M THEN
DRAWTEXT(" BULL ", -215, -25, SansSerif, Bold, 10) anchor(TopRight) coloured("Green")
ELSIF Not cond5M THEN
DRAWTEXT(" BEAR ", -215, -25, SansSerif, Bold, 10) anchor(TopRight) coloured("Red")
ENDIF
//   
// 15M
IF cond15M THEN
DRAWTEXT(" BULL ", -170, -25, SansSerif, Bold, 10) anchor(TopRight) coloured("Green")
ELSIF Not cond15M THEN
DRAWTEXT(" BEAR ", -170, -25, SansSerif, Bold, 10) anchor(TopRight) coloured("Red")
ENDIF
//
// 1H
IF cond1H THEN
DRAWTEXT(" BULL ", -125, -25, SansSerif, Bold, 10) anchor(TopRight) coloured("Green")
ELSIF Not cond1H THEN
DRAWTEXT(" BEAR ", -125, -25, SansSerif, Bold, 10) anchor(TopRight) coloured("Red")
ENDIF
//
// 4H
IF cond4H THEN
DRAWTEXT(" BULL ", -80, -25,  SansSerif, Bold, 10) anchor(TopRight) coloured("Green")
ELSIF Not cond4H THEN
DRAWTEXT(" BEAR ", -80, -25,  SansSerif, Bold, 10) anchor(TopRight) coloured("Red")
ENDIF
//
// 1D
IF cond1D THEN
DRAWTEXT(" BULL ", -35, -25,  SansSerif, Bold, 10) anchor(TopRight) coloured("Green")
ELSIF Not cond1D THEN
DRAWTEXT(" BEAR ", -35, -25,  SansSerif, Bold, 10) anchor(TopRight) coloured("Red")
ENDIF
ENDIF
RETURN

Nicolas, danskfilou and Iván González thanked this post