Voici

//---------------------------------------
//PRC_Humble LinReg Candles (by ugurvu)
//version = 0
//23.01.2026
//Iván González @ www.prorealcode.com
//Sharing ProRealTime knowledge
//---------------------------------------
// 0. Inputs
//---------------------------------------
linregLength=11
linreg=1 // 1=True 0=False
signalLength=11
smasignal=1 // 1=True 0=False
//---------------------------------------
// 1. Calculate OHLC prices with Linear Regression if enabled
//---------------------------------------
IF linReg = 1 THEN
   bOpen = LinearRegression[linregLength](open)
   bHigh = LinearRegression[linregLength](high)
   bLow = LinearRegression[linregLength](low)
   bClose = LinearRegression[linregLength](close)
ELSE
   bOpen = open
   bHigh = high
   bLow = low
   bClose = close
ENDIF
//---------------------------------------
// 2. Calculate Signal Line
//---------------------------------------
IF smaSignal = 1 THEN
   // Simple Moving Average
   signal = Average[signalLength](bClose)
ELSE
   // Exponential Moving Average
   signal = ExponentialAverage[signalLength](bClose)
ENDIF
//---------------------------------------
// 3. Drawing Candles
//---------------------------------------
// Green candles for bullish movements
IF bOpen < bClose THEN
   DRAWCANDLE(bOpen, bHigh, bLow, bClose) COLOURED(0, 200, 0)
ELSE
   // Red candles for bearish movements
   DRAWCANDLE(bOpen, bHigh, bLow, bClose) COLOURED(200, 0, 0)
ENDIF
//---------------------------------------
RETURN signal AS "Signal Line" COLOURED("blue")